Add net-analyzer/zabbix-3.4.3

2 files changed, 339 insertions, 0 deletions

diff --git a/net-analyzer/zabbix/Manifest b/net-analyzer/zabbix/Manifest
index b989839c..e3c5f47a 100644
--- a/net-analyzer/zabbix/Manifest
+++ b/net-analyzer/zabbix/Manifest
@@ -47,6 +47,7 @@ DIST zabbix-3.2.6.tar.gz 16008047 SHA256 98f025b39515b196552b8a23e2fe20a8180b5e9
 DIST zabbix-3.2.7.tar.gz 16016367 SHA256 3ea0c299bd69bc728177128740f0476bc1a2c1de438330df5bbd8f5fc6090712 SHA512 f60c82829c076a7f8b9d2f0c7dc91f7b65594ac4dcfaa08b19a61b730d8d21afc161636f793416613a47220535334fb675bb105738b130677c729fc0e31cd3e3 WHIRLPOOL 5956e6a5116a70f9feb00ffbb7547243f2de6a6c26188008bea31b4fb4d6fa31a099b11f9535f8409f7a66d6ab682837f27497b881b263f253192034250669fb
 DIST zabbix-3.4.1.tar.gz 17010519 SHA256 faaf1a1569ec6b4674d80e707904197c8b568f2b4660f636c28d0c42af471fd4 SHA512 e3ce49cbbb6ada1d12fa80ff366b9e819b8d7b8c60474698457f8250682614af0d2e5de6c2f6a9e34ab10bb8fd01eac51d8365489606b6d0aefc103c5780ebce WHIRLPOOL 52cfae3172e36a61db75f82f37ec97c9c85614c865c30b784b7644c2af99790e295f9700a1dcddfe85d23825f1b4cfccc2a9785051a8cb8d0c4439626ccbfcd9
 DIST zabbix-3.4.2.tar.gz 17113290 SHA256 54c21e04da4ef43380af647c6a0ddff67614337386fa318da021117efe5b334f SHA512 42feff59e1e1dd5d69a66cc857e9076b9a6f1410b5796a719cb660ea97ccd2544fe87f3cfabc27590cc53a321d24a7977daa320be1fdff31653b3650602dd385 WHIRLPOOL 752bf703018a67b8299a25b40e1fd204abf9e37675313705646b5eac05dfa84b5301f3ef9588aa21e097b1608ae82db418b084866f70800d78eb2384c1d34fce
+DIST zabbix-3.4.3.tar.gz 17130788 SHA256 00e87db503d332a1e3905d13f36b6ddad32c2514f03060361168655a8d4fd8cf SHA512 338f4c367d906252ad762ffff60652f6f3d8f0027684e1562fbf26a4628002b72671dd6a2a3547c1681277a9cdef544d671b89edac886e96914a0b3850e639a8 WHIRLPOOL 0568b4c28ab887d49c7d00accb0311faed150fb19b150ade01462f43a12af3c365c1a9731474be1ef3c3297430ef0f0348ca0fd45ef118ffa61cda1d5258161e
 EBUILD zabbix-2.2.15.ebuild 9611 SHA256 a17f2aa8db996f5e53dd3031fbfffaf626936b4b9c670c908f69cf08f596167c SHA512 2ae0953b8a9a617a4dc8b6f1c73adb4e167b831ce645f30d204dc762cfb5909c35c5bd89b11807ca3d0ed8a11d267bfc86599e10c7a0422821338c1287f06a74 WHIRLPOOL fe53c237412c6ed48cbda77719e09d4dbcd6e25edef1b0333467d15e43bba3c9e194c4525bb1f4fd226d2d56431b358cc36f9bf5f5fbd541e8f1c8cda00fc5ba
 EBUILD zabbix-2.2.16.ebuild 9611 SHA256 a17f2aa8db996f5e53dd3031fbfffaf626936b4b9c670c908f69cf08f596167c SHA512 2ae0953b8a9a617a4dc8b6f1c73adb4e167b831ce645f30d204dc762cfb5909c35c5bd89b11807ca3d0ed8a11d267bfc86599e10c7a0422821338c1287f06a74 WHIRLPOOL fe53c237412c6ed48cbda77719e09d4dbcd6e25edef1b0333467d15e43bba3c9e194c4525bb1f4fd226d2d56431b358cc36f9bf5f5fbd541e8f1c8cda00fc5ba
 EBUILD zabbix-2.2.5.ebuild 10242 SHA256 714a61f6c04787127d5f4d74cd1ea095b35d6308626d92e25b45c0474e4672a7 SHA512 67f0cdbbfbbc115cc60bef14e45ddd2898c501186a421e36bddd28f958cb01f8baa1c910bdea1505e5bd0a46e1dabd3791db77ffc40fe9950bc30f200fb00903 WHIRLPOOL af8851edcb2e06a99d1784f44201af78b911afe8a0459c400f0c3ed50b1b7fabf24c22c7777c739df3a1c653daceec63b1f7ae514e9c63dc9ede4d7efe8ebb5f
