dev-libs/libfido2/libfido2-1.3.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit cmake-utils udev linux-info

DESCRIPTION="Provides library functionality for FIDO 2.0"
HOMEPAGE="https://github.com/Yubico/libfido2"
SRC_URI="https://github.com/Yubico/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0/1"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="libressl +static-libs"

DEPEND="
	dev-libs/libcbor:=
	virtual/libudev:=
	!libressl? ( dev-libs/openssl:0= )
	libressl? ( dev-libs/libressl:0= )
"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}/libfido2-1.3.0-cmakelists.patch"

	# from upstream git, no longer needed with openssh-8.2
	"${FILESDIR}/libfido2-1.3.0-remove-openssh-middleware.patch"
)

pkg_pretend() {
	CONFIG_CHECK="
		~USB_HID
		~HIDRAW
	"

	check_extra_config
}

src_install() {
	cmake-utils_src_install

	if ! use static-libs; then
		rm -f "${D}/$(get_libdir)"/*.a || die
	fi

	udev_newrules udev/70-u2f.rules 70-libfido2-u2f.rules
}