net-irc/quassel: only apply new patches in ~arch in revbump

Move the patches from the previous commit (exec, mpris) into a revbump
in ~arch.

Also, add patch source annotations (PR links) to them.

Signed-off-by: Sam James <sam@gentoo.org>

4 files changed, 213 insertions, 2 deletions

diff --git a/net-irc/quassel/files/quassel-0.14.0-fix-exec-script.patch b/net-irc/quassel/files/quassel-0.14.0-fix-exec-script.patch
index fcaa188effcb..c0da6fc0e312 100644
--- a/net-irc/quassel/files/quassel-0.14.0-fix-exec-script.patch
+++ b/net-irc/quassel/files/quassel-0.14.0-fix-exec-script.patch
@@ -1,3 +1,5 @@
+https://github.com/quassel/quassel/pull/609
+
 From 247d7fe0a99a4e2a1c1b861455062c5630428492 Mon Sep 17 00:00:00 2001
 From: Max Audron <audron@cocaine.farm>
 Date: Tue, 18 Oct 2022 15:04:17 +0200
diff --git a/net-irc/quassel/files/quassel-0.14.0-fix-mpris-script.patch b/net-irc/quassel/files/quassel-0.14.0-fix-mpris-script.patch
index 6477d946b306..59726645bc82 100644
--- a/net-irc/quassel/files/quassel-0.14.0-fix-mpris-script.patch
+++ b/net-irc/quassel/files/quassel-0.14.0-fix-mpris-script.patch
@@ -1,3 +1,5 @@
+https://github.com/quassel/quassel/pull/617
+
 From c2ddbb99ed25c96e7f8eefd7eeff88f6d10c3875 Mon Sep 17 00:00:00 2001
 From: Andrew Udvare <audvare@gmail.com>
 Date: Fri, 3 May 2024 04:15:21 -0400
