Version bump.

Package-Manager: portage-2.1.9.25/cvs/Linux x86_64

8 files changed, 205 insertions, 4 deletions

diff --git a/dev-ruby/rspec-core/ChangeLog b/dev-ruby/rspec-core/ChangeLog
index f0d6121f49b2..8cb74a46994d 100644
--- a/dev-ruby/rspec-core/ChangeLog
+++ b/dev-ruby/rspec-core/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rspec-core
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-core/ChangeLog,v 1.6 2011/02/02 14:12:44 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-core/ChangeLog,v 1.7 2011/02/19 09:27:40 graaff Exp $
+
+*rspec-core-2.5.1 (19 Feb 2011)
+
+  19 Feb 2011; Hans de Graaff <graaff@gentoo.org> +rspec-core-2.5.1.ebuild:
+  Version bump.
 
   02 Feb 2011; Diego E. Pettenò <flameeyes@gentoo.org>
   rspec-core-2.4.0.ebuild, +files/rspec-core-2.4.0-tests.patch:
diff --git a/dev-ruby/rspec-core/rspec-core-2.5.1.ebuild b/dev-ruby/rspec-core/rspec-core-2.5.1.ebuild
new file mode 100644
index 000000000000..1b0785de204b
--- /dev/null
+++ b/dev-ruby/rspec-core/rspec-core-2.5.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-core/rspec-core-2.5.1.ebuild,v 1.1 2011/02/19 09:27:40 graaff Exp $
+
+EAPI=2
+USE_RUBY="ruby18 ree18 ruby19"
+
+RUBY_FAKEGEM_TASK_TEST="none"
+RUBY_FAKEGEM_TASK_DOC="none"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE=""
+
+RDEPEND="${RDEPEND} !<dev-ruby/rspec-1.3.1-r1"
+
+ruby_add_bdepend "test? (
+		dev-ruby/syntax
+		dev-ruby/rspec-expectations:2
+		dev-ruby/rspec-mocks:2
+	)"
+
+#	>=dev-ruby/cucumber-0.5.3
+#	>=dev-ruby/autotest-4.2.9
+#	dev-ruby/aruba"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm Gemfile || die
+
+	# Also clean the /usr/lib/rubyee path (which is our own invention).
+	sed -i -e 's#lib\\d\*\\/ruby\\/#lib\\d*\\/ruby(ee|)\\/#' lib/rspec/core/configuration.rb || die
+}
+
+all_ruby_compile() {
+	if use doc ; then
+		RUBYLIB="${S}/lib" rake rdoc || die "Unable to create documentation."
+	fi
+}
+
+each_ruby_test() {
+	PATH="${S}/bin:${PATH}" RUBYLIB="${S}/lib" ${RUBY} -S rake spec || die "Tests failed."
+
+	# There are features but they require aruba which we don't have yet.
+}
diff --git a/dev-ruby/rspec-expectations/ChangeLog b/dev-ruby/rspec-expectations/ChangeLog
index 5fef622b16c1..31bd9607a1fd 100644
--- a/dev-ruby/rspec-expectations/ChangeLog
+++ b/dev-ruby/rspec-expectations/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/rspec-expectations
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-expectations/ChangeLog,v 1.5 2011/01/15 17:01:34 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-expectations/ChangeLog,v 1.6 2011/02/19 09:26:45 graaff Exp $
+
+*rspec-expectations-2.5.0 (19 Feb 2011)
+
+  19 Feb 2011; Hans de Graaff <graaff@gentoo.org>
+  +rspec-expectations-2.5.0.ebuild:
+  Version bump.
 
 *rspec-expectations-2.4.0 (15 Jan 2011)
 
