net-analyzer/gvm-libs: add 22.11.0

Signed-off-by: Giuseppe Foti <foti.giuseppe@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/38503
Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 124 insertions, 0 deletions

diff --git a/net-analyzer/gvm-libs/Manifest b/net-analyzer/gvm-libs/Manifest
index d57bc633b049..d4e2a7091072 100644
--- a/net-analyzer/gvm-libs/Manifest
+++ b/net-analyzer/gvm-libs/Manifest
@@ -1,2 +1,3 @@
 DIST gvm-libs-22.10.0.tar.gz 323677 BLAKE2B f6ace01ce3e1e240496e4edd0d07ee4f155ffa7a3eabdef6e5342cac7e7f94fd2048649a6f00b1bbb3bbe6801f09db28733a33b852ac59f873050c8859d934bc SHA512 dd4a5758ddd70b0a565879f61c913e2cc6c21e8982626058f80da07d1f3d04ad5680b6c850acac46b9b9deb46390985230c5b7b2140c81bdeeb9e8b5e4813c18
+DIST gvm-libs-22.11.0.tar.gz 331231 BLAKE2B 0dbd92f1d87b711a08941851dea7044d4d285ec9010ddc48025a3c67ff9a75e32d956c0f1111c6e0904f51634312625f004447611f9ac59c2a2431f665cdc2c2 SHA512 379e0145baddf78b22ac540fbbd900e03bd9b7acbb1d233b8c101b287257638a0ca4d02d8ab73d1d289e2676e9da358f5e1d5ffe0258819b31619e7427ca50ee
 DIST gvm-libs-22.9.1.tar.gz 314228 BLAKE2B 117ddf5824f0a1f5788695074fa5044b21b5dcfb8d6235a9f423174fa76d9262f361371d1f6807e88979ce49cafab64f5aa9fd1d2e855395bfa103bf6b121ec8 SHA512 b06c21ced89dc9f14dd19b256b57af910f4d7e585bf9c90fb7e3c3497bb429294e3ffb64dc6ee710e8b3beeb4ca9ac6aecb9d5e4b25f0f9761fa0c9f18a8dfd1
diff --git a/net-analyzer/gvm-libs/gvm-libs-22.11.0.ebuild b/net-analyzer/gvm-libs/gvm-libs-22.11.0.ebuild
new file mode 100644
index 000000000000..c7a5babad1f9
--- /dev/null
+++ b/net-analyzer/gvm-libs/gvm-libs-22.11.0.ebuild
@@ -0,0 +1,123 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake toolchain-funcs
+
+DESCRIPTION="Greenbone Vulnerability Management (GVM) libraries"
+HOMEPAGE="https://www.greenbone.net https://github.com/greenbone/gvm-libs/"
+SRC_URI="https://github.com/greenbone/gvm-libs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ldap test radius"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	acct-user/gvm
+	>=app-crypt/gpgme-1.7.0:=
+	>=dev-libs/glib-2.42:2
+	>=dev-libs/hiredis-0.10.1:=
+	dev-libs/libgcrypt:=
+	dev-libs/libgpg-error
+	>=dev-libs/cJSON-1.7.14
+	>=dev-libs/libxml2-2.0:2
+	>=net-libs/gnutls-3.2.15:=
+	net-libs/libnet:1.1
+	net-libs/libpcap
+	>=net-libs/libssh-0.6.0:=
+	>=sys-apps/util-linux-2.25.0
+	sys-libs/libxcrypt:=
+	>=sys-libs/zlib-1.2.8
+	net-libs/paho-mqtt-c:1.3
+	ldap? ( net-nds/openldap:= )
+	radius? ( net-dialup/freeradius-client )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-vcs/git
+	app-alternatives/yacc
+	app-alternatives/lex
+	virtual/pkgconfig
+	doc? (
+		app-text/doxygen[dot]
+		app-text/xmltoman
+		app-text/htmldoc
+		dev-perl/CGI
+		dev-perl/SQL-Translator
+	)
+	test? ( dev-libs/cgreen )
+"
+
+pkg_setup() {
+	if tc-is-clang; then
+		local clang_major_version=$(clang-major-version);
+		if ! has_version "sys-libs/compiler-rt-sanitizers:${clang_major_version}[profile]"; then
+			eerror "Compiling this package with clang requires sys-libs/compiler-rt-sanitizers to be built with 'profile' USE flag enabled"
+			die "Clang detected, but sys-libs/compiler-rt-sanitizers not build with 'profile' USE flag enabled"
+		fi
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+	# QA-Fix | Remove -Werror compiler flag | Bug: #909558
+	sed -i -e "s/-Werror//" "${S}"/CMakeLists.txt || die
+	# QA-Fix | Remove doxygen warnings for !CLANG
+	if use doc; then
+		if ! tc-is-clang; then
+		   local f
+		   for f in doc/*.in; do
+			sed -i \
+				-e "s*CLANG_ASSISTED_PARSING = NO*#CLANG_ASSISTED_PARSING = NO*g" \
+				-e "s*CLANG_OPTIONS*#CLANG_OPTIONS*g" \
+				"${f}" || die "couldn't disable CLANG parsing"
+		   done
+		fi
+	fi
+
+	#Remove tests that doesn't work in the network sandbox
+	if use test; then
+		sed -i 's/add_test (networking-test networking-test)/ /g' base/CMakeLists.txt || die
+		sed -i 's/add_test (util-test util-test)/ /g' boreas/CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		"-DLOCALSTATEDIR=${EPREFIX}/var"
+		"-DSYSCONFDIR=${EPREFIX}/etc"
+		"-DGVM_RUN_DIR=${EPREFIX}/var/lib/gvm"
+		"-DBUILD_TESTS=$(usex test)"
+		"-DBUILD_WITH_RADIUS=$(usex radius)"
+		"-DBUILD_WITH_LDAP=$(usex ldap)"
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	if use doc; then
+		cmake_build -C "${BUILD_DIR}" doc
+		cmake_build doc-full -C "${BUILD_DIR}" doc
+	fi
+	cmake_build rebuild_cache
+	if use test; then
+		cmake_build tests
+	fi
+}
+
+src_install() {
+	if use doc; then
+		local HTML_DOCS=( "${BUILD_DIR}"/doc/generated/html/. )
+	fi
+	cmake_src_install
+
+	# Set proper permissions on required files/directories
+	keepdir /var/lib/gvm
+	if ! use prefix; then
+		fowners -R gvm:gvm /var/lib/gvm
+	fi
+}