diff --git a/net-irc/quassel/quassel-0.14.0-r2.ebuild b/net-irc/quassel/quassel-0.14.0-r2.ebuild
index 546741201071..0f44303bef6b 100644
--- a/net-irc/quassel/quassel-0.14.0-r2.ebuild
+++ b/net-irc/quassel/quassel-0.14.0-r2.ebuild
@@ -105,8 +105,6 @@ DOCS=( AUTHORS ChangeLog README.md )
 PATCHES=(
 	"${FILESDIR}/${P}-cxxflags.patch"
 	"${FILESDIR}/${P}-fix-desktop-application-name.patch"
-	"${FILESDIR}/${P}-fix-exec-script.patch"
-	"${FILESDIR}/${P}-fix-mpris-script.patch"
 )
 
 src_configure() {
diff --git a/net-irc/quassel/quassel-0.14.0-r3.ebuild b/net-irc/quassel/quassel-0.14.0-r3.ebuild
new file mode 100644
index 000000000000..56acb7683fa8
--- /dev/null
+++ b/net-irc/quassel/quassel-0.14.0-r3.ebuild
@@ -0,0 +1,209 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake optfeature pax-utils systemd xdg-utils
+
+if [[ ${PV} != *9999* ]]; then
+	MY_P=${PN}-${PV/_/-}
+	if [[ ${PV} == *_rc* ]] ; then
+		SRC_URI="https://github.com/quassel/quassel/archive/refs/tags/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+	else
+		SRC_URI="https://quassel-irc.org/pub/${MY_P}.tar.bz2"
+		KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86 ~amd64-linux"
+	fi
+	S="${WORKDIR}/${MY_P}"
+else
+	EGIT_REPO_URI=( "https://github.com/${PN}/${PN}" )
+	inherit git-r3
+fi
+
+DESCRIPTION="Qt/KDE IRC client supporting a remote daemon for 24/7 connectivity"
+HOMEPAGE="https://quassel-irc.org/"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="bundled-icons crypt +dbus gui kde ldap monolithic oxygen postgres +server spell syslog test urlpreview"
+
+REQUIRED_USE="
+	|| ( gui server monolithic )
+	crypt? ( || ( server monolithic ) )
+	kde? ( dbus spell )
+	ldap? ( || ( server monolithic ) )
+	postgres? ( || ( server monolithic ) )
+	spell? ( || ( gui monolithic ) )
+	syslog? ( || ( server monolithic ) )
+"
+
+RESTRICT="!test? ( test )"
+
+SERVER_DEPEND="
+	acct-group/quassel
+	acct-user/quassel
+	crypt? ( app-crypt/qca:2[ssl] )
+	ldap? ( net-nds/openldap:= )
+	postgres? ( dev-qt/qtsql:5[postgres] )
+	!postgres? (
+		dev-qt/qtsql:5[sqlite]
+		dev-db/sqlite:3[threadsafe(+),-secure-delete]
+	)
+	syslog? ( virtual/logger )
+"
+GUI_DEPEND="
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtwidgets:5
+	!bundled-icons? (
+		kde-frameworks/breeze-icons:*
+		oxygen? ( kde-frameworks/oxygen-icons:* )
+	)
+	dbus? (
+		>=dev-libs/libdbusmenu-qt-0.9.3_pre20140619
+		dev-qt/qtdbus:5
+	)
+	kde? (
+		kde-frameworks/kconfigwidgets:5
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/knotifyconfig:5
+		kde-frameworks/ktextwidgets:5
+		kde-frameworks/kwidgetsaddons:5
+		kde-frameworks/kxmlgui:5
+	)
+	spell? ( kde-frameworks/sonnet:5 )
+	urlpreview? ( dev-qt/qtwebengine:5[widgets] )
+"
+RDEPEND="
+	dev-libs/boost:=
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	sys-libs/zlib
+	monolithic? (
+		${SERVER_DEPEND}
+		${GUI_DEPEND}
+	)
+	!monolithic? (
+		server? ( ${SERVER_DEPEND} )
+		gui? ( ${GUI_DEPEND} )
+	)
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-cpp/gtest
+		dev-qt/qttest:5
+	)
+"
+BDEPEND="
+	dev-qt/linguist-tools:5
+	kde-frameworks/extra-cmake-modules:0
+"
+
+DOCS=( AUTHORS ChangeLog README.md )
+
+PATCHES=(
+	"${FILESDIR}/${P}-cxxflags.patch"
+	"${FILESDIR}/${P}-fix-desktop-application-name.patch"
+	"${FILESDIR}/${P}-fix-exec-script.patch"
+	"${FILESDIR}/${P}-fix-mpris-script.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_CCACHE=OFF
+		-DCMAKE_SKIP_RPATH=ON
+		-DEMBED_DATA=OFF
+		-DWITH_WEBKIT=OFF
+		-DWITH_BUNDLED_ICONS=$(usex bundled-icons)
+		-DWANT_QTCLIENT=$(usex gui)
+		-DWITH_KDE=$(usex kde)
+		-DWITH_LDAP=$(usex ldap)
+		-DWANT_MONO=$(usex monolithic)
+		-DWITH_OXYGEN_ICONS=$(usex oxygen)
+		-DWANT_CORE=$(usex server)
+		-DBUILD_TESTING=$(usex test)
+		-DWITH_WEBENGINE=$(usex urlpreview)
+	)
+
+	# bug #830708
+	if use gui || use monolithic ; then
+		mycmakeargs+=(
+			-DCMAKE_DISABLE_FIND_PACKAGE_LibsnoreQt5=ON
+			$(cmake_use_find_package dbus dbusmenu-qt5)
+			$(cmake_use_find_package dbus Qt5DBus)
+			$(cmake_use_find_package spell KF5Sonnet)
+		)
+	fi
+
+	if use server || use monolithic ; then
+		mycmakeargs+=( $(cmake_use_find_package crypt Qca-qt5) )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use server ; then
+		# Needs PaX marking, bug #346255
+		pax-mark m "${ED}"/usr/bin/quasselcore
+
+		# Init scripts & systemd unit
+		newinitd "${FILESDIR}"/quasselcore.init-r1 quasselcore
+		newconfd "${FILESDIR}"/quasselcore.conf-r1 quasselcore
+		systemd_dounit "${FILESDIR}"/quasselcore.service
+
+		# logrotate
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}"/quassel.logrotate quassel
+	fi
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${BUILD_DIR}/lib:${LD_LIBRARY_PATH}" cmake_src_test
+}
+
+pkg_postinst() {
+	if use monolithic ; then
+		elog "Information on how to enable SSL support for client/core connections"
+		elog "is available at: https://bugs.quassel-irc.org/projects/quassel-irc/wiki/Client-Core_SSL_support"
+	fi
+
+	if use server ; then
+		einfo "If you want to generate SSL certificate, remember to run:"
+		einfo "    emerge --config =${CATEGORY}/${PF}"
+	fi
+
+	if use server || use monolithic ; then
+		optfeature "running Quassel within an ident daemon" "net-misc/oidentd"
+	fi
+
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
+
+pkg_config() {
+	if use server ; then
+		# Generate the pem file only when it does not already exist
+		QUASSEL_DIR="${EROOT}"/var/lib/${PN}
+
+		if [[ ! -f "${QUASSEL_DIR}/quasselCert.pem" ]] ; then
+			einfo "Generating Quassel SSL certificate to: \"${QUASSEL_DIR}/quasselCert.pem\""
+			openssl req -x509 -nodes -days 365 -newkey rsa:2048 \
+				-keyout "${QUASSEL_DIR}/quasselCert.pem" \
+				-out "${QUASSEL_DIR}/quasselCert.pem" || die
+
+			# Permissions for the key
+			chown ${PN}:${PN} "${QUASSEL_DIR}/quasselCert.pem" || die
+			chmod 400 "${QUASSEL_DIR}/quasselCert.pem" || die
+		else
+			einfo "Certificate \"${QUASSEL_DIR}/quasselCert.pem\" already exists."
+			einfo "Remove it if you want to create new one."
+		fi
+	fi
+}