Revert "x11-libs/fox: drop 1.6.57-r3"

This reverts commit f354b2b155cc0e94040a7c1181100ba2b9df1ad5.

Still needed by x11-misc/xfe.

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/x11-libs/fox/Manifest b/x11-libs/fox/Manifest
index d7c4453bf9f6..ce1493d8b837 100644
--- a/x11-libs/fox/Manifest
+++ b/x11-libs/fox/Manifest
@@ -1 +1,2 @@
+DIST fox-1.6.57.tar.gz 4284018 BLAKE2B 3efbc6188225f9444fbd347359e8b4041a08fe654acb99c48e4966e501a2f72a44863f2e9b60ae810a259951f89cfc27b9a8b6341e029627066712e0dbf20e40 SHA512 e7b91054a9ea674818803415284cb61572935d22466e446cb37ef68344e2684e8acd567f7c8a6912f939dcbcc37455119ad6a01ac30513f460d0b3937b7e6087
 DIST fox-1.7.67.tar.gz 5689421 BLAKE2B 60f2d8e887a41f1e234cd31c1bd2702bcedae0f1b47cb7b9832c317e34a9b517cb603033d28e5ed66c4b97c85deaf3caa8dd40a508eaf715d63772e6ef0020b0 SHA512 a45db7ea9453e2afe0ff61ed6608925e94f9202dc1fbee5e2b88a5a1c16310019cb4611090f8234ad6ebc46a6519a36085683c4553d47bc9c21b8ef0c13ab540
diff --git a/x11-libs/fox/fox-1.6.57-r3.ebuild b/x11-libs/fox/fox-1.6.57-r3.ebuild
new file mode 100644
index 000000000000..9b924026e699
--- /dev/null
+++ b/x11-libs/fox/fox-1.6.57-r3.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="C++ Toolkit for developing Graphical User Interfaces easily and effectively"
+HOMEPAGE="http://www.fox-toolkit.org/"
+SRC_URI="ftp://ftp.fox-toolkit.org/pub/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="1.6"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+bzip2 +jpeg +opengl +png tiff +truetype +zlib debug doc profile"
+
+RDEPEND="
+	x11-libs/fox-wrapper
+	x11-libs/libXcursor
+	x11-libs/libXrandr
+	bzip2? ( app-arch/bzip2 )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	opengl? ( virtual/glu virtual/opengl )
+	png? ( media-libs/libpng:= )
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-libs/freetype:2
+		x11-libs/libXft
+	)
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+	x11-libs/libXt"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_prepare() {
+	default
+
+	local d
+	for d in utils windows adie calculator pathfinder shutterbug; do
+		sed -i -e "s:${d}::" Makefile.am || die
+	done
+
+	# Respect system CXXFLAGS
+	sed -i -e 's:CXXFLAGS=""::' configure.ac || die "Unable to force cxxflags."
+
+	# don't strip binaries
+	sed -i -e '/LDFLAGS="-s ${LDFLAGS}"/d' configure.ac || die "Unable to prevent stripping."
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		--enable-$(usex debug debug release) \
+		$(use_enable bzip2 bz2lib) \
+		$(use_enable jpeg) \
+		$(use_with opengl) \
+		$(use_enable png) \
+		$(use_enable tiff) \
+		$(use_with truetype xft) \
+		$(use_enable zlib) \
+		$(use_with profile profiling)
+}
+
+src_compile() {
+	emake
+	use doc && emake -C doc docs
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		artdir="${EPREFIX}"/usr/share/doc/${PF}/html/art \
+		screenshotsdir="${EPREFIX}"/usr/share/doc/${PF}/html/screenshots
+
+	local CP="${ED}"/usr/bin/ControlPanel
+	if [[ -f ${CP} ]]; then
+		mv "${CP}" "${ED}"/usr/bin/fox-ControlPanel-${SLOT} || \
+			die "Failed to install ControlPanel"
+	fi
+
+	dodoc ADDITIONS AUTHORS LICENSE_ADDENDUM README TRACING
+
+	if use doc; then
+		# install class reference docs if USE=doc
+		docinto html
+		dodoc -r doc/ref
+	else
+		# remove documentation if USE=-doc
+		rm -rf "${ED}"/usr/share/doc/${PF}/html || die
+	fi
+
+	# slot fox-config
+	if [[ -f ${ED}/usr/bin/fox-config ]] ; then
+		mv "${ED}"/usr/bin/fox-config "${ED}"/usr/bin/fox-${SLOT}-config \
+		|| die "failed to install fox-config"
+	fi
+
+	# no static archives
+	find "${D}" -name '*.la' -delete || die
+}