media-libs/avidemux-core: Add avidemux-core-2.6.20

Upgrade avidemux-core-9999 to EAPI 6 and add an ebuild for avidemux-core-2.6.20.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

3 files changed, 128 insertions, 25 deletions

diff --git a/media-libs/avidemux-core/Manifest b/media-libs/avidemux-core/Manifest
index 418a75235847..6f017f59f92b 100644
--- a/media-libs/avidemux-core/Manifest
+++ b/media-libs/avidemux-core/Manifest
@@ -1 +1,2 @@
+DIST avidemux_2.6.20.tar.gz 20172362 SHA256 03c6cb7fc9eb74688b4fcd5eb654ed7b9c4ffc717a72cc09b08a2d10cdc7ef9f SHA512 d01d0fc24a3004770bd3923c2debc4fa2752eb71df08cfe423746b9c44a2562ca01d82965ed2563b99572a4bed8034b79487199ce330208b51a3b7f87ccf7103 WHIRLPOOL 2e2dc21bed49eeb0cdfefe75fe51f6a84226e7e8e80b063bc0b3d8711a6b91db710611dc0ec06575be69ec8e24f2f9e5b5eb363b9c095267729e85e162a4ce38
 DIST avidemux_2.6.8.tar.gz 17380534 SHA256 02998c235a89894d184d745c94cac37b78bc20e9eb44b318ee2bb83f2507e682 SHA512 57a4042f1a9d46462850871d36950215c5ffb5b66ce2f2cde09d747e946c05adb7a550ac7763c96f4c1bcb2c39881407d9d88bc64c93053741091751495ba0b0 WHIRLPOOL 29f8a6039d82e686e8dfbfc7b23658921834238a4cc6c4de338afdfdc032a9a7cba1c8236789aa6dbcab318ec14c344c19563f153e6cbd63cd265c5fb15b44b6
diff --git a/media-libs/avidemux-core/avidemux-core-2.6.20.ebuild b/media-libs/avidemux-core/avidemux-core-2.6.20.ebuild
new file mode 100644
index 000000000000..e09688e05bf6
--- /dev/null
+++ b/media-libs/avidemux-core/avidemux-core-2.6.20.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit cmake-utils
+
+DESCRIPTION="Core libraries for a video editor designed for simple cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+
+# Multiple licenses because of all the bundled stuff.
+LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
+IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau video_cards_fglrx xv"
+
+if [[ ${PV} == *9999* ]] ; then
+	EGIT_REPO_URI="https://github.com/mean00/avidemux2.git"
+	EGIT_CHECKOUT_DIR=${WORKDIR}
+
+	inherit git-r3
+else
+	MY_PN="${PN/-core/}"
+	MY_P="${MY_PN}_${PV}"
+	SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+# Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
+DEPEND="
+	!<media-video/avidemux-${PV}:${SLOT}
+	dev-db/sqlite:3
+	sdl? ( media-libs/libsdl:0 )
+	system-ffmpeg? ( >=virtual/ffmpeg-9:0[mp3,theora] )
+	xv? ( x11-libs/libXv:0 )
+	vaapi? ( x11-libs/libva:0 )
+	vdpau? ( x11-libs/libvdpau:0 )
+	video_cards_fglrx? (
+		|| ( >=x11-drivers/ati-drivers-14.12-r3
+			x11-libs/xvba-video:0 )
+		)
+"
+RDEPEND="
+	$DEPEND
+	nls? ( virtual/libintl:0 )
+"
+DEPEND="
+	$DEPEND
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	!system-ffmpeg? ( dev-lang/yasm[nls=] )
+"
+
+S="${WORKDIR}/${MY_P}"
+CMAKE_USE_DIR="${S}/${PN/-/_}"
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if use system-ffmpeg ; then
+		# Preparations to support the system ffmpeg. Currently fails because it depends on files the system ffmpeg doesn't install.
+		local error="Failed to remove ffmpeg."
+
+		rm -rf cmake/admFFmpeg* cmake/ffmpeg* avidemux_core/ffmpeg_package buildCore/ffmpeg || die "${error}"
+		sed -i -e 's/include(admFFmpegUtil)//g' avidemux/commonCmakeApplication.cmake || die "${error}"
+		sed -i -e '/registerFFmpeg/d' avidemux/commonCmakeApplication.cmake || die "${error}"
+		sed -i -e 's/include(admFFmpegBuild)//g' avidemux_core/CMakeLists.txt || die "${error}"
+	else
+		# Avoid existing avidemux installations from making the build process fail, bug #461496.
+		sed -i -e "s:getFfmpegLibNames(\"\${sourceDir}\"):getFfmpegLibNames(\"${WORKDIR}/${P}_build/ffmpeg/source/\"):g" cmake/admFFmpegUtil.cmake \
+			|| die "Failed to avoid existing avidemux installation from making the build fail."
+	fi
+}
+
+src_configure() {
+	# Add lax vector typing for PowerPC.
+	if use ppc || use ppc64 ; then
+		append-cflags -flax-vector-conversions
+	fi
+
+	# See bug 432322.
+	use x86 && replace-flags -O0 -O1
+
+	local mycmakeargs=(
+		-DAVIDEMUX_SOURCE_DIR='${S}'
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+		-DNVENC="$(usex nvenc)"
+	)
+
+	if use debug ; then
+		mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile -j1
+}
+
+src_install() {
+	cmake-utils_src_install -j1
+}
diff --git a/media-libs/avidemux-core/avidemux-core-9999.ebuild b/media-libs/avidemux-core/avidemux-core-9999.ebuild
index 3a659ab182e9..e09688e05bf6 100644
--- a/media-libs/avidemux-core/avidemux-core-9999.ebuild
+++ b/media-libs/avidemux-core/avidemux-core-9999.ebuild
@@ -1,29 +1,28 @@
 # Copyright 1999-2017 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="5"
