blob: 3e8e85f984e8d7cbf324e7c3c71aacebf2a73453 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson xdg
DESCRIPTION="Music audio files viewer and analiser"
HOMEPAGE="https://www.sonicvisualiser.org/ https://github.com/sonic-visualiser/sonic-visualiser"
SRC_URI="https://code.soundsoftware.ac.uk/attachments/download/2866/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="id3tag jack mad ogg opus osc +portaudio pulseaudio test"
BDEPEND="
dev-qt/qttest:5
virtual/pkgconfig
"
RDEPEND="
app-arch/bzip2
dev-libs/capnproto:=
dev-libs/serd
dev-libs/sord
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5[ssl]
dev-qt/qtsvg:5
dev-qt/qtwidgets:5
dev-qt/qtxml:5
media-libs/alsa-lib
media-libs/dssi
media-libs/ladspa-sdk
media-libs/liblrdf
media-libs/libsamplerate
media-libs/libsndfile
media-libs/rubberband
media-libs/speex
media-libs/vamp-plugin-sdk
sci-libs/fftw:3.0=
id3tag? ( media-libs/libid3tag:= )
jack? ( virtual/jack )
mad? ( media-libs/libmad )
ogg? (
media-libs/libfishsound
media-libs/liboggz
)
opus? (
media-libs/libopusenc
media-libs/opusfile
)
osc? ( media-libs/liblo )
portaudio? ( media-libs/portaudio )
pulseaudio? ( media-libs/libpulse )
"
DEPEND="${RDEPEND}"
# tests fail without mp3 support
RESTRICT="!test? ( test )"
REQUIRED_USE="
|| ( jack pulseaudio portaudio )
test? ( id3tag mad )
"
PATCHES=(
"${FILESDIR}/${PN}-5.0.1-meson.build.patch"
)
src_configure() {
local emesonargs=(
$(meson_use id3tag)
$(meson_use jack)
$(meson_use mad)
$(meson_use ogg)
$(meson_use opus)
$(meson_use osc)
$(meson_use portaudio)
$(meson_use pulseaudio)
)
meson_src_configure
}
|
GitWeb