@@ -66,3 +67,4 @@ EBUILD zabbix-3.2.6.ebuild 9397 SHA256 75baa6d443286099d3b688e95d3b5ffedf69e2685
 EBUILD zabbix-3.2.7.ebuild 9397 SHA256 75baa6d443286099d3b688e95d3b5ffedf69e26858942afa9cc0f4f748b0cd88 SHA512 a71824c7d672423302d8912a4a7a18235600627840353d615cf2bde22065deaaef32085b39440ba4923fec65eec6f76155174216f606c3802e5592b740e3f108 WHIRLPOOL 0de96dbfde20cc5acd4b0de3cf0ecf5dc440ab4d214ed3da72ffa5750bf25642838ffdb8f2e447dbf24042177648c80f3a1b1478db6dc175d8dcbdec188081b4
 EBUILD zabbix-3.4.1.ebuild 9411 SHA256 2337ddb8646910a05f69037e5be1be674987bd5565ffba0e19faa46989454bed SHA512 74905f4d96226e6336d55d66d1df137a1a2d44cb18c0c406dff063aba0d8814c45370b6f490de66baa38be9315facee39fdb42d2df8ffe855bc6d42fb0f842f5 WHIRLPOOL 155f12943d4087fd2a77f2a9a54c01ddb7364520a27b79d9f6071922b8a2ae0a3b178bc44869ec45c5310e0215ce5d5845b92de4b81849c1c0eb5581102b0d94
 EBUILD zabbix-3.4.2.ebuild 9411 SHA256 2337ddb8646910a05f69037e5be1be674987bd5565ffba0e19faa46989454bed SHA512 74905f4d96226e6336d55d66d1df137a1a2d44cb18c0c406dff063aba0d8814c45370b6f490de66baa38be9315facee39fdb42d2df8ffe855bc6d42fb0f842f5 WHIRLPOOL 155f12943d4087fd2a77f2a9a54c01ddb7364520a27b79d9f6071922b8a2ae0a3b178bc44869ec45c5310e0215ce5d5845b92de4b81849c1c0eb5581102b0d94
