blob: 42e454d35cdeb2543ee1340758e503502fe6794e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic readme.gentoo-r1
DESCRIPTION="A small Jabber console client with various features, like MUC, SSL, PGP"
HOMEPAGE="http://mcabber.com/"
if [[ "${PV}" == 9999 ]]; then
inherit mercurial
EHG_REPO_URI="https://bitbucket.org/McKael/mcabber"
EHG_CHECKOUT_DIR="${WORKDIR}"
EHG_BOOTSTRAP="autogen.sh"
S="${WORKDIR}/${PN}"
else
SRC_URI="http://mcabber.com/files/${P}.tar.bz2"
KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="aspell crypt idn otr spell ssl vim-syntax"
LANGS="cs de fr it nl pl ru uk"
# localized help versions are installed only, when L10N var is set
for i in ${LANGS}; do
IUSE="${IUSE} l10n_${i}"
done;
RDEPEND="crypt? ( >=app-crypt/gpgme-1.0.0 )
otr? ( >=net-libs/libotr-3.1.0 )
aspell? ( app-text/aspell )
vim-syntax? ( || ( app-editors/vim app-editors/gvim ) )
idn? ( net-dns/libidn:= )
spell? ( app-text/enchant )
dev-libs/glib:2
net-libs/libnsl:0=
sys-libs/ncurses:0=
>=net-libs/loudmouth-1.4.3-r1[ssl?]"
DEPEND="${RDEPEND}
virtual/pkgconfig"
DOCS=( AUTHORS ChangeLog NEWS README TODO mcabberrc.example doc/README_PGP.txt )
pkg_setup() {
if use aspell && use spell; then
ewarn "NOTE: You have both USE flags 'aspell' and 'spell' enabled, enchant (USE flag 'spell') will be preferred."
fi
}
src_configure() {
econf \
--enable-modules \
$(use_enable crypt gpgme) \
$(use_enable otr) \
$(use_enable aspell) \
$(use_enable spell enchant) \
$(use_with idn libidn)
}
src_install() {
default
# clean unneeded language documentation
for i in ${LANGS}; do
use l10n_${i} || rm -rf "${ED}"/usr/share/${PN}/help/${i}
done
# contrib themes
insinto /usr/share/${PN}/themes
doins "${S}"/contrib/themes/*
# contrib generic scripts
exeinto /usr/share/${PN}/scripts
doexe "${S}"/contrib/*.{pl,py}
# contrib event scripts
exeinto /usr/share/${PN}/scripts/events
doexe "${S}"/contrib/events/*
if use vim-syntax; then
cd contrib/vim/ || die
insinto /usr/share/vim/vimfiles/syntax
doins mcabber_log-syntax.vim
insinto /usr/share/vim/vimfiles/ftdetect
doins mcabber_log-ftdetect.vim
fi
readme.gentoo_create_doc
}
pkg_postinst() {
readme.gentoo_print_elog
}
|
GitWeb