blob: 04506db41a40b37d592d076cf5daa7803f5c07d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI="4"
inherit cmake-utils
MY_P="${PN}1-${PV}"
if [[ ${PV} == 9999* ]] ; then
EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
inherit git-2
else
SRC_URI="http://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
fi
DESCRIPTION="Userspace access to FTDI USB interface chips"
HOMEPAGE="http://www.intra2net.com/en/developer/libftdi/"
LICENSE="LGPL-2"
SLOT="0"
IUSE="cxx doc examples python static-libs tools"
RDEPEND="virtual/libusb:1
cxx? ( dev-libs/boost )
python? ( dev-lang/python )
tools? (
!<dev-embedded/ftdi_eeprom-1.0
dev-libs/confuse
)"
DEPEND="${RDEPEND}
python? ( dev-lang/swig )
doc? ( app-doc/doxygen )"
S=${WORKDIR}/${MY_P}
src_configure() {
mycmakeargs=(
$(cmake-utils_use cxx FTDIPP)
$(cmake-utils_use doc DOCUMENTATION)
$(cmake-utils_use examples EXAMPLES)
$(cmake-utils_use python PYTHON_BINDINGS)
$(cmake-utils_use static-libs STATICLIBS)
$(cmake-utils_use tools FTDI_EEPROM)
-DCMAKE_SKIP_BUILD_RPATH=ON
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
dodoc AUTHORS ChangeLog README TODO
if use doc ; then
# Clean up crap man pages. #356369
rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/_* || die
doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
dohtml "${CMAKE_BUILD_DIR}"/doc/html/*
fi
if use examples ; then
docinto examples
dodoc examples/*.c
fi
}
|
GitWeb
