blob: d40930f5ff57afc0be0120e5f79f4f1f0c7c08be (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} pypy3 )
inherit distutils-r1
DESCRIPTION="Command-line YAML processor - jq wrapper for YAML documents"
HOMEPAGE="
https://yq.readthedocs.io/
https://github.com/kislyuk/yq/
https://pypi.org/project/yq/
"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
app-misc/jq
dev-python/argcomplete[${PYTHON_USEDEP}]
>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
dev-python/xmltodict[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/tomli[${PYTHON_USEDEP}]
' 3.{8..10})
"
DEPEND="
${RDEPEND}
test? (
dev-python/wheel[${PYTHON_USEDEP}]
)
"
PATCHES=(
"${FILESDIR}/yq-2.13.0-tests.patch"
"${FILESDIR}/${P}-tomli.patch"
)
python_prepare_all() {
sed -e 's:unittest.main():unittest.main(verbosity=2):' \
-i test/test.py || die
sed -r -e 's:[[:space:]]*"coverage",:: ; s:[[:space:]]*"flake8",::' \
-i setup.py || die
sed -e '/license_file/ d' -i setup.cfg || die
distutils-r1_python_prepare_all
}
python_test() {
"${EPYTHON}" test/test.py </dev/null || die "tests failed under ${EPYTHON}"
}
|
GitWeb
