blob: 44a31f60eaa535cfcbf6731befa5762aafd8aae8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs flag-o-matic
DESCRIPTION="A free stand-alone ini file parsing library"
HOMEPAGE="https://github.com/ndevilla/iniparser"
SRC_URI="https://github.com/ndevilla/iniparser/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="4"
KEYWORDS="~alpha ~amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="doc examples"
BDEPEND="doc? ( app-doc/doxygen )"
_newlib_so_with_symlinks() {
local source="${1}" base="${2}" current="${3}" revision="${4}" age="${5}"
newlib.so ${source} ${base}.so.${current}.${revision}.${age}
local i
for i in ".${current}" '' ; do
dosym ${base}.so.${current}.${revision}.${age} /usr/$(get_libdir)/${base}.so${i}
done
}
src_prepare() {
default
rm -r html || die
}
src_configure() {
append-lfs-flags
}
_emake() {
emake CC="$(tc-getCC)" AR="$(tc-getAR)" V=1 \
SO_TARGET=lib${PN}${SLOT}.so.1 \
ADDITIONAL_CFLAGS= \
"$@"
}
src_compile() {
_emake
}
src_test() {
_emake -C test
}
src_install() {
_newlib_so_with_symlinks lib${PN}${SLOT}.so.1 lib${PN}${SLOT} 1 0 0
insinto /usr/include/${PN}${SLOT}
doins src/*.h
if use doc; then
emake -C doc
HTML_DOCS=( html/. )
fi
if use examples; then
docinto examples
dodoc -r example/.
docompress -x /usr/share/doc/${PF}/examples
fi
einstalldocs
}
|
GitWeb
