media-sound/rhythmbox: Bump to 3.4.8

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/39273
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 140 insertions, 0 deletions

diff --git a/media-sound/rhythmbox/Manifest b/media-sound/rhythmbox/Manifest
index 4c8d15a0bf9a..256b5f81bf31 100644
--- a/media-sound/rhythmbox/Manifest
+++ b/media-sound/rhythmbox/Manifest
@@ -1 +1,2 @@
 DIST rhythmbox-3.4.7.tar.xz 3673444 BLAKE2B a9186d7c23f281ff0a0d4a2188061473e9bab39078f816051e385319afeb1a8825e124e608fc50422f1bd27adae569d75fb6c53af23c7d51086dcf01b962d652 SHA512 58de6e51d046920857ba0905043f4863ef443d5eca28cdf93c1a25e3053322664eb1f894c102d5629f8261c507626e215c097ee166f13a3e7cd82fb35c891cb4
+DIST rhythmbox-3.4.8.tar.xz 3679500 BLAKE2B 626db1ddc4bd82c8d49d07ea993990d060e8dcc71851f88aa9fbc03a5a80a5d0211d68652f5b21f6c194fe859e2e9179fb2d389a4dc38de67dfcb17681788db7 SHA512 381b2b6b28368fbc4796ac0ff9e9ae380d6e54b656d371bf8a4d8629e6aafdf9afd7879cb23a77af4a322fb844f0250004d02db63793de2886a2c127cc90ec9c
diff --git a/media-sound/rhythmbox/rhythmbox-3.4.8.ebuild b/media-sound/rhythmbox/rhythmbox-3.4.8.ebuild
new file mode 100644
index 000000000000..58fe556f5834
--- /dev/null
+++ b/media-sound/rhythmbox/rhythmbox-3.4.8.ebuild
@@ -0,0 +1,139 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{10..13} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit gnome.org gnome2-utils python-single-r1 meson virtualx xdg
+
+DESCRIPTION="Music management and playback software for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Rhythmbox"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+IUSE="cdr daap doc dbus keyring ipod libnotify lirc mtp +python test +udev upnp-av"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="
+	ipod? ( udev )
+	mtp? ( udev )
+	dbus? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+"
+
+DEPEND="
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2.18:2
+	>=dev-libs/glib-2.66.0:2
+	>=dev-libs/gobject-introspection-0.10:=
+	>=media-libs/gstreamer-1.4.0:1.0[introspection]
+	>=media-libs/gst-plugins-base-1.4.0:1.0[introspection]
+	>=x11-libs/gtk+-3.20.0:3[introspection]
+	dev-libs/json-glib
+	>=dev-libs/libpeas-0.7.3:0[gtk]
+	>=net-libs/libsoup-3.0.7:3.0
+	>=dev-libs/libxml2-2.7.8:2
+	x11-libs/pango
+	>=sys-libs/tdb-1.2.6
+	>=dev-libs/totem-pl-parser-3.2:=
+
+	cdr? ( >=app-cdr/brasero-2.91.90 )
+	daap? (
+		>=net-libs/libdmapsharing-3.9.11:4.0=
+		>=media-plugins/gst-plugins-soup-1.4:1.0
+	)
+	keyring? ( >=app-crypt/libsecret-0.18 )
+	libnotify? ( >=x11-libs/libnotify-0.7.0 )
+	lirc? ( app-misc/lirc )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			>=dev-python/pygobject-3.0:3[${PYTHON_USEDEP}]
+		')
+	)
+	udev? (
+		dev-libs/libgudev:=
+		ipod? ( >=media-libs/libgpod-0.7.92[udev] )
+		mtp? ( >=media-libs/libmtp-0.3 )
+	)
+"
+RDEPEND="${DEPEND}
+	media-plugins/gst-plugins-soup:1.0
+	|| (
+		media-plugins/gst-plugins-cdparanoia:1.0
+		media-plugins/gst-plugins-cdio:1.0
+	)
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/gst-plugins-taglib:1.0
+	x11-themes/adwaita-icon-theme
+	python? (
+		>=dev-libs/libpeas-0.7.3:0[python,${PYTHON_SINGLE_USEDEP}]
+		net-libs/libsoup:3.0[introspection]
+		x11-libs/gdk-pixbuf:2[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection]
+
+		dbus? ( sys-apps/dbus )
+		keyring? ( >=app-crypt/libsecret-0.18[introspection] )
+	)
+	upnp-av? (
+		>=media-libs/grilo-0.3.15-r1:0.3
+		>=media-plugins/grilo-plugins-0.3.16:0.3[upnp-av]
+	)
+"
+BDEPEND="
+	doc? ( dev-util/gi-docgen )
+	dev-util/itstool
+	virtual/pkgconfig
+	test? ( dev-libs/check )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.4.7-skip-broken-test.patch
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature cdr brasero)
+		$(meson_feature daap)
+		-Dfm_radio=enabled
+		$(meson_feature upnp-av grilo)
+		$(meson_feature udev gudev)
+		$(meson_feature ipod)
+		$(meson_feature libnotify)
+		$(meson_feature keyring libsecret)
+		$(meson_feature lirc)
+		$(meson_feature mtp)
+		$(meson_feature python plugins_python)
+		-Dplugins_vala=disabled
+		-Dsample-plugins=false
+
+		-Dhelp=true
+		$(meson_use doc apidoc)
+		$(meson_feature test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	unset SESSION_MANAGER
+	"${BROOT}${GLIB_COMPILE_SCHEMAS}" --allow-any-name "${S}/data" || die
+	GSETTINGS_SCHEMA_DIR="${S}/data" virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}