sys-apps/dtc: add USE=yaml

While at it added pkgconfig to build-time depends.

Reported-by: m.manico@gmx.at
Closes: https://bugs.gentoo.org/693714
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

3 files changed, 77 insertions, 4 deletions

diff --git a/sys-apps/dtc/dtc-1.5.0-r1.ebuild b/sys-apps/dtc/dtc-1.5.0-r1.ebuild
new file mode 100644
index 000000000000..466cd72eb844
--- /dev/null
+++ b/sys-apps/dtc/dtc-1.5.0-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit multilib toolchain-funcs eutils
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/dtc/dtc.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.kernel.org/pub/software/utils/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Open Firmware device tree compiler"
+HOMEPAGE="https://devicetree.org/ https://git.kernel.org/cgit/utils/dtc/dtc.git/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="static-libs yaml"
+
+BDEPEND="
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+"
+RDEPEND="yaml? ( dev-libs/libyaml )"
+DEPEND="${RDEPEND}"
+
+DOCS="
+	Documentation/dt-object-internal.txt
+	Documentation/dts-format.txt
+	Documentation/manual.txt
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.4-posix-shell.patch
+	"${FILESDIR}"/${PN}-1.5.0-fdt_check_full-visibility.patch
+	"${FILESDIR}"/${PN}-1.5.0-gcc-10.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^CFLAGS =/s:=:+=:' \
+		-e '/^CPPFLAGS =/s:=:+=:' \
+		-e 's:-Werror::' \
+		-e 's:-g -Os::' \
+		-e "/^PREFIX =/s:=.*:= ${EPREFIX}/usr:" \
+		-e "/^LIBDIR =/s:=.*:= \$(PREFIX)/$(get_libdir):" \
+		Makefile || die
+
+	tc-export AR CC PKG_CONFIG
+	export V=1
+	export NO_YAML=$(usex !yaml 1 0)
+	export NO_VALGRIND=1 # used only in 'make checkm'
+}
+
+src_install() {
+	default
+
+	use static-libs || find "${ED}" -name '*.a' -delete
+}
diff --git a/sys-apps/dtc/dtc-9999.ebuild b/sys-apps/dtc/dtc-9999.ebuild
index 4d086b5e4a3d..a481c0ee0bc7 100644
--- a/sys-apps/dtc/dtc-9999.ebuild
+++ b/sys-apps/dtc/dtc-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 inherit multilib toolchain-funcs eutils
 
 if [[ ${PV} == "9999" ]] ; then
@@ -9,7 +9,7 @@ if [[ ${PV} == "9999" ]] ; then
 	inherit git-r3
 else
 	SRC_URI="https://www.kernel.org/pub/software/utils/${PN}/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
 fi
 
 DESCRIPTION="Open Firmware device tree compiler"
@@ -17,12 +17,16 @@ HOMEPAGE="https://devicetree.org/ https://git.kernel.org/cgit/utils/dtc/dtc.git/
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="static-libs"
+IUSE="static-libs yaml"
 
-DEPEND="
+BDEPEND="
 	sys-devel/bison
 	sys-devel/flex
+	virtual/pkgconfig
 "
+RDEPEND="yaml? ( dev-libs/libyaml )"
+DEPEND="${RDEPEND}"
+
 DOCS="
 	Documentation/dt-object-internal.txt
 	Documentation/dts-format.txt
@@ -47,6 +51,8 @@ src_prepare() {
 
 	tc-export AR CC PKG_CONFIG
 	export V=1
+	export NO_YAML=$(usex !yaml 1 0)
+	export NO_VALGRIND=1 # used only in 'make checkm'
 }
 
 src_install() {
diff --git a/sys-apps/dtc/metadata.xml b/sys-apps/dtc/metadata.xml
index 22fee8df393b..17bad4a3b9b4 100644
--- a/sys-apps/dtc/metadata.xml
+++ b/sys-apps/dtc/metadata.xml
@@ -8,6 +8,9 @@
 		<email>embedded@gentoo.org</email>
 		<name>Embedded Gentoo</name>
 	</maintainer>
+	<use>
+		<flag name="yaml">support .yaml-encoded device trees</flag>
+	</use>
 	<upstream>
 		<remote-id type="cpe">cpe:/a:dtc_project:dtc</remote-id>
 	</upstream>