media-sound/cmus: bump to 2.10.0 - eapi8, deps versions cleanup, updated live

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

3 files changed, 163 insertions, 9 deletions

diff --git a/media-sound/cmus/Manifest b/media-sound/cmus/Manifest
index c5a79155862c..7f6c0c62fa01 100644
--- a/media-sound/cmus/Manifest
+++ b/media-sound/cmus/Manifest
@@ -1 +1,2 @@
+DIST cmus-2.10.0.tar.gz 324121 BLAKE2B 7a9b17b04f9461b5375f51584f1dce35dcb6863d57eb9b28391cbfb6abb4eae1f541ee6f10cbbf4c7048c08fd77307647700fd08e41eb56bbad89b67657dd876 SHA512 c055dc974a88f32c7f19fb2e4260ede37fbddc3f23707a98e7f669032c1b4fd9a1032eb5c808cf5ee635617d3abf176e78d1e8596cbe669bbad95cd5c50dde7c
 DIST cmus-2.9.1.tar.gz 321004 BLAKE2B 1531d9ca8c1fd54ca487eb2b9ce8602f2d448dd80567a04bfc18449d60fbcd5286cd9f0d19983a885b2a532793c44d7dab8c1993ac8d7f5ada4f01ce670404d9 SHA512 b417e58a68c54e97db92b8760a49a3071e81f1594f2144911eed3ccceb68499dedf0699ae313babcb822d71b37add8880dfb2018686cb572e89f8627446d5e05
diff --git a/media-sound/cmus/cmus-2.10.0.ebuild b/media-sound/cmus/cmus-2.10.0.ebuild
new file mode 100644
index 000000000000..7a06ebbe8099
--- /dev/null
+++ b/media-sound/cmus/cmus-2.10.0.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 toolchain-funcs
+
+if [[ ${PV} == "9999" ]] ; then
+	EGIT_REPO_URI="https://github.com/cmus/cmus.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/cmus/cmus/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+fi
+
+DESCRIPTION="Ncurses based music player with plugin support for many formats"
+HOMEPAGE="https://cmus.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac alsa ao cddb cdio debug discid elogind examples ffmpeg +flac jack libsamplerate
+	+mad mikmod modplug mp4 musepack opus oss pidgin pulseaudio systemd tremor +unicode
+	+vorbis wavpack"
+
+REQUIRED_USE="?? ( elogind systemd )"
+
+BDEPEND="
+	virtual/pkgconfig
+"
+DEPEND="
+	sys-libs/ncurses:=[unicode(+)?]
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	ao? ( media-libs/libao )
+	cddb? ( media-libs/libcddb )
+	cdio? ( dev-libs/libcdio-paranoia )
+	discid? ( media-libs/libdiscid )
+	elogind? ( sys-auth/elogind )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac )
+	jack? ( virtual/jack )
+	libsamplerate? ( media-libs/libsamplerate )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	modplug? ( media-libs/libmodplug )
+	mp4? ( media-libs/libmp4v2:0 )
+	musepack? ( media-sound/musepack-tools )
+	opus? ( media-libs/opusfile )
+	pulseaudio? ( media-sound/pulseaudio )
+	systemd? ( sys-apps/systemd )
+	tremor? ( media-libs/tremor )
+	!tremor? ( vorbis? ( media-libs/libvorbis ) )
+	wavpack? ( media-sound/wavpack )
+"
+RDEPEND="${DEPEND}
+	pidgin? (
+		dev-python/dbus-python
+		net-im/pidgin
+	)
+"
+
+# Both CONFIG_TREMOR=y and CONFIG_VORBIS=y are required to link to tremor libs instead of vorbis libs
+REQUIRED_USE="tremor? ( vorbis )
+	mp4? ( aac )" # enabling mp4 adds -lfaad
+
+DOCS=( AUTHORS README.md )
+
+S="${WORKDIR}/${P/_/-}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.9.1-atomic.patch"
+)
+
+src_configure() {
+	my_config() {
+		local value
+		use ${1} && value=a || value=n
+		myconf+=( ${2}=${value} )
+	}
+
+	local debuglevel=1
+	use debug && debuglevel=2
+	local myconf=(
+		CONFIG_CUE=y
+		CONFIG_ARTS=n
+		CONFIG_SUN=n
+		CONFIG_SNDIO=n
+		CONFIG_WAVEOUT=n
+		CONFIG_VTX=n
+		CONFIG_ROAR=n
+	)
+
+	my_config cddb CONFIG_CDDB
+	my_config cdio CONFIG_CDIO
+	my_config discid CONFIG_DISCID
+	my_config flac CONFIG_FLAC
+	my_config mad CONFIG_MAD
+	my_config modplug CONFIG_MODPLUG
+	my_config mikmod CONFIG_MIKMOD
+	my_config musepack CONFIG_MPC
+	my_config vorbis CONFIG_VORBIS
+	my_config tremor CONFIG_TREMOR
+	my_config opus CONFIG_OPUS
+	my_config wavpack CONFIG_WAVPACK
+	my_config mp4 CONFIG_MP4
+	my_config aac CONFIG_AAC
+	my_config ffmpeg CONFIG_FFMPEG
+	my_config pulseaudio CONFIG_PULSE
+	my_config alsa CONFIG_ALSA
+	my_config jack CONFIG_JACK
+	my_config libsamplerate CONFIG_SAMPLERATE
+	my_config ao CONFIG_AO
+	my_config oss CONFIG_OSS
+
+	if use elogind || use systemd; then
+		myconf+=( CONFIG_MPRIS=a )
+	else
+		myconf+=( CONFIG_MPRIS=n )
+	fi
+
+	./configure prefix="${EPREFIX}"/usr "${myconf[@]}" \
+		exampledir="${EPREFIX}"/usr/share/doc/${PF}/examples \
+		libdir="${EPREFIX}"/usr/$(get_libdir) DEBUG=${debuglevel} || die
+}
+
+src_compile() {
+	tc-export_build_env BUILD_CC
+	emake V=2 \
+		CC="$(tc-getCC)" LD="$(tc-getCC)" \
+		HOSTCC="${BUILD_CC}" HOSTLD="${BUILD_CC}" \
+		HOST_CFLAGS="${BUILD_CFLAGS}" HOST_LDFLAGS="${BUILD_LDFLAGS}"
+}
+
+src_install() {
+	default
+
+	if ! use examples; then
+		rm -rf "${ED}"/usr/share/doc/${PF}/examples || die
+	fi
+
+	insinto /usr/share/zsh/site-functions
+	doins contrib/_cmus
+
+	newbashcomp contrib/${PN}.bash-completion ${PN}
+
+	if use pidgin; then
+		newbin contrib/cmus-updatepidgin.py cmus-updatepidgin
+	fi
+}
diff --git a/media-sound/cmus/cmus-9999.ebuild b/media-sound/cmus/cmus-9999.ebuild
index 3a73e7ed9e71..7a06ebbe8099 100644
--- a/media-sound/cmus/cmus-9999.ebuild
+++ b/media-sound/cmus/cmus-9999.ebuild
@@ -1,7 +1,7 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit bash-completion-r1 toolchain-funcs
 
