blob: 554016d124e29418508df32579570806704ac8ae (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit toolchain-funcs
DESCRIPTION="Very good, but slow, deflate or zlib compression"
HOMEPAGE="https://github.com/google/zopfli/"
SRC_URI="https://github.com/google/zopfli/archive/${P}.tar.gz"
S="${WORKDIR}/${PN}-${P}"
LICENSE="Apache-2.0"
SLOT="0/1"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
DOCS=( CONTRIBUTORS README README.zopflipng )
PATCHES=( "${FILESDIR}"/${P}-makefile.patch )
# zopfli statically links libzopfli
# zopflipng statically links libzopflipng
# zopflipng also statically links an exact version of LodePNG (https://github.com/lvandeve/lodepng)
# As of version 1.0.1 neither of the binaries
# use the libraries we install. The libraries
# exist solely for use by external programs.
src_compile() {
tc-export CC CXX
emake libzopfli
emake zopfli
emake libzopflipng
emake zopflipng
}
# The Makefile has no install phase
src_install() {
dolib.so libzopfli.so.${PV}
dosym libzopfli.so.${PV} /usr/$(get_libdir)/libzopfli.so.1
dobin ${PN}
# This version was erroneously not bumped to match ${PV}
dolib.so libzopflipng.so.1.0.0
dosym libzopflipng.so.1.0.0 /usr/$(get_libdir)/libzopflipng.so.1
dobin zopflipng
}
|
GitWeb
