blob: 5f3041c3d838acf96199becbd08a7ab8e32b6af8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
# The selftests fail with pypy, and urlgrabber segfaults for me.
PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
inherit distutils-r1
DESCRIPTION="python binding for curl/libcurl"
HOMEPAGE="https://github.com/pycurl/pycurl https://pypi.python.org/pypi/pycurl"
SRC_URI="http://pycurl.sourceforge.net/download/${P}.tar.gz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
IUSE="curl_ssl_gnutls curl_ssl_libressl curl_ssl_nss +curl_ssl_openssl examples ssl test"
# Depend on a curl with curl_ssl_* USE flags.
# libcurl must not be using an ssl backend we do not support.
# If the libcurl ssl backend changes pycurl should be recompiled.
# If curl uses gnutls, depend on at least gnutls 2.11.0 so that pycurl
# does not need to initialize gcrypt threading and we do not need to
# explicitly link to libgcrypt.
RDEPEND="
>=net-misc/curl-7.25.0-r1[ssl=]
ssl? (
net-misc/curl[curl_ssl_gnutls(-)=,curl_ssl_libressl(-)=,curl_ssl_nss(-)=,curl_ssl_openssl(-)=,-curl_ssl_axtls(-),-curl_ssl_cyassl(-),-curl_ssl_polarssl(-)]
curl_ssl_gnutls? ( >=net-libs/gnutls-2.11.0 )
)"
# bottle-0.12.7: https://github.com/pycurl/pycurl/issues/180
# bottle-0.12.7: https://github.com/defnull/bottle/commit/f35197e2a18de1672831a70a163fcfd38327a802
DEPEND="${RDEPEND}
test? (
dev-python/nose[${PYTHON_USEDEP}]
>=dev-python/bottle-0.12.7[${PYTHON_USEDEP}]
)"
# Needed for individual runs of testsuite by python impls.
DISTUTILS_IN_SOURCE_BUILD=1
PATCHES=(
"${FILESDIR}"/${P}-py3.5-backport.patch
)
python_prepare_all() {
sed -e "/setup_args\['data_files'\] = /d" -i setup.py || die
distutils-r1_python_prepare_all
}
python_configure_all() {
# Override faulty detection in setup.py, bug 510974.
export PYCURL_SSL_LIBRARY=${CURL_SSL/libressl/openssl}
}
python_compile() {
python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
distutils-r1_python_compile
}
python_test() {
# Python3.5 test problems
# https://github.com/pycurl/pycurl/issues/273
# https://github.com/pycurl/pycurl/issues/274
emake -j1 do-test
}
python_install_all() {
local HTML_DOCS=( doc/. )
use examples && local EXAMPLES=( examples/. )
distutils-r1_python_install_all
}
|
GitWeb
