blob: c3b6e647a0ec29205e55c9c78a19399e4f724fd5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit xdg-utils
DESCRIPTION="A simple Xfce4 media player using GStreamer"
HOMEPAGE="
https://docs.xfce.org/apps/parole/start
https://gitlab.xfce.org/apps/parole/
"
SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="amd64 ~loong ~mips ~ppc64 ~riscv x86"
IUSE="libnotify taglib wayland X"
REQUIRED_USE="|| ( wayland X )"
DEPEND="
>=dev-libs/dbus-glib-0.100
>=dev-libs/glib-2.38:2
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
sys-apps/dbus
>=x11-libs/gtk+-3.20:3[wayland?,X?]
>=xfce-base/libxfce4ui-4.11:=[gtk3(+)]
>=xfce-base/libxfce4util-4.11:=
>=xfce-base/xfconf-4.10:=
libnotify? ( >=x11-libs/libnotify-0.7 )
taglib? ( >=media-libs/taglib-1.6:0= )
X? (
>=x11-libs/libX11-1.6.7
)
"
RDEPEND="
${DEPEND}
media-plugins/gst-plugins-meta:1.0
"
DEPEND+="
x11-base/xorg-proto
"
BDEPEND="
dev-util/glib-utils
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
src_configure() {
local myconf=(
# clutter backend does not work with new GTK+3 versions
--disable-clutter
$(use_enable taglib)
$(use_enable libnotify notify-plugin)
$(use_enable wayland)
$(use_enable X x11)
)
econf "${myconf[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
}
pkg_postinst() {
xdg_desktop_database_update
xdg_icon_cache_update
}
pkg_postrm() {
xdg_desktop_database_update
xdg_icon_cache_update
}
|
GitWeb