app-accessibility/speechd-el/speechd-el-2.11.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit optfeature readme.gentoo-r1 elisp

DESCRIPTION="Emacs speech support"
HOMEPAGE="https://www.freebsoft.org/speechd-el
	https://github.com/brailcom/speechd-el"
SRC_URI="https://github.com/brailcom/${PN}/archive/${P}.tar.gz"
S="${WORKDIR}"/${PN}-${P}

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="amd64 ppc x86"

RDEPEND=">=app-accessibility/speech-dispatcher-0.7"

DOC_CONTENTS="To get Emacs to speak execute:
M-x speechd-speak RET

or add following to your initialization file (~/.emacs):
(speechd-speak)"
DISABLE_AUTOFORMATTING=YES

SITEFILE="50${PN}-gentoo.el"

src_compile() {
	emake
}

src_install() {
	elisp_src_install

	dobin speechd-log-extractor
	dodoc ANNOUNCE NEWS README speechd-speak.pdf
	doinfo ${PN}.info
}

pkg_postinst() {
	elisp_pkg_postinst

	optfeature "braille support" "app-accessibility/brltty"
}