media-sound/qmmp: Bump to version 1.6.0

Closes: https://bugs.gentoo.org/846890
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

3 files changed, 175 insertions, 0 deletions

diff --git a/media-sound/qmmp/Manifest b/media-sound/qmmp/Manifest
index c1fd61a98ce8..9b6246e96ef6 100644
--- a/media-sound/qmmp/Manifest
+++ b/media-sound/qmmp/Manifest
@@ -1 +1,2 @@
 DIST qmmp-1.5.4.tar.bz2 1388941 BLAKE2B e1a205b6315cd841c7d7a94ed85dca7fcbc74416dcc09458637ccadab96c3a2614039007cdbab404098d2818f4b5cdb7a0bc5cf27e1bfdd0f146d73e2834f230 SHA512 5dcc543f75f3baa6115c7c692acaca00b1ad6b62c773ac18ad97447fc17978f067d85b132d1fdb65467474417b7d7e8d8b43e0284196978ca63dd5d431a23bf5
+DIST qmmp-1.6.0.tar.bz2 1364512 BLAKE2B 3af905fa8af1a23f04d3df30856f881184a5150de571ffb82efc98179c2fe67a232207ad1233c57fde9000facc1df07317b10658e5f462f79083e99deeb7bb9f SHA512 a96242b4eb46fce84f7eefb1dd90cf4c51809c7f8471a405462d95cb3ba5c373e217c50ed48b4ad6b94e1a7e0948839433d4085c41a35991bffd08699a4826f1
diff --git a/media-sound/qmmp/files/qmmp-1.6.0-udisks_plugin.patch b/media-sound/qmmp/files/qmmp-1.6.0-udisks_plugin.patch
new file mode 100644
index 000000000000..45512099ffeb
--- /dev/null
+++ b/media-sound/qmmp/files/qmmp-1.6.0-udisks_plugin.patch
@@ -0,0 +1,11 @@
+--- qmmp-1.6.0/src/plugins/General/CMakeLists.txt
++++ qmmp-1.6.0/src/plugins/General/CMakeLists.txt
+@@ -51,7 +51,7 @@
+ ENDIF(USE_HAL AND Qt5DBus_FOUND)
+ 
+ IF(USE_UDISKS2 AND Qt5DBus_FOUND)
+-add_subdirectory(udisks2)
++add_subdirectory(udisks)
+ ENDIF(USE_UDISKS2 AND Qt5DBus_FOUND)
+ 
+ IF(USE_HOTKEY AND Qt5X11Extras_FOUND)
diff --git a/media-sound/qmmp/qmmp-1.6.0.ebuild b/media-sound/qmmp/qmmp-1.6.0.ebuild
new file mode 100644
index 000000000000..973fbd88a571
--- /dev/null
+++ b/media-sound/qmmp/qmmp-1.6.0.ebuild
@@ -0,0 +1,163 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Qt5-based audio player with winamp/xmms skins support"
+HOMEPAGE="http://qmmp.ylsoftware.com"
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="http://qmmp.ylsoftware.com/files/${P}.tar.bz2
+		mirror://sourceforge/${PN}-dev/files/${P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit subversion
+	QMMP_DEV_BRANCH="1.3"
+	ESVN_REPO_URI="svn://svn.code.sf.net/p/${PN}-dev/code/branches/${PN}-${QMMP_DEV_BRANCH}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+# KEYWORDS further up
+IUSE="aac +alsa analyzer archive bs2b cdda cover crossfade cue curl +dbus enca
+ffmpeg flac game gnome jack ladspa lyrics +mad midi mms mplayer musepack
+notifier opus oss pipewire projectm pulseaudio qsui qtmedia scrobbler shout sid
+sndfile soxr stereo tray udisks +vorbis wavpack xmp"
+
+REQUIRED_USE="
+	gnome? ( dbus )
+	shout? ( soxr vorbis )
+	udisks? ( dbus )
+"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	media-libs/taglib
+	x11-libs/libX11
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	dbus? ( dev-qt/qtdbus:5 )
+	enca? ( app-i18n/enca )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac )
+	game? ( media-libs/game-music-emu )
+	jack? (
+		media-libs/libsamplerate
+		virtual/jack
+	)
+	ladspa? ( media-plugins/cmt-plugins )
+	mad? (
+		media-libs/libmad:=
+		media-sound/mpg123:=
+	)
+	midi? ( media-sound/wildmidi )
+	mms? ( media-libs/libmms )
+	mplayer? ( media-video/mplayer )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	opus? ( media-libs/opusfile )
+	pipewire? ( media-video/pipewire )
+	projectm? (
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qtopengl:5
+		media-libs/libprojectm:=
+	)
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.9 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	shout? ( media-libs/libshout )
+	sid? ( >=media-libs/libsidplayfp-1.1.0 )
+	sndfile? ( media-libs/libsndfile )
+	soxr? ( media-libs/soxr )
+	udisks? ( sys-fs/udisks:2 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	wavpack? ( media-sound/wavpack )
+	xmp? ( media-libs/libxmp )
+"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5
+"
+
+DOCS=( AUTHORS ChangeLog README )
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.6.0-udisks_plugin.patch"
+)
+
+src_prepare() {
+	if has_version dev-libs/libcdio-paranoia ; then
+		sed -i \
+			-e 's:cdio/cdda.h:cdio/paranoia/cdda.h:' \
+			src/plugins/Input/cdaudio/decoder_cdaudio.cpp || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_AAC="$(usex aac)"
+		-DUSE_ALSA="$(usex alsa)"
+		-DUSE_ANALYZER="$(usex analyzer)"
+		-DUSE_ARCHIVE="$(usex archive)"
+		-DUSE_BS2B="$(usex bs2b)"
+		-DUSE_CDA="$(usex cdda)"
+		-DUSE_COVER="$(usex cover)"
+		-DUSE_CROSSFADE="$(usex crossfade)"
+		-DUSE_CUE="$(usex cue)"
+		-DUSE_CURL="$(usex curl)"
+		-DUSE_KDENOTIFY="$(usex dbus)"
+		-DUSE_MPRIS="$(usex dbus)"
+		-DUSE_ENCA="$(usex enca)"
+		-DUSE_FFMPEG="$(usex ffmpeg)"
+		-DUSE_FILEWRITER="$(usex vorbis)"
+		-DUSE_FLAC="$(usex flac)"
+		-DUSE_GME="$(usex game)"
+		-DUSE_GNOMEHOTKEY="$(usex gnome)"
+		-DUSE_HAL=OFF
+		-DUSE_JACK="$(usex jack)"
+		-DUSE_LADSPA="$(usex ladspa)"
+		-DUSE_LYRICS="$(usex lyrics)"
+		-DUSE_MAD="$(usex mad)"
+		-DUSE_MIDI="$(usex midi)"
+		-DUSE_MMS="$(usex mms)"
+		-DUSE_MPLAYER="$(usex mplayer)"
+		-DUSE_MPC="$(usex musepack)"
+		-DUSE_NOTIFIER="$(usex notifier)"
+		-DUSE_OPUS="$(usex opus)"
+		-DUSE_OSS="$(usex oss)"
+		-DUSE_PIPEWIRE="$(usex pipewire)"
+		-DUSE_PROJECTM="$(usex projectm)"
+		-DUSE_PULSE="$(usex pulseaudio)"
+		-DUSE_QSUI="$(usex qsui)"
+		-DUSE_QTMULTIMEDIA="$(usex qtmedia)"
+		-DUSE_SCROBBLER="$(usex scrobbler)"
+		-DUSE_SHOUT="$(usex shout)"
+		-DUSE_SID="$(usex sid)"
+		-DUSE_SNDFILE="$(usex sndfile)"
+		-DUSE_SOXR="$(usex soxr)"
+		-DUSE_STEREO="$(usex stereo)"
+		-DUSE_STATICON="$(usex tray)"
+		-DUSE_UDISKS2="$(usex udisks)"
+		-DUSE_VORBIS="$(usex vorbis)"
+		-DUSE_WAVPACK="$(usex wavpack)"
+		-DUSE_XMP="$(usex xmp)"
+	)
+
+	cmake_src_configure
+}