blob: 5f074999796a7a7a86c249bc7d09bc0f71ba92fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PHP_EXT_NAME="mongodb"
USE_PHP="php7-3 php7-4 php8-0"
inherit php-ext-pecl-r3
DESCRIPTION="MongoDB database driver for PHP"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="sasl test"
PHP_DEPEND="
php_targets_php7-3? ( dev-lang/php:7.3[json,ssl,zlib] )
php_targets_php7-4? ( dev-lang/php:7.4[json,ssl,zlib] )
php_targets_php8-0? ( dev-lang/php:8.0[ssl,zlib] )"
COMMON_DEPEND="${PHP_DEPEND}
>=dev-libs/libbson-1.18.0
>=dev-libs/mongo-c-driver-1.18.0[sasl?,ssl]
dev-libs/openssl:0=
sasl? ( dev-libs/cyrus-sasl )"
DEPEND="${COMMON_DEPEND}
test? ( dev-db/mongodb )"
RDEPEND="${COMMON_DEPEND}"
BDEPEND="${PHP_DEPEND}
virtual/pkgconfig"
# No tests on x86 because tests require dev-db/mongodb which don't support
# x86 anymore (bug #645994)
RESTRICT="x86? ( test )
!test? ( test )"
src_configure() {
local PHP_EXT_ECONF_ARGS=(
--enable-mongodb
--with-libbson
--with-libmongoc
--with-mongodb-sasl=$(usex sasl)
)
php-ext-source-r3_src_configure
}
src_test() {
local PORT=27017
mongod --port ${PORT} --bind_ip 127.0.0.1 --nounixsocket --fork \
--dbpath="${T}" --logpath="${T}/mongod.log" || die
php-ext-pecl-r3_src_test
kill $(<"${T}/mongod.lock")
}
|
GitWeb
