blob: 9848a4c18f2d36b4500ebc44855a486e33fbdc7f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
inherit eutils toolchain-funcs
DESCRIPTION="A network scanning tool for pentesters"
HOMEPAGE="https://www.thc.org/thc-amap/"
SRC_URI="https://www.thc.org/releases/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="libressl ssl"
DEPEND="
dev-libs/libpcre
ssl? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:0= )
)
"
RDEPEND="
${DEPEND}
!sci-biology/amap
"
src_prepare() {
rm -r pcre-3.9 || die
sed -i -e "s:etc/:share/amap/:g" amap-lib.c || die
# Above change requires below change. See sources...
sed -i '/strlen(AMAP_PREFIX/s: 5 : 12 :' amap-lib.c || die
sed -i 's:/usr/local:/usr:' amap.h || die
# Files to be updated are at different location, bug 207839.
sed -i '/AMAP_RESOURCE/s:www:freeworld:' amap.h || die
sed -i '/DATADIR/s:/etc:/share/amap:' Makefile.am || die
epatch "${FILESDIR}"/4.8-system-pcre.patch
}
src_configure() {
# non-autotools configure script
./configure || die
sed -i \
-e '/^XDEFINES=/s:=.*:=:' \
-e '/^XLIBS=/s:=.*:=:' \
-e '/^XLIBPATHS/s:=.*:=:' \
-e '/^XIPATHS=/s:=.*:=:' \
-e "/^CC=/d" \
Makefile || die
if use ssl ; then
sed -i \
-e '/^XDEFINES=/s:=:=-DOPENSSL:' \
-e '/^XLIBS=/s:=:=-lcrypto -lssl:' \
Makefile || die
fi
sed -i Makefile \
-e '/-o amap/{s|(OPT) |(OPT) $(LDFLAGS) |g}' \
|| die
}
src_compile() {
emake CC=$(tc-getCC) OPT="${CFLAGS}"
}
src_install() {
dobin amap amapcrap
insinto /usr/share/amap
doins appdefs.*
doman ${PN}.1
dodoc README TODO CHANGES
}
|
GitWeb
