net-analyzer/netdata: 1.11.0 version bump

Also:
EAPI=7
Updated github URL

Signed-off-by: Craig Andrews <candrews@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

3 files changed, 116 insertions, 4 deletions

diff --git a/net-analyzer/netdata/Manifest b/net-analyzer/netdata/Manifest
index 8705cb492bda..4ead74dfffe6 100644
--- a/net-analyzer/netdata/Manifest
+++ b/net-analyzer/netdata/Manifest
@@ -1 +1,2 @@
 DIST netdata-1.10.0.tar.gz 2611773 BLAKE2B ffc4bfa593e4a36785c7e09709f1063598bd337016ad858e435049c5821f44fd5f048e4e7874e06d67c7e59234f6ec67a8a50fc7573f6b2f0cd768770ee2a612 SHA512 2358db818ad7d1ef6298c25d3f9d6c5a5a850f5bbe033b82cca1f3bc154055523637691417b6f2c2d4b7273b575afa0ec13e203ea7c2dd6321088a078ef05017
+DIST netdata-1.11.0.tar.gz 2845399 BLAKE2B e80faa3eb584ec4d617d223463a65f680e199125329c0c5db25c5320421b2c0e769f9334a49824e3974398055238e3bb27f741668850fa6191ffd810da08dc89 SHA512 c3b4045276e4a5af63ccc5403f34d37f2de6dcd95a653aa15ad33dba26c46f2d4cba06b17b1d5289bd1b8697777a41a79a159296f6843a910841523c418149ff
diff --git a/net-analyzer/netdata/netdata-1.11.0.ebuild b/net-analyzer/netdata/netdata-1.11.0.ebuild
new file mode 100644
index 000000000000..8d23470a368d
--- /dev/null
+++ b/net-analyzer/netdata/netdata-1.11.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit autotools fcaps linux-info python-r1 systemd user
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/netdata/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/netdata/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Linux real time system monitoring, done right!"
+HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
+
+LICENSE="GPL-3+ MIT BSD"
+SLOT="0"
+IUSE="caps +compression cpu_flags_x86_sse2 ipmi mysql nfacct nodejs postgres +python"
+REQUIRED_USE="
+	mysql? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )"
+# most unconditional dependencies are for plugins.d/charts.d.plugin:
+RDEPEND="
+	>=app-shells/bash-4:0
+	|| (
+		net-analyzer/openbsd-netcat
+		net-analyzer/netcat6
+		net-analyzer/netcat
+	)
+	net-analyzer/tcpdump
+	net-analyzer/traceroute
+	net-misc/curl
+	net-misc/wget
+	sys-apps/util-linux
+	virtual/awk
+	caps? ( sys-libs/libcap )
+	compression? ( sys-libs/zlib )
+	ipmi? ( sys-libs/freeipmi )
+	nfacct? (
+		net-firewall/nfacct
+		net-libs/libmnl
+	)
+	nodejs? ( net-libs/nodejs )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		mysql? (
+			|| (
+				dev-python/mysqlclient[${PYTHON_USEDEP}]
+				dev-python/mysql-python[${PYTHON_USEDEP}]
+			)
+		)
+		postgres? ( dev-python/psycopg:2[${PYTHON_USEDEP}] )
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+: ${NETDATA_USER:=netdata}
+: ${NETDATA_GROUP:=netdata}
+
+FILECAPS=(
+	'cap_dac_read_search,cap_sys_ptrace+ep' 'usr/libexec/netdata/plugins.d/apps.plugin'
+)
+
+pkg_setup() {
+	linux-info_pkg_setup
+
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 / ${PN}
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		--with-user=${NETDATA_USER} \
+		$(use_enable nfacct plugin-nfacct) \
+		$(use_enable ipmi plugin-freeipmi) \
+		$(use_enable cpu_flags_x86_sse2 x86-sse) \
+		$(use_with compression zlib)
+}
+
+src_install() {
+	default
+
+	rm -rf "${D}/var/cache" || die
+
+	# Remove unneeded .keep files
+	find "${ED}" -name ".keep" -delete || die
+
+	fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/log/netdata
+	keepdir /var/log/netdata
+	fowners -Rc ${NETDATA_USER}:${NETDATA_GROUP} /var/lib/netdata
+	keepdir /var/lib/netdata
+	keepdir /var/lib/netdata/registry
+
+	fowners -Rc root:${NETDATA_GROUP} /usr/share/${PN}
+
+	newinitd system/netdata-openrc ${PN}
+	systemd_dounit system/netdata.service
+	insinto /etc/netdata
+	doins system/netdata.conf
+}
diff --git a/net-analyzer/netdata/netdata-9999.ebuild b/net-analyzer/netdata/netdata-9999.ebuild
index f781f2a51517..8d23470a368d 100644
--- a/net-analyzer/netdata/netdata-9999.ebuild
+++ b/net-analyzer/netdata/netdata-9999.ebuild
@@ -1,21 +1,21 @@
 # Copyright 1999-2018 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
 
 inherit autotools fcaps linux-info python-r1 systemd user
 
 if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/firehol/${PN}.git"
+	EGIT_REPO_URI="https://github.com/netdata/${PN}.git"
 	inherit git-r3
 else
-	SRC_URI="https://github.com/firehol/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/netdata/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~x86"
 fi
 
 DESCRIPTION="Linux real time system monitoring, done right!"
-HOMEPAGE="https://github.com/firehol/netdata https://my-netdata.io/"
+HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
 
 LICENSE="GPL-3+ MIT BSD"
 SLOT="0"