media-gfx/graphicsmagick: add 1.3.39

Bug: https://bugs.gentoo.org/888545
Signed-off-by: Sam James <sam@gentoo.org>

3 files changed, 163 insertions, 1 deletions

diff --git a/media-gfx/graphicsmagick/Manifest b/media-gfx/graphicsmagick/Manifest
index 59c65f0fe9f1..b263f37b53e4 100644
--- a/media-gfx/graphicsmagick/Manifest
+++ b/media-gfx/graphicsmagick/Manifest
@@ -1,2 +1,4 @@
 DIST GraphicsMagick-1.3.38.tar.xz 5958352 BLAKE2B 132c8b2303690dbe84b0e9ab33db0c0861845ef0260915e33197912dbcae02ae70c27bce634cfe0ab6b739ef6f3e828cbea9043fc90be993fb2c4a5e33e20ee9 SHA512 478f9e2907d4cb1099b0cbd1a73e4ab58aef94edf6cb1636ce48a378084ec1671599fd4f369455e5af898e94d1386f7149f6933b7c668027a6f6952bc763ec3a
 DIST GraphicsMagick-1.3.38.tar.xz.sig 119 BLAKE2B 166b7bb6de30af22d1f2317812f76dee43dd69c5557613deea35de3767624466c07001fe029ec9d33d0c61ed2fe5ca3f48bf435853374c722963a1293bfaa7a1 SHA512 c6dfee7e4b63b646460f9045ca5c8f3105d1a761ec3cd3471b53293178ed9a963884539c8026d934ce1915654d517a9b30232d7260a13f6d7dbeb5a592485b09
+DIST GraphicsMagick-1.3.39.tar.xz 5509028 BLAKE2B 774717df5c10664d7f60305bbc0b780bd896c27cf5999fae3835a3b3275068bde626a8efb073f7eb9151671e0c170579b5fa7a36b9773e1a0d96c5cd7d0b73c8 SHA512 4820587a8fbc18864134a243eca68359389d92f2b716c657088e06b6fcf76831d9b3b4644478195ee6c5fb3a4ebdce06c79997f5a5778a28c63f5c8a319419a4
+DIST GraphicsMagick-1.3.39.tar.xz.asc 228 BLAKE2B ea9f9d607a4699e148beab6f43f04897c808db5a19c9b0d62d65218127506549931d9cae002ebed2abc8022fb9707612a298139fd051da6c5a6f2f9d5ac3d2a0 SHA512 f9d83d39e1bda804c1c128f18c9a6539906b21abacfb64501fb65c67a56b46b8591ba32a890ecf49917791ebdf394307136229b5820e16909159f5c42270f7ba
diff --git a/media-gfx/graphicsmagick/graphicsmagick-1.3.39.ebuild b/media-gfx/graphicsmagick/graphicsmagick-1.3.39.ebuild
new file mode 100644
index 000000000000..b0c2884dd116
--- /dev/null
+++ b/media-gfx/graphicsmagick/graphicsmagick-1.3.39.ebuild
@@ -0,0 +1,160 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+MY_P=${P/graphicsm/GraphicsM}
+DESCRIPTION="Collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.graphicsmagick.org/ https://hg.osdn.net/view/graphicsmagick/GM"
+
+if [[ ${PV} == 9999 ]] ; then
+	inherit mercurial
+	EHG_REPO_URI="http://hg.code.sf.net/p/${PN}/code"
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bobfriesenhahn.asc
+	inherit verify-sig
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.asc )"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+
+	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-bobfriesenhahn )"
+fi
+
+LICENSE="MIT"
+SLOT="0/${PV%.*}"
+
+IUSE="bzip2 +cxx debug dynamic-loading fpx heif imagemagick jbig jpeg jpegxl lcms lzma"
+IUSE+=" openmp perl png postscript q16 q32 static-libs svg tcmalloc tiff truetype"
+IUSE+=" webp wmf X zlib zstd"
+
+RDEPEND="
+	dev-libs/libltdl
+	bzip2? ( app-arch/bzip2 )
+	fpx? ( media-libs/libfpx )
+	heif? ( media-libs/libheif:= )
+	imagemagick? ( !media-gfx/imagemagick )
+	jbig? ( media-libs/jbigkit )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	lcms? ( media-libs/lcms:2 )
+	lzma? ( app-arch/xz-utils )
+	perl? ( dev-lang/perl:= )
+	png? ( media-libs/libpng:= )
+	postscript? ( app-text/ghostscript-gpl )
+	svg? ( dev-libs/libxml2 )
+	tcmalloc? ( dev-util/google-perftools:= )
+	tiff? ( media-libs/tiff:= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+	)
+	webp? ( media-libs/libwebp:= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+	)
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.36-flags.patch
+	"${FILESDIR}"/${PN}-1.3.19-perl.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+src_prepare() {
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local depth=8
+
+	use q16 && depth=16
+	use q32 && depth=32
+
+	local myeconfargs=(
+		--enable-largefile
+		--enable-shared
+		$(use_enable static-libs static)
+		$(use_enable debug prof)
+		$(use_enable debug gcov)
+		$(use_enable imagemagick magick-compat)
+		$(use_enable openmp)
+		--with-threads
+		$(use_with dynamic-loading modules)
+		--with-quantum-depth=${depth}
+		--without-frozenpaths
+		$(use_with cxx magick-plus-plus)
+		$(use_with heif)
+		$(use_with jpegxl jxl)
+		$(use_with perl)
+		--with-perl-options=INSTALLDIRS=vendor
+		$(use_with bzip2 bzlib)
+		$(use_with postscript dps)
+		$(use_with fpx)
+		$(use_with jbig)
+		$(use_with webp)
+		$(use_with jpeg)
+		# Needs last-rited/unpackaged jasper
+		--without-jp2
+		$(use_with lcms lcms2)
+		$(use_with lzma)
+		$(use_with png)
+		$(use_with tcmalloc)
+		$(use_with tiff)
+		--without-trio
+		$(use_with truetype ttf)
+		$(use_with wmf)
+		--with-fontpath="${EPREFIX}"/usr/share/fonts
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts
+		--with-windows-font-dir="${EPREFIX}"/usr/share/fonts/corefonts
+		$(use_with svg xml)
+		$(use_with zlib)
+		$(use_with zstd)
+		$(use_with X x)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	use perl && emake perl-build
+}
+
+src_test() {
+	unset DISPLAY # some perl tests fail when DISPLAY is set
+
+	default
+}
+
+src_install() {
+	default
+
+	if use perl ; then
+		emake -C PerlMagick DESTDIR="${D}" install
+
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} + || die
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} + || die
+}
diff --git a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
index 2c1c95d1eb59..b0c2884dd116 100644
--- a/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
+++ b/media-gfx/graphicsmagick/graphicsmagick-9999.ebuild
@@ -16,7 +16,7 @@ else
 	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/bobfriesenhahn.asc
 	inherit verify-sig
 	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
-	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.sig )"
+	SRC_URI+=" verify-sig? ( mirror://sourceforge/${PN}/${MY_P}.tar.xz.asc )"
 	S="${WORKDIR}/${MY_P}"
 
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"