blob: a91443630746deb827e594e78f1045fc69caca49 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python{2_7,3_3,3_4} )
PYTHON_REQ_USE="threads(+)"
inherit db-use distutils-r1 multilib
DESCRIPTION="Python bindings for Berkeley DB"
HOMEPAGE="http://www.jcea.es/programacion/pybsddb.htm https://pypi.python.org/pypi/bsddb3"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux"
IUSE="doc"
RDEPEND=">=sys-libs/db-4.8.30
<sys-libs/db-6.1"
DEPEND="${RDEPEND}
dev-python/setuptools[${PYTHON_USEDEP}]"
DISTUTILS_IN_SOURCE_BUILD=1
src_prepare() {
# This list should be kept in sync with setup.py.
for DB_VER in 6.0 5.3 5.2 5.1 5.0 4.8; do
has_version "sys-libs/db:${DB_VER}" && break
done
# Force version.
sed -e "s/db_ver = None/db_ver = (${DB_VER%.*}, ${DB_VER#*.})/" \
-e "s/dblib = 'db'/dblib = '$(db_libname ${DB_VER})'/" \
-i setup2.py setup3.py || die
# Adjust test.py to look in build/lib.
sed -e "s/'lib.%s' % PLAT_SPEC/'lib'/" \
-i test2.py test3.py || die
distutils-r1_src_prepare
}
src_configure() {
# These are needed for both build and install.
export BERKELEYDB_DIR="${EPREFIX}/usr"
export BERKELEYDB_INCDIR="$(db_includedir)"
export BERKELEYDB_LIBDIR="${EPREFIX}/usr/$(get_libdir)"
}
python_compile() {
if ! python_is_python3; then
local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
fi
distutils-r1_python_compile
}
python_test() {
"${PYTHON}" test.py -v || die "Testing failed with ${EPYTHON}"
}
python_install_all() {
use doc && local HTML_DOCS=( docs/html/. )
distutils-r1_python_install_all
}
|
GitWeb
