sci-libs/libsigrokdecode: Version bump

Package-Manager: Portage-2.3.0, Repoman-2.3.1

1 files changed, 55 insertions, 0 deletions

diff --git a/sci-libs/libsigrokdecode/libsigrokdecode-0.4.1.ebuild b/sci-libs/libsigrokdecode/libsigrokdecode-0.4.1.ebuild
new file mode 100644
index 000000000000..f9674e40c2a6
--- /dev/null
+++ b/sci-libs/libsigrokdecode/libsigrokdecode-0.4.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_4 )
+
+inherit eutils python-single-r1
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-r3 autotools
+else
+	SRC_URI="http://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="provide (streaming) protocol decoding functionality"
+HOMEPAGE="http://sigrok.org/wiki/Libsigrokdecode"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND=">=dev-libs/glib-2.24.0
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+
+	# Only a test program (not installed, and not used by src_test)
+	# is used by libsigrok, so disable it to avoid the compile.
+	sed -i \
+		-e '/build_runtc=/s:yes:no:' \
+		configure || die
+
+	eapply_user
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}