media-sound/audiotools: initial import

Signed-off-by: Tim Harder <radhermit@gentoo.org>

4 files changed, 143 insertions, 0 deletions

diff --git a/media-sound/audiotools/Manifest b/media-sound/audiotools/Manifest
new file mode 100644
index 000000000000..ebd145bd6c7f
--- /dev/null
+++ b/media-sound/audiotools/Manifest
@@ -0,0 +1 @@
+DIST audiotools-3.1.1.tar.gz 6325408 BLAKE2B 065b5dc23796ea8d1dc72dc581a8929fe26e08180af2f0719470d80d5c82be2455ffda28fe8fd5ca63ae078f7fa5c6b5153e8fae496736da8f97a4eae38c4876 SHA512 dfba0dab8ef1573a12366bb4d46552eeb6c23c4abde34d9df51238fc97f573135b564cc3e5dbcaf7691c4502d8173dc926d8eb5ecd169fe619278ae89ff24c3a
diff --git a/media-sound/audiotools/audiotools-3.1.1.ebuild b/media-sound/audiotools/audiotools-3.1.1.ebuild
new file mode 100644
index 000000000000..6b5fa12fc8a5
--- /dev/null
+++ b/media-sound/audiotools/audiotools-3.1.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of command line audio tools"
+HOMEPAGE="http://audiotools.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac alsa cdda cdr cue dvda flac gui twolame mp3 opus pulseaudio vorbis wavpack"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	alsa? ( media-libs/alsa-lib )
+	cdda? ( dev-libs/libcdio-paranoia:0= )
+	dvda? ( media-libs/libdvd-audio )
+	twolame? ( media-sound/twolame )
+	mp3? ( || ( media-sound/mpg123 media-sound/lame ) )
+	opus? (
+		media-libs/opus
+		media-libs/opusfile
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+"
+RDEPEND="${DEPEND}
+	aac? (
+		media-libs/faad2
+		media-libs/faac
+	)
+	cdr? ( virtual/cdrtools )
+	cue? ( app-cdr/cdrdao )
+	flac? ( media-libs/flac )
+	gui? (
+		$(python_gen_impl_dep 'tk(+)')
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/urwid[${PYTHON_USEDEP}]
+	)
+"
+
+# lots of random failures
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}"/${P}-libcdio-paranoia.patch )
+
+src_prepare() {
+	default
+
+	local USEFLAG_LIBS=(
+		cdda:libcdio_paranoia
+		dvda:libdvd-audio
+		pulseaudio:libpulse
+		alsa:alsa
+		mp3:libmpg123
+		mp3:mp3lame
+		vorbis:vorbisfile
+		vorbis:vorbisenc
+		opus:opusfile
+		opus:opus
+		twolame:twolame
+	)
+
+	# enable/disable deps based on USE flags
+	local flag_lib flag lib
+	for flag_lib in "${USEFLAG_LIBS[@]}"; do
+		flag=${flag_lib/:*}
+		lib=${flag_lib/*:}
+		use ${flag} || { sed -i "/^${lib}:/s/probe/no/" setup.cfg || die; }
+	done
+}
+
+python_compile_all() {
+	emake -C docs
+}
+
+python_test() {
+	cd test || die
+	"${PYTHON}" test.py || die
+}
+
+python_install_all() {
+	doman docs/*.{1,5}
+	distutils-r1_python_install_all
+}
diff --git a/media-sound/audiotools/files/audiotools-3.1.1-libcdio-paranoia.patch b/media-sound/audiotools/files/audiotools-3.1.1-libcdio-paranoia.patch
new file mode 100644
index 000000000000..1081149641a6
--- /dev/null
+++ b/media-sound/audiotools/files/audiotools-3.1.1-libcdio-paranoia.patch
@@ -0,0 +1,33 @@
+Add support for Gentoo's newer dev-libs/libcdio-paranoia file layout and
+versioning.
+
+--- audiotools-3.1.1/setup.py
++++ audiotools-3.1.1/setup.py
+@@ -190,6 +190,14 @@
+                     return tuple(int(s) for s in pkg_config_stdout.split("."))
+                 except ValueError:
+                     # version isn't all integers
++                    # try to split off libcdio_paranoia extended versioning
++                    if library == 'libcdio_paranoia':
++                        version = pkg_config_stdout.partition('+')[2]
++                        if version:
++                            try:
++                                return tuple(int(s) for s in version.split("."))
++                            except ValueError:
++                                pass
+                     return tuple()
+             else:
+                 # library not found
+--- audiotools-3.1.1/src/cdiomodule.h
++++ audiotools-3.1.1/src/cdiomodule.h
+@@ -3,8 +3,8 @@
+ #include <cdio/cdda.h>
+ #include <cdio/paranoia.h>
+ #else
+-#include <cdio/cdparanoia/cdda.h>
+-#include <cdio/cdparanoia/paranoia.h>
++#include <cdio/paranoia/cdda.h>
++#include <cdio/paranoia/paranoia.h>
+ #endif
+ 
+ /********************************************************
diff --git a/media-sound/audiotools/metadata.xml b/media-sound/audiotools/metadata.xml
new file mode 100644
index 000000000000..6e38a80b6a68
--- /dev/null
+++ b/media-sound/audiotools/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>sound@gentoo.org</email>
+		<name>Gentoo Sound project</name>
+	</maintainer>
+	<use>
+		<flag name="cue">Enable CUE sheet support</flag>
+		<flag name="dvda">Enable DVD-Audio support</flag>
+		<flag name="gui">Enable support for GUI tools</flag>
+		<flag name="twolame">Enable twolame support (MPEG Audio Layer 2 encoder)</flag>
+	</use>
+	<upstream>
+		<remote-id type="sourceforge">audiotools</remote-id>
+	</upstream>
+</pkgmetadata>