net-wireless/gnome-bluetooth: Version bump to 42.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/net-wireless/gnome-bluetooth/Manifest b/net-wireless/gnome-bluetooth/Manifest
index b80dfc7b5403..f53082d2d5a5 100644
--- a/net-wireless/gnome-bluetooth/Manifest
+++ b/net-wireless/gnome-bluetooth/Manifest
@@ -1 +1,2 @@
 DIST gnome-bluetooth-3.34.5.tar.xz 353936 BLAKE2B 40300752830f71d436591e22a64a282745d8419ee46de534f76c4871a86a4c8f7b2203e3ddc4ca08d26348b97bf4a68315802ffa09c69265c55001e4806c7f1e SHA512 48431b3d19083705a6623442c5cd2d6c14962cdf30fc599ba47dceb6612b80142af77e1b6df142b530cb1015638081a06de38a3034177e0d05a354c40f19d9e5
+DIST gnome-bluetooth-42.0.tar.xz 302440 BLAKE2B f7e02efe04b1dddee365b9c316368d92428099d6d1191d9c785018bc4bebc19942e7216bd7e6e824cd132a53b6750b1f41393d270e99718312c96da7f6a4ad5b SHA512 769bd9300fa1d830240e84257230425fe7f2e871cbd6c8fa6416514487a26326601a21c16075a66cf886850bab17f5c8e2235463f3695ea194c9230d6e50337c
diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-42.0.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.0.ebuild
new file mode 100644
index 000000000000..b636fe4e0a00
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-42.0.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..10} )
+inherit gnome.org meson python-any-r1 udev xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="2/13" # subslot = libgnome-bluetooth soname version
+IUSE="gtk-doc +introspection test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.4:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.1:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev
+	>=sys-power/upower-0.99.14
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		has_version -b "dev-python/python-dbusmock[${PYTHON_USEDEP}]" &&
+		has_version -b "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dsendto=true
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	udev_dorules "${FILESDIR}"/61-${PN}.rules
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! has_version 'sys-apps/systemd[acl]' ; then
+		elog "Don't forget to add yourself to the plugdev group "
+		elog "if you want to be able to control bluetooth transmitter."
+	fi
+}