blob: 0775282f7108ba1a39a9d2f89e624d05d1c6dc5e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cargo meson
MY_P=glycin-${PV/_/.}
DESCRIPTION="Loaders for glycin clients (glycin crate or libglycin)"
HOMEPAGE="https://gitlab.gnome.org/sophie-h/glycin/"
SRC_URI="
https://download.gnome.org/sources/glycin/$(ver_cut 1-2)/${MY_P}.tar.xz
"
S=${WORKDIR}/${MY_P}
LICENSE="|| ( LGPL-2.1+ MPL-2.0 )"
# Dependent crate licenses
LICENSE+="
Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD GPL-3+ ISC MIT
Unicode-DFS-2016
|| ( LGPL-2.1+ MPL-2.0 )
"
SLOT="0"
KEYWORDS="~amd64"
IUSE="heif jpegxl svg test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.60:2
>=sys-libs/libseccomp-2.5.0
heif? ( >=media-libs/libheif-1.17.0:= )
jpegxl? ( >=media-libs/libjxl-0.10.0:= )
svg? (
>=gnome-base/librsvg-2.52.0:2
>=x11-libs/cairo-1.17.0
)
"
DEPEND="
${RDEPEND}
test? (
>=gui-libs/gtk-4.12.0:4
>=media-libs/lcms-2.14:2
)
"
BDEPEND="
test? (
sys-apps/bubblewrap
sys-apps/dbus
)
"
ECARGO_VENDOR=${S}/vendor
QA_FLAGS_IGNORED="usr/libexec/glycin-loaders/.*"
src_prepare() {
default
# https://gitlab.gnome.org/sophie-h/glycin/-/issues/81
sed -i -e '\|/fonts|d' tests/tests.rs || die
}
src_configure() {
local formats=(
$(usev heif glycin-heif)
$(usev jpegxl glycin-jxl)
$(usev svg glycin-svg)
glycin-image-rs
)
local formats_s=${formats[*]}
local emesonargs=(
-Dprofile=$(usex debug dev release)
-Dglycin-loaders=true
-Dloaders="${formats_s// /,}"
-Dtests=$(usex test true false)
-Dlibglycin=false
)
meson_src_configure
ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
}
src_test() {
# tests write to /proc/*/uid_map
# apparently, "addpredict /" in Portage breaks it
local -x SANDBOX_ON=0
meson_src_test
}
|
GitWeb