@@ -10,7 +10,7 @@ if [[ ${PV} == "9999" ]] ; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/cmus/cmus/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+	KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
 fi
 
 DESCRIPTION="Ncurses based music player with plugin support for many formats"
@@ -30,7 +30,7 @@ BDEPEND="
 DEPEND="
 	sys-libs/ncurses:=[unicode(+)?]
 	aac? ( media-libs/faad2 )
-	alsa? ( >=media-libs/alsa-lib-1.0.11 )
+	alsa? ( media-libs/alsa-lib )
 	ao? ( media-libs/libao )
 	cddb? ( media-libs/libcddb )
 	cdio? ( dev-libs/libcdio-paranoia )
@@ -40,16 +40,16 @@ DEPEND="
 	flac? ( media-libs/flac )
 	jack? ( virtual/jack )
 	libsamplerate? ( media-libs/libsamplerate )
-	mad? ( >=media-libs/libmad-0.14 )
+	mad? ( media-libs/libmad )
 	mikmod? ( media-libs/libmikmod:0 )
-	modplug? ( >=media-libs/libmodplug-0.7 )
-	mp4? ( >=media-libs/libmp4v2-1.9:0 )
-	musepack? ( >=media-sound/musepack-tools-444 )
+	modplug? ( media-libs/libmodplug )
+	mp4? ( media-libs/libmp4v2:0 )
+	musepack? ( media-sound/musepack-tools )
 	opus? ( media-libs/opusfile )
 	pulseaudio? ( media-sound/pulseaudio )
 	systemd? ( sys-apps/systemd )
 	tremor? ( media-libs/tremor )
-	!tremor? ( vorbis? ( >=media-libs/libvorbis-1.0 ) )
+	!tremor? ( vorbis? ( media-libs/libvorbis ) )
 	wavpack? ( media-sound/wavpack )
 "
 RDEPEND="${DEPEND}
@@ -67,6 +67,10 @@ DOCS=( AUTHORS README.md )
 
 S="${WORKDIR}/${P/_/-}"
 
+PATCHES=(
+	"${FILESDIR}/${PN}-2.9.1-atomic.patch"
+)
+
 src_configure() {
 	my_config() {
 		local value