1 files changed, 49 insertions, 0 deletions
diff --git a/gnome-extra/gnome-weather/gnome-weather-3.24.0.ebuild b/gnome-extra/gnome-weather/gnome-weather-3.24.0.ebuild
new file mode 100644
index 000000000000..298f8403247c
--- /dev/null
+++ b/gnome-extra/gnome-weather/gnome-weather-3.24.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit gnome2 python-any-r1 virtualx
+
+DESCRIPTION="A weather application for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Design/Apps/Weather"
+
+LICENSE="GPL-2+ LGPL-2+ MIT CC-BY-3.0 CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=app-misc/geoclue-2.3.1:2.0
+	>=dev-libs/gjs-1.43.3
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/gobject-introspection-1.35.9:=
+	>=dev-libs/libgweather-3.17.2:=
+	gnome-base/gsettings-desktop-schemas
+	>=x11-libs/gtk+-3.11.4:3
+"
+DEPEND="${RDEPEND}
+	dev-libs/appstream-glib
+	>=dev-util/intltool-0.26
+	virtual/pkgconfig
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-util/dogtail[${PYTHON_USEDEP}]') )
+"
+
+python_check_deps() {
+	use test && has_version "dev-util/dogtail[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure $(use_enable test dogtail)
+}
+
+src_test() {
+	virtx emake check TESTS_ENVIRONMENT="dbus-run-session"
+}