added 0ad, ebuild by Philip Taylor

2 files changed, 119 insertions, 0 deletions

diff --git a/games-strategy/0ad/0ad-7732.ebuild b/games-strategy/0ad/0ad-7732.ebuild
new file mode 100644
index 0000000..d3631cb
--- /dev/null
+++ b/games-strategy/0ad/0ad-7732.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="3"
+
+inherit eutils wxwidgets games
+
+MY_P="0ad-r0${PV}-pre-alpha"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="0 A.D. is a free, real-time strategy game currently under development by Wildfire Games."
+HOMEPAGE="http://wildfiregames.com/0ad/"
+SRC_URI="mirror://sourceforge/zero-ad/${MY_P}-unix-build.tar.xz
+	mirror://sourceforge/zero-ad/${MY_P}-unix-data.tar.xz"
+
+LICENSE="GPL-2 CCPL-Attribution-ShareAlike-3.0"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+IUSE="debug +editor test"
+
+RDEPEND="virtual/opengl
+	media-libs/openal
+	dev-libs/crypto++
+	media-libs/libsdl
+	dev-libs/boost
+	sys-libs/zlib
+	|| ( dev-libs/libgamin app-admin/fam )
+	editor? ( x11-libs/wxGTK:2.8 )
+	media-libs/devil
+	<net-libs/enet-1.3
+	media-libs/jpeg
+	media-libs/libpng
+	dev-libs/libxml2
+	media-libs/libvorbis
+	media-libs/libogg"
+
+DEPEND="${RDEPEND}
+	dev-lang/nasm
+	app-arch/xz-utils"
+
+RESTRICT="strip mirror"
+
+dir=${GAMES_PREFIX_OPT}/${PN}
+
+pkg_setup() {
+	games_pkg_setup
+	if use editor ; then
+		WX_GTK_VER=2.8 need-wxwidgets unicode
+	fi
+}
+
+src_compile() {
+	if ! use editor ; then
+		sed -i "s:--atlas::" "${S}/build/workspaces/update-workspaces.sh" \
+		|| die "AtlasUI sed failed"
+	fi
+
+	cd "${S}/build/workspaces"
+	./update-workspaces.sh || die "update-workspaces.sh failed"
+	cd gcc
+
+	TARGETS="pyrogenesis Collada"
+	if use test ; then
+		TARGETS="${TARGETS} test"
+	fi
+	if use editor ; then
+		TARGETS="${TARGETS} AtlasUI"
+	fi
+	if use debug ; then
+		CONFIG=Debug
+	else
+		CONFIG=Release
+	fi
+	CONFIG=${CONFIG} emake ${TARGETS} || die "Can't build"
+}
+
+src_test() {
+	cd "${S}/binaries/system"
+	if use debug ; then
+		./test_dbg || die "Tests failed"
+	else
+		./test || die "Tests failed"
+	fi
+}
+
+src_install() {
+	cd "${S}"/binaries
+	insinto "${dir}"
+	doins -r data || die "doins -r failed"
+
+	insinto "${dir}"/system
+	if use debug ; then
+		doins "${S}"/binaries/system/libmozjs-ps-debug.so || die "doins failed"
+		doins "${S}"/binaries/system/libCollada_dbg.so || die "doins failed"
+		if use editor ; then
+			doins "${S}"/binaries/system/libAtlasUI_dbg.so || die "doins failed"
+		fi
+		EXE_NAME=pyrogenesis_dbg
+	else
+		doins "${S}"/binaries/system/libmozjs-ps-release.so || die "doins failed"
+		doins "${S}"/binaries/system/libCollada.so || die "doins failed"
+		if use editor ; then
+			doins "${S}"/binaries/system/libAtlasUI.so || die "doins failed"
+		fi
+		EXE_NAME=pyrogenesis
+	fi
+
+	exeinto "${dir}"/system
+	doexe "${S}"/binaries/system/${EXE_NAME} || die "doexe failed"
+
+	games_make_wrapper ${PN} ./system/${EXE_NAME} ${dir}
+#	make_desktop_entry "${dir}"/system/${EXE_NAME} "0 A.D."
+
+	prepgamesdirs
+}
diff --git a/games-strategy/0ad/Manifest b/games-strategy/0ad/Manifest
new file mode 100644
index 0000000..092fe9c
--- /dev/null
+++ b/games-strategy/0ad/Manifest
@@ -0,0 +1,3 @@
+DIST 0ad-r07732-pre-alpha-unix-build.tar.xz 3404348 RMD160 4d11820bf2f7baea8fe7262ab890a87d820b1004 SHA1 3d2f908158f4cd0b4dae209192ccf458d0abbf27 SHA256 98b37d8220e9f80461587b0f9711642c99c72d11a5e738b391ad582d054006e5
+DIST 0ad-r07732-pre-alpha-unix-data.tar.xz 102645876 RMD160 01b1d9fae6920022c5daeb3f810dc912b71e736b SHA1 8cfcff95005d14c6f7b809303b701545f0779b1f SHA256 b6c54ceff0079bfbf86d947d1e6b1a1b35f69d37c1c4db16dfa19da3a0eb977e
+EBUILD 0ad-7732.ebuild 2669 RMD160 730ee8d47778cc439dabf30091f80f1ab3d7999e SHA1 486bad1ba24995e18379b99711b79a577837ce7e SHA256 b3d69f87b0f4141c212798f1bc5b413c7272aeeaa36beefcb7dd149929fe8e57