net-vpn/networkmanager-wireguard/networkmanager-wireguard-9999.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57

# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools git-r3

DESCRIPTION="NetworkManager WireGuard plugin"
HOMEPAGE="https://github.com/max-moser/network-manager-wireguard"
SRC_URI=""
EGIT_REPO_URI="https://github.com/max-moser/network-manager-wireguard"

LICENSE="GPL-2+"
SLOT="0"
IUSE="+glib +gtk +nls"
REQUIRED_USE="glib? ( gtk )"

RDEPEND="
	net-misc/networkmanager
	virtual/wireguard
	glib? ( dev-libs/glib )
	gtk? (
		app-crypt/libsecret
		gnome-extra/nm-applet
		x11-libs/gtk+:3
	)
"

DEPEND="${RDEPEND}"

BDEPEND="
	virtual/pkgconfig
	nls? (
		dev-util/intltool
		sys-devel/gettext
	)
"

src_prepare() {
	default

	eautoreconf
}

src_configure() {
	local myeconfargs=(
		--disable-lto
		--disable-more-warnings
		--disable-static
		$(use_with glib	libnm-glib)
		$(use_with gtk gnome)
		$(use_enable nls)
		--with-dist-version="Gentoo"
	)

	econf "${myeconfargs[@]}"
}