proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 58 insertions, 0 deletions

diff --git a/x11-wm/qtile/qtile-0.8.0.ebuild b/x11-wm/qtile/qtile-0.8.0.ebuild
new file mode 100644
index 000000000000..1c538a26eaf7
--- /dev/null
+++ b/x11-wm/qtile/qtile-0.8.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 virtualx
+
+if [[ ${PV} == 9999* ]] ; then
+	EGIT_REPO_URI="git://github.com/qtile/qtile.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/qtile/qtile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A full-featured, hackable tiling window manager written in Python"
+HOMEPAGE="http://qtile.org/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/pycairo-1.10.0-r4[xcb,${PYTHON_USEDEP}]
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	>=x11-libs/xpyb-1.3.1-r1[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/python-xlib[${PYTHON_USEDEP}]
+		x11-base/xorg-server[kdrive]
+	)"
+
+# tests fail due to xauth errors from python-xlib
+RESTRICT="test"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	VIRTUALX_COMMAND="nosetests" virtualmake
+}
+
+python_install_all() {
+	local DOCS=( CHANGELOG README.rst )
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+
+	insinto /usr/share/xsessions
+	doins resources/qtile.desktop
+
+	exeinto /etc/X11/Sessions
+	newexe "${FILESDIR}"/${PN}-session ${PN}
+}