x11-misc/lightdm-gtk-greeter: Bump to version 2.0.5

Package-Manager: Portage-2.3.24, Repoman-2.3.6

2 files changed, 79 insertions, 0 deletions

diff --git a/x11-misc/lightdm-gtk-greeter/Manifest b/x11-misc/lightdm-gtk-greeter/Manifest
index 268ad7581712..f41dcb07b5e0 100644
--- a/x11-misc/lightdm-gtk-greeter/Manifest
+++ b/x11-misc/lightdm-gtk-greeter/Manifest
@@ -2,3 +2,4 @@ DIST lightdm-gentoo-patch-2.tar.gz 695543 BLAKE2B 62e21dd413b90053160f774663d89c
 DIST lightdm-gtk-greeter-2.0.1.tar.gz 467375 BLAKE2B 9b6e4c597b0dcace770609f7bbe55dac627445b609619b7965566e964f1584bb75ed3ff7d45567dbdded5fb777578043990b9f8ba6f17d27951adf222740cee8 SHA512 fd41cae828f7feafb462143519500d0d98a8b6729eb5ffd9be4247d47fa0074fa00ac9892c8cbdda9d7656e9d6949ae65e69911ae911269e99e80e4fefb19a08
 DIST lightdm-gtk-greeter-2.0.3.tar.gz 490512 BLAKE2B 93aa086d520ed04bef5eda8f5c8afdf8f4d15f2b2b130fb889adc0a4270916d9a0151e20963f7dc8ec1f09c9f00a5966b49c3bd03ead048c63291a42486ede8e SHA512 bd5b18890cf0190faab0e6a2bffab67be359e99f45fda0be7eecded146d2518a4efc0fd4fd29970076246bb989f626dd750cb14b22ddf6188b2be5f113bff3b0
 DIST lightdm-gtk-greeter-2.0.4.tar.gz 566819 BLAKE2B 21b11a12e2af82e5548a72617da5b592a067a5fb883aa68e8076f3ec3793691a0e957da22ff49664334f67b3d7b20dda90bd02dce4bc4feadc18248e48125efc SHA512 d4dbcb7117ffd288b8a3a516423362ead837dfe83ea48cdf24056926d440900fefd22522868c39da2831dca861731b1a53f33a9db0d86c5e334e673a5dac3254
+DIST lightdm-gtk-greeter-2.0.5.tar.gz 571189 BLAKE2B 583e75b1d621ffef4ade7e65fb3ab4891a119f1d416c8011a80d06e1916ecb5903f4c1af432052cb05a72aa38cde38293dd90eed00295fec5ff758e78576e10e SHA512 1ae31a36e19a2e8825bb0bfe4eef51f317306636bc0f14df9ee4c89c81d60ce7193d74e053ce59ae50c6fe05d27be73fb5a83cce732a0df4a3b4390539418fad
diff --git a/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.5.ebuild b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.5.ebuild
new file mode 100644
index 000000000000..248aa5ef01e4
--- /dev/null
+++ b/x11-misc/lightdm-gtk-greeter/lightdm-gtk-greeter-2.0.5.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit versionator gnome2-utils
+
+DESCRIPTION="LightDM GTK+ Greeter"
+HOMEPAGE="https://launchpad.net/lightdm-gtk-greeter"
+SRC_URI="https://launchpad.net/lightdm-gtk-greeter/$(get_version_component_range 1-2)/${PV}/+download/${P}.tar.gz
+	branding? ( https://dev.gentoo.org/~hwoarang/distfiles/lightdm-gentoo-patch-2.tar.gz )"
+
+LICENSE="GPL-3 LGPL-3
+	branding? ( CC-BY-3.0 )"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="ayatana branding"
+
+COMMON_DEPEND="ayatana? ( dev-libs/libindicator:3 )
+	x11-libs/gtk+:3
+	>=x11-misc/lightdm-1.2.2"
+
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	xfce-base/exo"
+
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/gnome-themes-standard
+	>=x11-themes/adwaita-icon-theme-3.14.1"
+
+GENTOO_BG="gentoo-bg_65.jpg"
+
+src_prepare() {
+	# Ok, this has to be fixed in the tarball but I am too lazy to do it.
+	# I will fix this once I decide to update the tarball with a new gentoo
+	# background
+	# Bug #404467
+	if use branding; then
+		sed \
+			-e "/xft-hintstyle/s:slight:hintslight:" \
+			-e "/background/s:=.*:=/usr/share/lightdm/backgrounds/${GENTOO_BG}:" \
+			-i "${WORKDIR}"/${PN}.conf || die
+		# Add back the reboot/shutdown buttons
+		echo 'indicators=~host;~spacer;~clock;~spacer;~session;~language;~a11y;~power;~' \
+			>> "${WORKDIR}"/${PN}.conf || die
+	fi
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-kill-on-sigterm
+		--enable-at-spi-command="${EPREFIX}/usr/libexec/at-spi-bus-launcher --launch-immediately"
+		$(use_enable ayatana libindicator)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if use branding; then
+		insinto /etc/lightdm/
+		doins "${WORKDIR}"/${PN}.conf
+		insinto /usr/share/lightdm/backgrounds/
+		doins "${WORKDIR}"/${GENTOO_BG}
+		newdoc "${WORKDIR}"/README.txt README-background.txt
+	fi
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}