Add app-crypt/pinentry-0.9.6-r6

2 files changed, 125 insertions, 0 deletions

diff --git a/app-crypt/pinentry/Manifest b/app-crypt/pinentry/Manifest
index 64b58785..e62474da 100644
--- a/app-crypt/pinentry/Manifest
+++ b/app-crypt/pinentry/Manifest
@@ -31,3 +31,4 @@ EBUILD pinentry-0.9.4-r1.ebuild 2942 SHA256 7ddfd6ac1f95e7d8927c53709fa67e7f5db6
 EBUILD pinentry-0.9.5.ebuild 2912 SHA256 89d7672e5b5afdcf7e136095b9047f082049c9c470495e6b94c37c936a575909 SHA512 92cc1d63f764e6797cd4590dda5063aed78dede117c6ec9141f19e0aac7579e56df2fec2708c38123d7b526d601df9fd2ed9b7ff257a61676399bdbde2551a58 WHIRLPOOL bd489e06a5e175fd1fd50e13f0c11a2fdf8ebe96a93228b8d6cac8de0b3f246967aad8e5ec3a3b51d10e8440079efa5fc311fc9d70153ac32c66c5eaf31111a1
 EBUILD pinentry-0.9.6-r1.ebuild 2939 SHA256 dcebfebbd64562d53bfc70e8a1fcbda790adf01d693fd8e502202b1068461e37 SHA512 2f2ff4b2ded35472ec3e73cde33ed999f533a11b1ce7c7221f9851cabb4d5907568102579526e0e019cd93502fddcb4263035ba9199afa6b84ecd498e001e9d4 WHIRLPOOL b05b42143d3816536c6e9bc219d56431679825373195a04ae40ebb51ee9099435f2c5e9e0eeb09b9cf651f5bc7fb68a38a37944806f667fcd79e4c0d94503188
 EBUILD pinentry-0.9.6-r5.ebuild 3436 SHA256 fcb831aac2f5796ae3fb599a1eef2c532d7fd6827edd2b3ea6ef525057f466c1 SHA512 815ca2539bb09d5950ffff6801929c9096879abd5925bbc3b944206f3cb3f5f70a4e931261d0b9f6ef50fddb8a72481a5d553ef4b342eaad076cd49fd859c7e5 WHIRLPOOL f0bc78996fa29d911993ff09227f4545a0c1ca159ac3cf32223ed2477db93c961392064637db2da82c89a6775571f3abc8196247379586e8b7f253200c560813
+EBUILD pinentry-0.9.6-r6.ebuild 3426 SHA256 54fbffa65d71dae6913ef0b406570ff3a28243b1970376808f604640b9c0fde0 SHA512 6fa0972f6a8ce02605544970cb1bddee2a35f48790bfbda3338dbeb98823730d7c89ebd0216cde5f9996943a00d216b0d6882dbcc7ba45031a502e7382f38fc5 WHIRLPOOL d2df3020598020a45d70abc33507d804f79b7cc6999f3432c50ed166388c2d7684ef58f9e45f485cd22076abf654259f5366c6582abffdc4e3b0364db6b051fa
diff --git a/app-crypt/pinentry/pinentry-0.9.6-r6.ebuild b/app-crypt/pinentry/pinentry-0.9.6-r6.ebuild
new file mode 100644
index 00000000..277587a4
--- /dev/null
+++ b/app-crypt/pinentry/pinentry-0.9.6-r6.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id: ea0df559a95bc003971ed054fc35fba4a533f743 $
+
+EAPI=5
+
+inherit autotools qmake-utils multilib eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Collection of simple PIN or passphrase entry dialogs which utilize the Assuan protocol"
+HOMEPAGE="http://gnupg.org/aegypten2/index.html"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="emacs gtk ncurses qt4 qt5 caps gnome-keyring static"
+
+CDEPEND="
+	>=dev-libs/libgpg-error-1.17
+	>=dev-libs/libassuan-2
+	>=dev-libs/libgcrypt-1.6.3
+	ncurses? ( sys-libs/ncurses:0= )
+	gtk? ( x11-libs/gtk+:2 )
+	qt4? (
+		>=dev-qt/qtgui-4.4.1:4
+	     )
+	qt5? (
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	     )
+	caps? ( sys-libs/libcap )
+	static? ( >=sys-libs/ncurses-5.7-r5:0=[static-libs,-gpm] )
+	app-eselect/eselect-pinentry
+	gnome-keyring? ( app-crypt/libsecret )
+"
+
+DEPEND="${CDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+RDEPEND="
+	${CDEPEND}
+	gnome-keyring? ( app-crypt/gcr )
+"
+
+REQUIRED_USE="
+	|| ( ncurses gtk qt4 qt5 )
+	gtk? ( !static )
+	qt4? ( !static )
+	qt5? ( !static )
+	static? ( ncurses )
+	?? ( qt4 qt5 )
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.8.2-ncurses.patch"
+	epatch "${FILESDIR}/${P}-add-disable-pinentry-qt5-option.patch"
+	epatch "${FILESDIR}/${PN}-0.9.4-configure.ac.patch"
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=()
+	use static && append-ldflags -static
+	[[ "$(gcc-major-version)" -ge 5 ]] && append-cxxflags -std=gnu++11
+
+	QT_MOC=""
+	if use qt4; then
+		myconf+=( --enable-pinentry-qt
+			  --disable-pinentry-qt5
+			)
+		QT_MOC="$(qt4_get_bindir)"/moc
+		# Issues finding qt on multilib systems
+		export QTLIB="$(qt4_get_libdir)"
+	elif use qt5; then
+		myconf+=( --enable-pinentry-qt )
+		QT_MOC="$(qt5_get_bindir)"/moc
+		export QTLIB="$(qt5_get_libdir)"
+	else
+		myconf+=( --disable-pinentry-qt )
+	fi
+
+	econf \
+		--enable-pinentry-tty \
+		$(use_enable emacs pinentry-emacs) \
+		$(use_enable gtk pinentry-gtk2) \
+		$(use_enable ncurses pinentry-curses) \
+		$(use_enable ncurses fallback-curses) \
+		$(use_with caps libcap) \
+		$(use_enable gnome-keyring libsecret) \
+		$(use_enable gnome-keyring pinentry-gnome3) \
+		"${myconf[@]}" \
+		MOC="${QT_MOC}"
+}
+
+src_install() {
+	default
+	rm -f "${ED}"/usr/bin/pinentry || die
+
+	if use qt4 || use qt5; then
+		dosym pinentry-qt /usr/bin/pinentry-qt4
+	fi
+}
+
+pkg_postinst() {
+	if ! has_version 'app-crypt/pinentry' || has_version '<app-crypt/pinentry-0.7.3'; then
+		elog "We no longer install pinentry-curses and pinentry-qt SUID root by default."
+		elog "Linux kernels >=2.6.9 support memory locking for unprivileged processes."
+		elog "The soft resource limit for memory locking specifies the limit an"
+		elog "unprivileged process may lock into memory. You can also use POSIX"
+		elog "capabilities to allow pinentry to lock memory. To do so activate the caps"
+		elog "USE flag and add the CAP_IPC_LOCK capability to the permitted set of"
+		elog "your users."
+	fi
+
+	eselect pinentry update ifunset
+}
+
+pkg_postrm() {
+	eselect pinentry update ifunset
+}