1 files changed, 38 insertions, 0 deletions
diff --git a/dev-scheme/bytestructures/bytestructures-2.0.2.ebuild b/dev-scheme/bytestructures/bytestructures-2.0.2.ebuild
new file mode 100644
index 000000000000..3412c6595c4b
--- /dev/null
+++ b/dev-scheme/bytestructures/bytestructures-2.0.2.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Structured access to bytevector contents"
+HOMEPAGE="https://github.com/TaylanUB/scheme-bytestructures/"
+SRC_URI="https://github.com/TaylanUB/scheme-${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/scheme-${PN}-${PV}"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=dev-scheme/guile-2.0.0:="
+DEPEND="${RDEPEND}"
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_install() {
+	default
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}