blob: e74cb10b552367b378b5a1ccbd9fff6d6d9ee2de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="Extensible Python-based build utility"
HOMEPAGE="http://www.scons.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
doc? ( http://www.scons.org/doc/${PV}/PDF/${PN}-user.pdf -> ${P}-user.pdf
http://www.scons.org/doc/${PV}/HTML/${PN}-user.html -> ${P}-user.html )"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="doc"
python_prepare_all() {
local PATCHES=(
"${FILESDIR}/scons-1.2.0-popen.patch"
"${FILESDIR}/${PN}-2.1.0-jython.patch"
)
# https://bugs.gentoo.org/show_bug.cgi?id=361061
sed -i -e "s|/usr/local/bin:/opt/bin:/bin:/usr/bin|${EPREFIX}/usr/local/bin:${EPREFIX}/opt/bin:${EPREFIX}/bin:${EPREFIX}/usr/bin:/usr/local/bin:/opt/bin:/bin:/usr/bin|g" engine/SCons/Platform/posix.py || die
# and make sure the build system doesn't "force" /usr/local/ :(
sed -i -e "s/'darwin'/'NOWAYdarwinWAYNO'/" setup.py || die
distutils-r1_python_prepare_all
}
python_install() {
distutils-r1_python_install \
--standard-lib \
--no-version-script \
--install-data "${EPREFIX}"/usr/share
}
python_install_all() {
local DOCS=( {CHANGES,README,RELEASE}.txt )
distutils-r1_python_install_all
use doc && dodoc "${DISTDIR}"/${P}-user.{pdf,html}
}
src_install() {
distutils-r1_src_install
# Build system does not use build_scripts properly.
# http://scons.tigris.org/issues/show_bug.cgi?id=2891
python_replicate_script "${ED}"usr/bin/scons{,ign,-time}
}
|
GitWeb
