x11-misc/dunst: add 1.7.1

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/x11-misc/dunst/Manifest b/x11-misc/dunst/Manifest
index 9e4e2f70296d..c17bfc8f0b6a 100644
--- a/x11-misc/dunst/Manifest
+++ b/x11-misc/dunst/Manifest
@@ -1 +1,2 @@
 DIST dunst-1.6.1.tar.gz 217267 BLAKE2B 267e5be6a079097fb5a677bd2451b0e5bcbcddadf4c4de9af87d4eab7dd90b61908f140db3f1238b6a79d370fc3bb89c062c6b4deeefae6c9c0069b55017e907 SHA512 079ffd0ff75f1865b68cb8db261849cbe4f68b5c632c39ef8f7a3d193ff3eba3734bca31cb7268f27c9a411aec56e4c484c383b419bc0b4755b7d80ede84cd96
+DIST dunst-1.7.1.tar.gz 4585838 BLAKE2B 3bc11b4d5e6826ca03b70aa4a2cca38e2d54170cf53e8912d55129ce23eb3bacf618f8242a6be5ddcb35d7d26d6e327b9210492af2898041eae7cdec9acd9f16 SHA512 5e3e0af3cff79b371e38ddf836b53ae65e2ff32d709f7bf29c29445071e98c786d430105aa61b5a80f9c709daa07f02389f141edfd4a3dcfa53b2c667782c9a9
diff --git a/x11-misc/dunst/dunst-1.7.1.ebuild b/x11-misc/dunst/dunst-1.7.1.ebuild
new file mode 100644
index 000000000000..b1b89821e8ab
--- /dev/null
+++ b/x11-misc/dunst/dunst-1.7.1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit systemd toolchain-funcs
+
+DESCRIPTION="Lightweight replacement for common notification daemons"
+HOMEPAGE="https://dunst-project.org/ https://github.com/dunst-project/dunst"
+SRC_URI="https://github.com/dunst-project/dunst/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="wayland"
+
+DEPEND="
+	dev-libs/glib:2
+	sys-apps/dbus
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXScrnSaver
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libnotify
+	x11-libs/pango[X]
+	x11-misc/xdg-utils
+	wayland? ( dev-libs/wayland )
+"
+
+RDEPEND="${DEPEND}"
+
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	wayland? ( dev-libs/wayland-protocols )
+"
+
+src_prepare() {
+	default
+
+	# Respect users CFLAGS
+	sed -e 's/-Os//' -i config.mk || die
+
+	# Use correct path for system unit
+	sed -e "s|##PREFIX##|${EPREFIX}/usr|" -i dunst.systemd.service.in || die
+}
+
+src_configure() {
+	tc-export CC PKG_CONFIG
+
+	default
+}
+
+src_compile() {
+	local myemakeargs=(
+		SYSTEMD="0"
+		WAYLAND="$(usex wayland 1 0)"
+	)
+
+	emake "${myemakeargs[@]}"
+}
+
+src_install() {
+	local myemakeargs=(
+		PREFIX="${ED}/usr"
+		SYSCONFDIR="${ED}/etc"
+		SYSTEMD="0"
+		WAYLAND="$(usex wayland 1 0)"
+	)
+
+	emake "${myemakeargs[@]}" install
+
+	systemd_newuserunit dunst.systemd.service.in dunst.service
+}