net-irc/konversation: 23.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/net-irc/konversation/Manifest b/net-irc/konversation/Manifest
index 9907249523a9..264b2a166d00 100644
--- a/net-irc/konversation/Manifest
+++ b/net-irc/konversation/Manifest
@@ -1 +1,2 @@
 DIST konversation-23.04.3.tar.xz 4455124 BLAKE2B b773d7c243a8cd60241e186afeef9376bd60714d35b634cc3b8561e14892fc70a65103bb92c2c3ba638eeeb44e98309b9a00a237cd3207dde447a5348e22ff60 SHA512 881b4cab21c1cfdf8a7a89741e8b94287260c84556cbf64931fb6aad09d78999b94cdf50d9b39393eda162eabbf3d95049d07c1084bb3b0a31b4e4d73b06b3d3
+DIST konversation-23.08.0.tar.xz 4477176 BLAKE2B fe5c09edd0fb1c2ffc4c66eca6f28c6a337e9522cd96b80f0cd07c1a0ef1469e82c8b5d588ce2f26a3f8f59e45a8f6f2b558756eb0572d02ef99e0690b70a659 SHA512 f2dab6cc43b0d96340027dec1c801d3503275498e6e6c8e731a756b3400f17c9f82a714a2aa9fb6d0edfbbb8ac406dacf3845fc5fecf82b471a6978e9b08a27e
diff --git a/net-irc/konversation/konversation-23.08.0.ebuild b/net-irc/konversation/konversation-23.08.0.ebuild
new file mode 100644
index 000000000000..8258ecfef485
--- /dev/null
+++ b/net-irc/konversation/konversation-23.08.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.106.0
+QTMIN=5.15.9
+inherit ecm gear.kde.org
+
+DESCRIPTION="User friendly IRC Client"
+HOMEPAGE="https://konversation.kde.org https://apps.kde.org/konversation/"
+
+LICENSE="GPL-2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="+crypt"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtmultimedia-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kglobalaccel-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kidletime-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+)] )
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:5
+	crypt? ( >=app-crypt/qca-2.3.0:2[qt5(+),ssl] )
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package crypt Qca-qt5)
+	)
+
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+
+	# Bug 616162
+	insinto /etc/xdg
+	doins "${FILESDIR}"/konversationrc
+}