1 files changed, 0 insertions, 63 deletions
diff --git a/net-misc/ytfzf/ytfzf-2.5.0.ebuild b/net-misc/ytfzf/ytfzf-2.5.0.ebuild
deleted file mode 100644
index 743a99d9afe1..000000000000
--- a/net-misc/ytfzf/ytfzf-2.5.0.ebuild
+++ /dev/null
@@ -1,63 +0,0 @@
-# Copyright 2021-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit optfeature
-
-DESCRIPTION="Posix script to find and watch youtube videos from the terminal"
-HOMEPAGE="https://github.com/pystardust/ytfzf/"
-SRC_URI="https://github.com/pystardust/ytfzf/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="X minimal"
-
-RDEPEND="
-	app-misc/jq
-	net-misc/curl[ssl]
-	virtual/awk
-	!minimal? (
-		X? ( media-gfx/ueberzug )
-		app-shells/fzf
-		media-video/mpv[lua]
-		net-misc/yt-dlp
-	)"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-cachedir.patch
-)
-
-src_prepare() {
-	default
-
-	sed -i "/^: ...YTFZF_SYSTEM_ADDON_DIR/s|/usr/local|${EPREFIX}/usr|" ytfzf || die
-}
-
-src_compile() { :; }
-
-src_install() {
-	local emakeargs=(
-		DESTDIR="${D}"
-		PREFIX="${EPREFIX}"/usr
-		DOCDIR="${EPREFIX}"/usr/share/doc/${PF}
-	)
-
-	emake "${emakeargs[@]}" addons doc install
-	einstalldocs
-
-	rm -r "${ED}"/usr/share/licenses || die
-}
-
-pkg_postinst() {
-	optfeature "external menu support" x11-misc/dmenu
-	optfeature "desktop notifications" x11-libs/libnotify
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "Note that ${PN} supports many methods to display menus/thumbnails."
-		elog "This ebuild primarily covers defaults and major features, additional"
-		elog "dependencies may be needed for others. Set USE=minimal if want full"
-		elog "control over optional dependencies (e.g. fzf is optional if use dmenu)."
-	fi
-}