media-gfx/gthumb: bump to 3.4.5

Reorders dependency list to the order found in configure.ac for easier
checking of updates. Remove unnecessary libSM and libICE deps, which
aren't needed since libegg (smclient) usage was removed in January 2014.
Fix gsettings-desktop-schemas dep to be a build dep too, because configure
checks for it at build-time.

Package-Manager: Portage-2.3.6, Repoman-2.3.2

2 files changed, 86 insertions, 0 deletions

diff --git a/media-gfx/gthumb/Manifest b/media-gfx/gthumb/Manifest
index e3833efe1a29..2d5fbed1848d 100644
--- a/media-gfx/gthumb/Manifest
+++ b/media-gfx/gthumb/Manifest
@@ -1 +1,2 @@
 DIST gthumb-3.4.4.1.tar.xz 3420356 SHA256 4dc63bb1cc1f139259bba7f9fd1735182f16ba37254119a9f9c3e13a898a9533 SHA512 e70eb1d27af3fa9320d556f56c2b283d26115eb145188811e4ece5b9599f2abb21c95be40b33c88defef9d4678ba84faa5a1c988240e532c8c055ff30c054c00 WHIRLPOOL a4b702a493e0b622731d5ecca1f437fec4f924576e78476c6460e159f3f052b287838573bbf1eeb0af485e4e97db7d3dc799e0524e55571d36e9f4a0fb92ab2a
+DIST gthumb-3.4.5.tar.xz 3391492 SHA256 816fc63ba9cfc397ea8c9a4d21870051813aa4d97383f3d3ae74cb3ea8235746 SHA512 a709e9af9626578a6121fc6d60aa8ec2ee9f1758e9078f2e77498cbfc28cd0f1c8631aeb5c9312496b344ff889f4545935871409af5e3cd625c9a62df5d22d85 WHIRLPOOL ee5b9d4e379e3c0ef56c3e1fe19d5e231f768ac02fb5ff5d28f15707ec137ea704d87dec8630763cf4a2b75fc0a08466a06a8d08b262e4e139830ca2a3da9719
diff --git a/media-gfx/gthumb/gthumb-3.4.5.ebuild b/media-gfx/gthumb/gthumb-3.4.5.ebuild
new file mode 100644
index 000000000000..bbdc812b369a
--- /dev/null
+++ b/media-gfx/gthumb/gthumb-3.4.5.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Image viewer and browser for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/gthumb"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="cdr debug exif gnome-keyring gstreamer http jpeg json lcms raw slideshow svg tiff test webkit webp"
+
+RDEPEND="
+	>=dev-libs/glib-2.36.0:2[dbus]
+	>=x11-libs/gtk+-3.10.0:3
+	exif? ( >=media-gfx/exiv2-0.21:= )
+	slideshow? (
+		>=media-libs/clutter-1.12.0:1.0
+		>=media-libs/clutter-gtk-1:1.0 )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0 )
+	raw? ( >=media-libs/libraw-0.14:= )
+	http? ( >=net-libs/libsoup-2.42.0:2.4 )
+	gnome-keyring? ( >=app-crypt/libsecret-0.11 )
+	cdr? ( >=app-cdr/brasero-3.2 )
+	svg? ( >=gnome-base/librsvg-2.34:2 )
+	webp? ( >=media-libs/libwebp-0.2.0 )
+	json? ( >=dev-libs/json-glib-0.15.0 )
+	webkit? ( >=net-libs/webkit-gtk-1.10.0:4 )
+	lcms? ( >=media-libs/lcms-2.6:2 )
+
+	media-libs/libpng:0=
+	sys-libs/zlib
+	>=gnome-base/gsettings-desktop-schemas-0.1.4
+	jpeg? ( virtual/jpeg:0= )
+	tiff? ( media-libs/tiff:= )
+	!raw? ( media-gfx/dcraw )
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	>=dev-util/intltool-0.35
+	sys-devel/bison
+	sys-devel/flex
+	virtual/pkgconfig
+	test? ( ~app-text/docbook-xml-dtd-4.1.2 )
+"
+# eautoreconf needs:
+#	gnome-base/gnome-common
+
+src_prepare() {
+	# Remove unwanted CFLAGS added with USE=debug
+	sed -e 's/CFLAGS="$CFLAGS -g -O0 -DDEBUG"//' \
+		-i configure.ac -i configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Upstream says in configure help that libchamplain support
+	# crashes frequently
+	gnome2_src_configure \
+		--disable-static \
+		--disable-libchamplain \
+		$(use_enable cdr libbrasero) \
+		$(use_enable debug) \
+		$(use_enable exif exiv2) \
+		$(use_enable gnome-keyring libsecret) \
+		$(use_enable gstreamer) \
+		$(use_enable http libsoup) \
+		$(use_enable jpeg) \
+		$(use_enable json libjson-glib) \
+		$(use_enable lcms lcms2) \
+		$(use_enable raw libraw) \
+		$(use_enable slideshow clutter) \
+		$(use_enable svg librsvg) \
+		$(use_enable test test-suite) \
+		$(use_enable tiff) \
+		$(use_enable webkit webkit2) \
+		$(use_enable webp libwebp)
+}