+EBUILD zabbix-3.4.3.ebuild 9411 SHA256 2337ddb8646910a05f69037e5be1be674987bd5565ffba0e19faa46989454bed SHA512 74905f4d96226e6336d55d66d1df137a1a2d44cb18c0c406dff063aba0d8814c45370b6f490de66baa38be9315facee39fdb42d2df8ffe855bc6d42fb0f842f5 WHIRLPOOL 155f12943d4087fd2a77f2a9a54c01ddb7364520a27b79d9f6071922b8a2ae0a3b178bc44869ec45c5310e0215ce5d5845b92de4b81849c1c0eb5581102b0d94
diff --git a/net-analyzer/zabbix/zabbix-3.4.3.ebuild b/net-analyzer/zabbix/zabbix-3.4.3.ebuild
new file mode 100644
index 00000000..10412540
--- /dev/null
+++ b/net-analyzer/zabbix/zabbix-3.4.3.ebuild
@@ -0,0 +1,337 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+# needed to make webapp-config dep optional
+WEBAPP_OPTIONAL="yes"
+inherit flag-o-matic webapp java-pkg-opt-2 user systemd toolchain-funcs
+
+DESCRIPTION="ZABBIX is software for monitoring of your applications, network and servers"
+HOMEPAGE="http://www.zabbix.com/"
+MY_P=${P/_/}
+MY_PV=${PV/_/}
+SRC_URI="http://prdownloads.sourceforge.net/zabbix/${MY_P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+WEBAPP_MANUAL_SLOT="yes"
+KEYWORDS="~amd64 ~x86"
+IUSE="+agent curl frontend ipv6 java ldap libxml2 mysql odbc openipmi oracle +postgres proxy server snmp sqlite ssh ssl static systemd xmpp"
+REQUIRED_USE="|| ( agent frontend proxy server )
+	proxy? ( ^^ ( mysql oracle postgres sqlite odbc ) )
+	server? ( ^^ ( mysql oracle postgres odbc ) )
+	static? ( !oracle !snmp )"
+
+COMMON_DEPEND="snmp? ( net-analyzer/net-snmp )
+	ldap? (
+		net-nds/openldap
+		=dev-libs/cyrus-sasl-2*
+		net-libs/gnutls
+	)
+	mysql? ( >=virtual/mysql-5.0.3 )
+	sqlite? ( >=dev-db/sqlite-3.3.5 )
+	postgres? ( dev-db/postgresql:* )
+	oracle? ( >=dev-db/oracle-instantclient-basic-10.0.0.0 )
+	xmpp? ( dev-libs/iksemel )
+	libxml2? ( dev-libs/libxml2 )
+	curl? ( net-misc/curl )
+	openipmi? ( sys-libs/openipmi )
+	ssh? ( net-libs/libssh2 )
+	java? ( virtual/jdk:* )
+	odbc? ( dev-db/unixODBC )
+	ssl? ( dev-libs/openssl:=[-bindist] )"
+
+RDEPEND="${COMMON_DEPEND}
+	proxy? ( net-analyzer/fping[suid] )
+	server? ( net-analyzer/fping[suid]
+		app-admin/webapp-config
+		dev-libs/libevent )
+	java?	(
+		>=virtual/jre-1.4
+		dev-java/slf4j-api
+	)
+	frontend? (
+		>=dev-lang/php-5.3.0[bcmath,ctype,sockets,gd,truetype,xml,session,xmlreader,xmlwriter,nls,sysvipc,unicode]
+		|| ( dev-lang/php[apache2] dev-lang/php[cgi] dev-lang/php[fpm] )
+		mysql? ( dev-lang/php[mysqli] )
+		odbc? ( dev-lang/php[odbc] )
+		oracle? ( dev-lang/php[oci8-instant-client] )
+		postgres? ( dev-lang/php[postgres] )
+		sqlite? ( dev-lang/php[sqlite] )
+		media-libs/gd[png]
+		app-admin/webapp-config )"
+DEPEND="${COMMON_DEPEND}
+	static? (
+		ldap? (
+			net-nds/openldap[static-libs]
+			=dev-libs/cyrus-sasl-2*[static-libs]
+			net-libs/gnutls[static-libs]
+		)
+	mysql? ( >=virtual/mysql-5.0.3[static-libs] )
+	sqlite? ( >=dev-db/sqlite-3.3.5[static-libs] )
+	postgres? ( dev-db/postgresql:*[static-libs] )
+	libxml2? ( dev-libs/libxml2[static-libs] )
+	curl? ( net-misc/curl[static-libs] )
+	ssh? ( net-libs/libssh2[static-libs] )
+	odbc? ( dev-db/unixODBC[static-libs] )
+	)
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+ZABBIXJAVA_BASE="opt/zabbix"
+
+pkg_setup() {
+	if use oracle; then
+		if [ -z "${ORACLE_HOME}" ]; then
+			eerror
+			eerror "The environment variable ORACLE_HOME must be set"
+			eerror "and point to the correct location."
+			eerror "It looks like you don't have Oracle installed."
+			eerror
+			die "Environment variable ORACLE_HOME is not set"
+		fi
+		if has_version 'dev-db/oracle-instantclient-basic'; then
+			ewarn
+			ewarn "Please ensure you have a full install of the Oracle client."
+			ewarn "dev-db/oracle-instantclient* is NOT sufficient."
+			ewarn
+		fi
+	fi
+
+	if use frontend; then
+		webapp_pkg_setup
+	fi
+
+	enewgroup zabbix
+	enewuser zabbix -1 -1 /var/lib/zabbix/home zabbix
+}
+
+java_prepare() {
+	cd "${S}/src/zabbix_java/lib"
+	rm -v *.jar || die
+
+	java-pkg_jar-from slf4j-api
+}
+
+src_prepare() {
+	default
+}
+
+src_configure() {
+	econf \
+		$(use_enable server) \
+		$(use_enable proxy) \
+		$(use_enable agent) \
+		$(use_enable ipv6) \
+		$(use_enable static) \
+		$(use_enable java) \
+		$(use_with ldap) \
+		$(use_with snmp net-snmp) \
+		$(use_with mysql) \
+		$(use_with postgres postgresql) \
+		$(use_with oracle) \
+		$(use_with sqlite sqlite3) \
+		$(use_with xmpp jabber) \
+		$(use_with curl libcurl) \
+		$(use_with openipmi openipmi) \
+		$(use_with ssh ssh2) \
+		$(use_with libxml2) \
+		$(use_with odbc unixodbc) \
+		$(use_with ssl openssl) \
+		|| die "econf failed"
+}
+
+src_compile() {
+	if [ -f Makefile ] || [ -f GNUmakefile ] || [ -f makefile ]; then
+		emake AR="$(tc-getAR)" RANLIB="$(tc-getRANLIB)" || die "emake failed"
+	fi
+}
+
+src_install() {
+	dodir \
+		/etc/zabbix \
+		/var/lib/zabbix \
+		/var/lib/zabbix/home \
+		/var/lib/zabbix/scripts \
+		/var/lib/zabbix/alertscripts \
+		/var/lib/zabbix/externalscripts \
+		/var/log/zabbix
+
+	keepdir \
+		/etc/zabbix \
+		/var/lib/zabbix \
+		/var/lib/zabbix/home \
+		/var/lib/zabbix/scripts \
+		/var/lib/zabbix/alertscripts \
+		/var/lib/zabbix/externalscripts \
+		/var/log/zabbix
+
+	if use server; then
+		insinto /etc/zabbix
+		doins "${FILESDIR}/3.0"/zabbix_server.conf
+		doinitd "${FILESDIR}/3.0"/init.d/zabbix-server
+		dosbin src/zabbix_server/zabbix_server
+		fowners zabbix:zabbix /etc/zabbix/zabbix_server.conf
+		fperms 0640 /etc/zabbix/zabbix_server.conf
+		dodir /usr/share/zabbix
+		/bin/cp -R "${S}/database/" "${D}"/usr/share/zabbix/
+		if use systemd; then
+			systemd_dounit "${FILESDIR}/zabbix-server.service"
+			systemd_newtmpfilesd "${FILESDIR}/zabbix-server.tmpfiles" zabbix-server.conf
+		fi
+	fi
+
+	if use proxy; then
+		doinitd "${FILESDIR}/3.0"/init.d/zabbix-proxy
+		dosbin src/zabbix_proxy/zabbix_proxy
+		insinto /etc/zabbix
+		doins "${FILESDIR}/3.0"/zabbix_proxy.conf
+		dodir /usr/share/zabbix
+		/bin/cp -R "${S}/database/" "${D}"/usr/share/zabbix/
+		if use systemd; then
+			systemd_dounit "${FILESDIR}/zabbix-proxy.service"
+			systemd_newtmpfilesd "${FILESDIR}/zabbix-proxy.tmpfiles" zabbix-proxy.conf
+		fi
+	fi
+
+	if use agent; then
+		insinto /etc/zabbix
+		doins "${FILESDIR}/3.0"/zabbix_agentd.conf
+		doinitd "${FILESDIR}/3.0"/init.d/zabbix-agentd
+		dosbin src/zabbix_agent/zabbix_agentd
+		dobin \
+			src/zabbix_sender/zabbix_sender \
+			src/zabbix_get/zabbix_get
+		fowners zabbix:zabbix /etc/zabbix/zabbix_agentd.conf
+		fperms 0640 /etc/zabbix/zabbix_agentd.conf
+		if use systemd; then
+			systemd_dounit "${FILESDIR}/zabbix-agentd.service"
+			systemd_newtmpfilesd "${FILESDIR}/zabbix-agentd.tmpfiles" zabbix-agentd.conf
+		fi
+	fi
+
+	fowners zabbix:zabbix \
+		/etc/zabbix \
+		/var/lib/zabbix \
+		/var/lib/zabbix/home \
+		/var/lib/zabbix/scripts \
+		/var/lib/zabbix/alertscripts \
+		/var/lib/zabbix/externalscripts \
+		/var/log/zabbix
+	fperms 0750 \
+		/etc/zabbix \
+		/var/lib/zabbix \
+		/var/lib/zabbix/home \
+		/var/lib/zabbix/scripts \
+		/var/lib/zabbix/alertscripts \
+		/var/lib/zabbix/externalscripts \
+		/var/log/zabbix
+
+	dodoc README INSTALL NEWS ChangeLog \
+		conf/zabbix_agentd.conf \
+		conf/zabbix_proxy.conf \
+		conf/zabbix_agentd/userparameter_examples.conf \
+		conf/zabbix_agentd/userparameter_mysql.conf \
+		conf/zabbix_server.conf
+
+	if use frontend; then
+		webapp_src_preinst
+		cp -R frontends/php/* "${D}/${MY_HTDOCSDIR}"
+		webapp_configfile \
+			"${MY_HTDOCSDIR}"/include/db.inc.php \
+			"${MY_HTDOCSDIR}"/include/config.inc.php
+		webapp_src_install
+	fi
+
+	if use java; then
+		dodir \
+			/${ZABBIXJAVA_BASE} \
+			/${ZABBIXJAVA_BASE}/bin \
+			/${ZABBIXJAVA_BASE}/lib
+		keepdir /${ZABBIXJAVA_BASE}
+		insinto /${ZABBIXJAVA_BASE}/bin
+		doins src/zabbix_java/bin/zabbix-java-gateway-${MY_PV}.jar
+		insinto /${ZABBIXJAVA_BASE}/lib
+		doins \
+			src/zabbix_java/lib/logback-classic-0.9.27.jar \
+			src/zabbix_java/lib/logback-console.xml \
+			src/zabbix_java/lib/logback-core-0.9.27.jar \
+			src/zabbix_java/lib/logback.xml \
+			src/zabbix_java/lib/android-json-4.3_r3.1.jar \
+			src/zabbix_java/lib/slf4j-api-1.6.1.jar
+		fowners -R zabbix:zabbix /${ZABBIXJAVA_BASE}
+		doinitd "${FILESDIR}"/3.0/init.d/zabbix-jmx-proxy
+		doconfd "${FILESDIR}"/3.0/conf.d/zabbix-jmx-proxy
+	fi
+}
+
+pkg_postinst() {
+	if use server || use proxy ; then
+		elog
+		elog "You may need to configure your database for Zabbix,"
+		elog "if you have not already done so. "
+		elog
+
+		local zabbix_homedir="$( egethome zabbix )"
+		if [ -n "${zabbix_homedir}" ] && \
+		   [ "${zabbix_homedir}" != "/var/lib/zabbix/home" ]; then
+			ewarn
+			ewarn "The user 'zabbix' should have his homedir changed"
+			ewarn "to /var/lib/zabbix/home if you want to use"
+			ewarn "custom alert scripts."
+			ewarn
+			ewarn "A real homedir might be needed for configfiles"
+			ewarn "for custom alert scripts (e.g. ~/.sendxmpprc when"
+			ewarn "using sendxmpp for Jabber alerts)."
+			ewarn
+			ewarn "To change the homedir use:"
+			ewarn "  usermod -d /var/lib/zabbix/home zabbix"
+			ewarn
+		fi
+	fi
+
+	if use server; then
+		elog
+		elog "For distributed monitoring you have to run:"
+		elog
+		elog "zabbix_server -n <nodeid>"
+		elog
+		elog "This will convert database data for use with Node ID"
+		elog "and also adds a local node."
+		elog
+	fi
+
+	elog "--"
+	elog
+	elog "You may need to add these lines to /etc/services:"
+	elog
+	elog "zabbix-agent     10050/tcp Zabbix Agent"
+	elog "zabbix-agent     10050/udp Zabbix Agent"
+	elog "zabbix-trapper   10051/tcp Zabbix Trapper"
+	elog "zabbix-trapper   10051/udp Zabbix Trapper"
+	elog
+
+	if use server || use proxy ; then
+		# check for fping
+		local -i fping_perms
+		fping_perms=$(stat -c %a /usr/sbin/fping 2>/dev/null)
+		case ${fping_perms} in
+			4[157][157][157])
+				;;
+			*)
+				ewarn
+				ewarn "If you want to use the checks 'icmpping' and 'icmppingsec',"
+				ewarn "you have to make /usr/sbin/fping setuid root and executable"
+				ewarn "by everyone. Run the following command to fix it:"
+				ewarn
+				ewarn "  chmod u=rwsx,g=rx,o=rx /usr/sbin/fping"
+				ewarn
+				ewarn "Please be aware that this might impose a security risk,"
+				ewarn "depending on the code quality of fping."
+				ewarn
+				;;
+		esac
+	fi
+}
+# vi: set diffopt=iwhite,filler: