app-emacs/dashboard/dashboard-1.8.0_pre20220809.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

COMMIT=49e5603cac7d028bfc4c679161a20ca40327956c
NEED_EMACS=26.1

inherit elisp

DESCRIPTION="Extensible Emacs dashboard, with sections like bookmarks, agenda and more"
HOMEPAGE="https://github.com/emacs-dashboard/emacs-dashboard/"
SRC_URI="https://github.com/emacs-dashboard/emacs-${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}"/emacs-${PN}-${COMMIT}

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="amd64 x86"
RESTRICT="test"  # tests not in the repository, require "Eask"

DOCS=( CHANGELOG.md README.org etc )
PATCHES=( "${FILESDIR}"/${PN}-dashboard-widgets.el-banners.patch )

ELISP_REMOVE=( .dir-locals.el )
SITEFILE="50${PN}-gentoo.el"

src_prepare() {
	elisp_src_prepare

	sed "s|@SITEETC@|${EPREFIX}${SITEETC}/${PN}|" -i dashboard-widgets.el || die
}

src_install() {
	elisp_src_install

	insinto "${SITEETC}"/${PN}
	doins -r banners
}