blob: 6a1096cc8f5b1ca6ce08fb3514e5a417dd271f2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit autotools gnome2-utils savedconfig
DESCRIPTION="Canonical's on-screen-display notification agent"
HOMEPAGE="https://launchpad.net/notify-osd"
SRC_URI="https://launchpad.net/${PN}/precise/${PV}/+download/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="minimal"
COMMON_DEPEND="
>=dev-libs/dbus-glib-0.98
>=dev-libs/glib-2.16:2
>=x11-libs/gtk+-3.2:3
>=x11-libs/libnotify-0.7
>=x11-libs/libwnck-3:3
x11-libs/libX11
x11-libs/pixman
!x11-misc/notification-daemon
!x11-misc/qtnotifydaemon
"
RDEPEND="${COMMON_DEPEND}
gnome-base/gsettings-desktop-schemas
!minimal? ( x11-themes/notify-osd-icons )
"
DEPEND="${COMMON_DEPEND}
dev-util/glib-utils
gnome-base/gnome-common
x11-base/xorg-proto
virtual/pkgconfig
"
RESTRICT="test" # virtualx.eclass: 1 of 1: FAIL: test-modules
src_prepare() {
default
sed -i -e 's:noinst_PROG:check_PROG:' tests/Makefile.am || die
restore_config src/{bubble,defaults,dnd}.c #428134
mv configure.in configure.ac || die
eautoreconf
}
src_configure() {
econf --libexecdir="/usr/$(get_libdir)/${PN}"
}
src_install() {
default
save_config src/{bubble,defaults,dnd}.c
rm -f "${ED}"/usr/share/${PN}/icons/*/*/*/README
}
pkg_preinst() {
gnome2_icon_savelist
gnome2_schemas_savelist
}
pkg_postinst() {
gnome2_icon_cache_update
gnome2_schemas_update
}
pkg_postrm() {
gnome2_icon_cache_update
gnome2_schemas_update
}
|
GitWeb
