blob: 399af2e017348c667151e5878595a84be5ab06f4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit multilib-minimal
DESCRIPTION="GNU VCDimager"
HOMEPAGE="http://www.vcdimager.org/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~arm64 hppa ia64 ppc ppc64 sparc x86"
IUSE="+xml static-libs"
RDEPEND="
>=dev-libs/libcdio-0.90-r1:0=[-minimal,${MULTILIB_USEDEP}]
<dev-libs/libcdio-1.0
dev-libs/popt
xml? ( dev-libs/libxml2:2 )
"
DEPEND="${RDEPEND}
virtual/pkgconfig
"
DOCS=( AUTHORS BUGS ChangeLog FAQ HACKING NEWS README THANKS TODO )
PATCHES=( "${FILESDIR}/${P}-libcdio-1.0.0.patch" )
src_prepare() {
default
# Avoid building useless programs. Bug #226249
sed -i \
-e 's/check_PROGRAMS =/check_PROGRAMS +=/' \
-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
test/Makefile.in || die
sed -i \
-e 's/noinst_PROGRAMS =/check_PROGRAMS =/' \
example/Makefile.in || die
}
multilib_src_configure() {
# We disable the xmltest because the configure script includes differently
# than the actual XML-frontend C files.
local myconf
if use xml && multilib_is_native_abi ; then
myconf="--with-xml-prefix=${EPREFIX}/usr --disable-xmltest"
else
myconf="--without-xml-frontend"
fi
multilib_is_native_abi || myconf="${myconf} --without-cli-frontend"
ECONF_SOURCE="${S}" \
econf $(use_enable static-libs static) ${myconf}
}
multilib_src_install_all() {
find "${D}" -name '*.la' -delete
einstalldocs
}
|
GitWeb
