net-im/dino: Add 0.4.3

[sam: Sync live, fix keywords.]

Signed-off-by: Michael Vetter <jubalh@iodoru.org>
Closes: https://github.com/gentoo/gentoo/pull/31828
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 102 insertions, 1 deletions

diff --git a/net-im/dino/Manifest b/net-im/dino/Manifest
index d45bd4206da7..674adcabd18e 100644
--- a/net-im/dino/Manifest
+++ b/net-im/dino/Manifest
@@ -1 +1,2 @@
 DIST dino-0.4.2.tar.gz 882421 BLAKE2B 36c0487a19202506e4de69afd923991c912e82c974f61e787ff4af37a40133fdbdb02315e82f7e85ccb8b3cd7d734aed7f8508ca31c1ffec49674ef68f71793b SHA512 b5d5b9e2ab2ff24f53778303e5428ed0613537944cf5d9139aa7e13558ee40ffb1566c6e9267dd802938a6abf0f0d5fbe94ef17fb3e18a11d47cc0d040928d19
+DIST dino-0.4.3.tar.gz 883558 BLAKE2B 31ea5eafedcaabbc1ec99c72b5a0c1a6f80462ce3f8288b2d54d68106cfb9a31d3ac525660cd1ff7bf0faf2fbfdb2f47dd37672cc0f2b3283121fd364f670092 SHA512 c3e5e3ba05d7190206a8a3144002eac94f162525ab229edd420215eff3d5644293d0c8737266f0ed9f112313b2e6e83fb02fcc10d0f568fb5b2295238ebe78ea
diff --git a/net-im/dino/dino-0.4.3.ebuild b/net-im/dino/dino-0.4.3.ebuild
new file mode 100644
index 000000000000..443a60ca974f
--- /dev/null
+++ b/net-im/dino/dino-0.4.3.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake vala xdg readme.gentoo-r1
+
+DESCRIPTION="Modern Jabber/XMPP Client using GTK+/Vala"
+HOMEPAGE="https://dino.im"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+gpg +http +omemo +notification-sound +rtp test"
+RESTRICT="!test? ( test )"
+
+MY_REPO_URI="https://github.com/dino/dino"
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="${MY_REPO_URI}.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~arm64"
+	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
+fi
+
+RDEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/icu:=
+	dev-libs/libgee:0.8=
+	gui-libs/gtk:4
+	>=gui-libs/libadwaita-1.2.0:1[vala]
+	media-libs/graphene
+	net-libs/glib-networking
+	net-libs/gnutls:=
+	>=net-libs/libnice-0.1.15
+	net-libs/libsignal-protocol-c
+	net-libs/libsrtp:2=
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/pango
+	gpg? ( app-crypt/gpgme:= )
+	http? ( net-libs/libsoup:2.4 )
+	notification-sound? ( media-libs/libcanberra:0[sound] )
+	omemo? (
+		dev-libs/libgcrypt:=
+		media-gfx/qrencode:=
+	)
+	rtp? (
+		media-libs/gst-plugins-base:1.0
+		media-libs/gstreamer:1.0
+		media-libs/webrtc-audio-processing:0
+	)
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+"
+BDEPEND="
+	sys-devel/gettext
+	$(vala_depend)
+"
+
+src_configure() {
+	vala_setup
+
+	local disabled_plugins=(
+		$(usex gpg "" "openpgp")
+		$(usex omemo "" "omemo")
+		$(usex http  "" "http-files")
+		$(usex rtp "" rtp)
+	)
+	local enabled_plugins=(
+		$(usex notification-sound "notification-sound" "")
+	)
+	local mycmakeargs=(
+		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
+		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
+		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DSOUP_VERSION=2"
+		"-DBUILD_TESTS=$(usex test)"
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/xmpp-vala-test || die
+}
+
+src_install() {
+	cmake_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	readme.gentoo_print_elog
+}
diff --git a/net-im/dino/dino-9999.ebuild b/net-im/dino/dino-9999.ebuild
index 2f820b80edf9..443a60ca974f 100644
--- a/net-im/dino/dino-9999.ebuild
+++ b/net-im/dino/dino-9999.ebuild
@@ -18,7 +18,7 @@ if [[ ${PV} == "9999" ]]; then
 	EGIT_REPO_URI="${MY_REPO_URI}.git"
 	inherit git-r3
 else
-	KEYWORDS="amd64"
+	KEYWORDS="~amd64 ~arm64"
 	SRC_URI="${MY_REPO_URI}/releases/download/v${PV}/${P}.tar.gz"
 fi
 
@@ -77,6 +77,7 @@ src_configure() {
 		"-DENABLED_PLUGINS=$(local IFS=";"; echo "${enabled_plugins[*]}")"
 		"-DDISABLED_PLUGINS=$(local IFS=";"; echo "${disabled_plugins[*]}")"
 		"-DVALA_EXECUTABLE=${VALAC}"
+		"-DSOUP_VERSION=2"
 		"-DBUILD_TESTS=$(usex test)"
 	)