+EAPI="6"
 
-inherit cmake-utils eutils flag-o-matic
-
-SLOT="2.6"
+inherit cmake-utils
 
 DESCRIPTION="Core libraries for a video editor designed for simple cutting, filtering and encoding tasks"
 HOMEPAGE="http://fixounet.free.fr/avidemux"
 
 # Multiple licenses because of all the bundled stuff.
 LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
+SLOT="2.6"
 IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau video_cards_fglrx xv"
-KEYWORDS="~amd64 ~x86"
 
-MY_PN="${PN/-core/}"
 if [[ ${PV} == *9999* ]] ; then
-	KEYWORDS=""
 	EGIT_REPO_URI="https://github.com/mean00/avidemux2.git"
+	EGIT_CHECKOUT_DIR=${WORKDIR}
 
-	inherit git-2
+	inherit git-r3
 else
+	MY_PN="${PN/-core/}"
 	MY_P="${MY_PN}_${PV}"
 	SRC_URI="mirror://sourceforge/${MY_PN}/${MY_PN}/${PV}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
 fi
 
 # Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
@@ -52,13 +51,9 @@ DEPEND="
 "
 
 S="${WORKDIR}/${MY_P}"
-BUILD_DIR="${S}/buildCore"
-
-DOCS=( AUTHORS README )
+CMAKE_USE_DIR="${S}/${PN/-/_}"
 
 src_prepare() {
-	mkdir "${BUILD_DIR}" || die "Can't create build folder."
-
 	cmake-utils_src_prepare
 
 	if use system-ffmpeg ; then
@@ -71,10 +66,12 @@ src_prepare() {
 		sed -i -e 's/include(admFFmpegBuild)//g' avidemux_core/CMakeLists.txt || die "${error}"
 	else
 		# Avoid existing avidemux installations from making the build process fail, bug #461496.
-		sed -i -e "s:getFfmpegLibNames(\"\${sourceDir}\"):getFfmpegLibNames(\"${S}/buildCore/ffmpeg/source/\"):g" cmake/admFFmpegUtil.cmake \
+		sed -i -e "s:getFfmpegLibNames(\"\${sourceDir}\"):getFfmpegLibNames(\"${WORKDIR}/${P}_build/ffmpeg/source/\"):g" cmake/admFFmpegUtil.cmake \
 			|| die "Failed to avoid existing avidemux installation from making the build fail."
 	fi
+}
 
+src_configure() {
 	# Add lax vector typing for PowerPC.
 	if use ppc || use ppc64 ; then
 		append-cflags -flax-vector-conversions
@@ -82,25 +79,23 @@ src_prepare() {
 
 	# See bug 432322.
 	use x86 && replace-flags -O0 -O1
-}
 
-src_configure() {
 	local mycmakeargs=(
 		-DAVIDEMUX_SOURCE_DIR='${S}'
-		$(cmake-utils_use nls GETTEXT)
-		$(cmake-utils_use sdl SDL)
-		$(cmake-utils_use vaapi LIBVA)
-		$(cmake-utils_use vdpau VDPAU)
-		$(cmake-utils_use video_cards_fglrx XVBA)
-		$(cmake-utils_use xv XVIDEO)
-		$(cmake-utils_use nvenc NVENC)
+		-DGETTEXT="$(usex nls)"
+		-DSDL="$(usex sdl)"
+		-DLIBVA="$(usex vaapi)"
+		-DVDPAU="$(usex vdpau)"
+		-DXVBA="$(usex video_cards_fglrx)"
+		-DXVIDEO="$(usex xv)"
+		-DNVENC="$(usex nvenc)"
 	)
 
 	if use debug ; then
-		mycmakeargs+=( -DVERBOSE=1 -DCMAKE_BUILD_TYPE=Debug -DADM_DEBUG=1 )
+		mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
 	fi
 
-	CMAKE_USE_DIR="${S}"/avidemux_core cmake-utils_src_configure
+	cmake-utils_src_configure
 }
 
 src_compile() {