diff --git a/dev-ruby/rspec-expectations/rspec-expectations-2.5.0.ebuild b/dev-ruby/rspec-expectations/rspec-expectations-2.5.0.ebuild
new file mode 100644
index 000000000000..3c2bd6c7394e
--- /dev/null
+++ b/dev-ruby/rspec-expectations/rspec-expectations-2.5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-expectations/rspec-expectations-2.5.0.ebuild,v 1.1 2011/02/19 09:26:45 graaff Exp $
+
+EAPI=2
+USE_RUBY="ruby18 ree18 ruby19"
+
+RUBY_FAKEGEM_TASK_TEST="none"
+
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/diff-lcs-1.1.2"
+
+ruby_add_bdepend "test? (
+		>=dev-ruby/rspec-core-2.4.0:2
+		dev-ruby/rspec-mocks:2
+	)"
+
+# Not clear yet to what extend we need those (now)
+#	>=dev-ruby/cucumber-0.6.2
+#	>=dev-ruby/aruba-0.1.1"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm Gemfile || die
+}
+
+each_ruby_test() {
+	PATH="${S}/bin:${PATH}" RUBYLIB="${S}/lib" ${RUBY} -S rake spec
+
+	# There are features but they require aruba which we don't have yet.
+}
diff --git a/dev-ruby/rspec-mocks/ChangeLog b/dev-ruby/rspec-mocks/ChangeLog
index ed9e33867132..79210740d76c 100644
--- a/dev-ruby/rspec-mocks/ChangeLog
+++ b/dev-ruby/rspec-mocks/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rspec-mocks
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-mocks/ChangeLog,v 1.7 2011/02/02 14:13:26 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-mocks/ChangeLog,v 1.8 2011/02/19 09:26:14 graaff Exp $
+
+*rspec-mocks-2.5.0 (19 Feb 2011)
+
+  19 Feb 2011; Hans de Graaff <graaff@gentoo.org> +rspec-mocks-2.5.0.ebuild:
+  Version bump.
 
   02 Feb 2011; Diego E. Pettenò <flameeyes@gentoo.org>
   rspec-mocks-2.4.0.ebuild, +files/rspec-mocks-2.4.0-no-cucumber.patch:
diff --git a/dev-ruby/rspec-mocks/rspec-mocks-2.5.0.ebuild b/dev-ruby/rspec-mocks/rspec-mocks-2.5.0.ebuild
new file mode 100644
index 000000000000..11ddde3c3b90
--- /dev/null
+++ b/dev-ruby/rspec-mocks/rspec-mocks-2.5.0.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-mocks/rspec-mocks-2.5.0.ebuild,v 1.1 2011/02/19 09:26:14 graaff Exp $
+
+EAPI=2
+USE_RUBY="ruby18 ree18 ruby19"
+
+RUBY_FAKEGEM_TASK_TEST="none"
+
+RUBY_FAKEGEM_TASK_DOC="none"
+RUBY_FAKEGEM_EXTRADOC="README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE=""
+
+# cucumber and rspec-core are loaded unconditionally in the Rakefile,
+# so we also need to require them for USE=doc.
+ruby_add_bdepend "test? (
+		dev-ruby/rspec-core:2
+		dev-ruby/rspec-expectations:2
+	)
+	doc? ( dev-ruby/rspec-core:2 )"
+
+# Not clear yet to what extend we need those (now)
+#	>=dev-ruby/cucumber-0.6.2
+#	>=dev-ruby/aruba-0.1.1"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm Gemfile || die
+}
+
+all_ruby_compile() {
+	if use doc ; then
+		RUBYLIB="${S}/lib" rake rdoc || die
+	fi
+}
+
+each_ruby_test() {
+	PATH="${S}/bin:${PATH}" RUBYLIB="${S}/lib" ${RUBY} -S rake spec || die
+
+	# There are features but they require aruba which we don't have yet.
+}
diff --git a/dev-ruby/rspec/ChangeLog b/dev-ruby/rspec/ChangeLog
index 023366d8af45..ab550656cd94 100644
--- a/dev-ruby/rspec/ChangeLog
+++ b/dev-ruby/rspec/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/rspec
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec/ChangeLog,v 1.85 2011/02/02 14:15:08 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec/ChangeLog,v 1.86 2011/02/19 09:28:49 graaff Exp $
+
+*rspec-2.5.0 (19 Feb 2011)
+
+  19 Feb 2011; Hans de Graaff <graaff@gentoo.org> +rspec-2.5.0.ebuild:
+  Version bump.
 
   02 Feb 2011; Diego E. Pettenò <flameeyes@gentoo.org> rspec-2.4.0.ebuild:
   Add ruby19 support.
diff --git a/dev-ruby/rspec/rspec-2.5.0.ebuild b/dev-ruby/rspec/rspec-2.5.0.ebuild
new file mode 100644
index 000000000000..18587d52b9ff
--- /dev/null
+++ b/dev-ruby/rspec/rspec-2.5.0.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec/rspec-2.5.0.ebuild,v 1.1 2011/02/19 09:28:49 graaff Exp $
+
+EAPI=2
+USE_RUBY="ruby18 ruby19 ree18"
+
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="README.markdown"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend "
+	=dev-ruby/rspec-core-2.5*
+	~dev-ruby/rspec-expectations-${PV}
+	~dev-ruby/rspec-mocks-${PV}"