mail-client/mutt: version bump to 1.6.0, USE=sidebar doesn't compile yet

Package-Manager: portage-2.2.28-prefix

2 files changed, 289 insertions, 0 deletions

diff --git a/mail-client/mutt/Manifest b/mail-client/mutt/Manifest
index 7c79378414bd..298226a58dba 100644
--- a/mail-client/mutt/Manifest
+++ b/mail-client/mutt/Manifest
@@ -4,3 +4,5 @@ DIST mutt-1.5.23-gentoo-patches-r8.tar.bz2 167959 SHA256 30aed5383b77321b92e407b
 DIST mutt-1.5.23.tar.gz 3782032 SHA256 3af0701e57b9e1880ed3a0dee34498a228939e854a16cdccd24e5e502626fd37 SHA512 f1b4a7230253651857f61bd7215cce870a613012f613d4c907d401556083726c8ed7d429d57a8bf858c3b5b23683380d4c1494540d86ca80813e22cb6b95bc1e WHIRLPOOL b5a676d204aece8c572d57a027fa5a402b7afe8e5b7d4c83b2d1b1612eb0ac5cb58cd225757732a017f03444e0ea42dacffcf1cf2d46c18ae92d7d3306059c61
 DIST mutt-1.5.24-gentoo-patches-r1.tar.bz2 118546 SHA256 411ad728404f4e7743b82bb79020776ce5bdf614772c387b15992e14f7c444d2 SHA512 c19e6627683b91119bbbfcd5b3250cb3fb79ff9d62b45861002c50ac232f65447744313921fe10a517efb9cb93f5638615d5b8ce1dd946fab3083bd9eaffefc1 WHIRLPOOL cbd1a3858e3b187117e26718066a2f2dd9c690aca3a77b050142d12b96599adada1a8a723b91b000f9eda92d9ceed284a1ac5cdd243de8085a233f01fac003d7
 DIST mutt-1.5.24.tar.gz 3897115 SHA256 a292ca765ed7b19db4ac495938a3ef808a16193b7d623d65562bb8feb2b42200 SHA512 f7fe7edf9d1701a8e92761b1f5e6ef2e3a3b513af7898872cbe36a8800714cb76945788a60d2008820c57bc5344a4147e2686f690da42cfc8a912e3a432452b1 WHIRLPOOL 35408cabab100e688f8c6d0d598f79144b7c72fb31f41a720acb9a6381e7ca94d66e640fe1178b911cfb16dfde4c982362c4c78ea203aef3a3dbcba09dcdc023
+DIST mutt-1.6.0-gentoo-patches-r2.tar.xz 71108 SHA256 70709080f34b0eb49b5279f477f8f81b9b552e7eadc8e3bade761cbf905aac18 SHA512 8fff6af8e2d92612d9c90d89e526e85e11271ba42ae8b4482f813fe4ad4708746e1a5d602ab75e59ebc90e92b5d3f97a81d69a76d0f75173970f5b338bd1fd67 WHIRLPOOL 590361266bab02f95f1e78784ce8e0617c9766dccd2823864b24e4c6bc12f069ffbcdde741dc162f024431db68b0047cf7b97c3ef756be6f73499bc6a961e796
+DIST mutt-1.6.0.tar.gz 3954591 SHA256 29afb6238ab7a540c0e3a78ce25c970f975ab6c0f0bc9f919993aab772136c19 SHA512 601d5f70c7cd30903799714cd85b80f9650a029e621d044075e123656411dde809d5cef24a40ba49860bc242cf4a0b914c703deb5a7125b3a24eeb93f4ae3c4c WHIRLPOOL 4d0271ab703ec7fdadc49861921bb4728ee2e88629c45f286647982efa2b1021f07b929a745622961d8cd007941975cee1c29718536fd753563eb74e7670beac
diff --git a/mail-client/mutt/mutt-1.6.0.ebuild b/mail-client/mutt/mutt-1.6.0.ebuild
new file mode 100644
index 000000000000..ec55f288ba0c
--- /dev/null
+++ b/mail-client/mutt/mutt-1.6.0.ebuild
@@ -0,0 +1,287 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit eutils flag-o-matic autotools
+
+PATCHSET_REV="-r2"
+
+DESCRIPTION="A small but very powerful text-based mail client"
+HOMEPAGE="http://www.mutt.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	https://bitbucket.org/${PN}/${PN}/downloads/${P}.tar.gz
+	ftp://ftp.mutt.org/pub/mutt/${P}.tar.gz
+	mirror://gentoo/${P}-gentoo-patches${PATCHSET_REV}.tar.xz
+	https://dev.gentoo.org/~grobian/distfiles/${P}-gentoo-patches${PATCHSET_REV}.tar.xz"
+IUSE="berkdb crypt debug doc gdbm gnutls gpg idn imap kerberos libressl mbox nls nntp pop qdbm sasl selinux sidebar slang smime smtp ssl tokyocabinet"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+CDEPEND="
+	app-misc/mime-types
+	nls? ( virtual/libintl )
+	tokyocabinet?  ( dev-db/tokyocabinet )
+	!tokyocabinet? (
+		qdbm?  ( dev-db/qdbm )
+		!qdbm? (
+			gdbm?  ( sys-libs/gdbm )
+			!gdbm? ( berkdb? ( >=sys-libs/db-4 ) )
+		)
+	)
+	imap?    (
+		gnutls?  ( >=net-libs/gnutls-1.0.17 )
+		!gnutls? (
+			ssl? (
+				!libressl? ( >=dev-libs/openssl-0.9.6:0 )
+				libressl? ( dev-libs/libressl )
+			)
+		)
+		sasl?    ( >=dev-libs/cyrus-sasl-2 )
+	)
+	kerberos? ( virtual/krb5 )
+	pop?     (
+		gnutls?  ( >=net-libs/gnutls-1.0.17 )
+		!gnutls? (
+			ssl? (
+				!libressl? ( >=dev-libs/openssl-0.9.6:0 )
+				libressl? ( dev-libs/libressl )
+			)
+		)
+		sasl?    ( >=dev-libs/cyrus-sasl-2 )
+	)
+	smtp?     (
+		gnutls?  ( >=net-libs/gnutls-1.0.17 )
+		!gnutls? (
+			ssl? (
+				!libressl? ( >=dev-libs/openssl-0.9.6:0 )
+				libressl? ( dev-libs/libressl )
+			)
+		)
+		sasl?    ( >=dev-libs/cyrus-sasl-2 )
+	)
+	idn?     ( net-dns/libidn )
+	gpg?     ( >=app-crypt/gpgme-0.9.0 )
+	smime?   (
+		!libressl? ( >=dev-libs/openssl-0.9.6:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	slang? ( sys-libs/slang )
+	!slang? ( >=sys-libs/ncurses-5.2:0 )
+"
+DEPEND="${CDEPEND}
+	net-mail/mailbase
+	doc? (
+		dev-libs/libxml2
+		dev-libs/libxslt
+		app-text/docbook-xsl-stylesheets
+		|| ( www-client/lynx www-client/w3m www-client/elinks )
+	)"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-mutt )
+"
+PATCHDIR="${WORKDIR}"/${P}-gentoo-patches${PATCHSET_REV}
+
+pkg_setup() {
+	if use sidebar ; then
+		eerror "Sorry, but this version does not yet support sidebar"
+		eerror "Please mask ${PF} for now and check back later:"
+		eerror " # echo '=${CATEGORY}/${PF}' >> /etc/portage/package.mask"
+		die "booooo"
+	fi
+}
+
+src_prepare() {
+	# Post-release hot-fixes grabbed from HG, this is what all following
+	# patches are based on in my Mercurial patchqueue (mq).
+	# If you ever take over or need to modify patches here, just check
+	# out the gentoo branch(es) of Gentoo's Mutt Mercurial clone, and
+	# the patchqueue as it'll save you a lot of work.
+	# http://hg.code.sf.net/p/gentoomutt/code/
+	# http://hg.code.sf.net/p/gentoomuttpatches/code/
+	for rev in $(eval echo {0..${PR#r}}) ; do
+		local revpatch="${PATCHDIR}"/mutt-gentoo-${PV}-r${rev}.patch
+		[[ -e ${revpatch} ]] && \
+			epatch "${revpatch}"
+	done
+	# fix compilation with ncurses[tinfo], #459260
+	epatch "${PATCHDIR}"/ncurses-tinfo.patch
+
+	# this patch is non-generic and only works because we use a sysconfdir
+	# different from the one used by the mailbase ebuild
+	use prefix && epatch "${PATCHDIR}"/prefix-mailcap.patch
+
+	# must have fixes to compile or behave correctly, upstream
+	# ignores, disagrees or simply doesn't respond/apply
+	epatch "${PATCHDIR}"/bdb-prefix.patch # fix bdb detection
+	# same category, but functional bits
+	epatch "${PATCHDIR}"/dont-reveal-bbc.patch
+
+	# the big feature patches that upstream doesn't want to include, but
+	# nearly every distro has due to their usefulness
+	for p in "${PATCHDIR}"/[0-9][0-9]-*.patch ; do
+		epatch "${p}"
+	done
+
+	# we conditionalise this one, simply because it has considerable
+	# impact on the code
+	if use sidebar ; then
+		epatch "${PATCHDIR}"/sidebar-20140412.patch
+		epatch "${PATCHDIR}"/sidebar-dotpathsep.patch
+		epatch "${PATCHDIR}"/sidebar-counts.patch
+	fi
+
+	# Avoid symbol conflicts on Solaris
+	sed -i \
+		-e 's/\<M_CMD\>/MUTT_CMD/g' \
+		-e 's/\<M_READ\>/MUTT_READ/g' \
+		*.[ch] imap/*.[ch] || die
+
+	local upatches=
+	# allow user patches
+	eapply_user && upatches=" with user patches"
+
+	# patch version string for bug reports
+	sed -i -e 's/"Mutt %s (%s)"/"Mutt %s (%s, Gentoo '"${PVR}${upatches}"')"/' \
+		muttlib.c || die "failed patching in Gentoo version"
+
+	# many patches touch the buildsystem, we always need this
+	AT_M4DIR="m4" eautoreconf
+
+	# the configure script contains some "cleverness" whether or not to setgid
+	# the dotlock program, resulting in bugs like #278332
+	sed -i -e 's/@DOTLOCK_GROUP@//' \
+		Makefile.in || die "sed failed"
+
+	# don't just build documentation (lengthy process, with big dependencies)
+	if use !doc ; then
+		sed -i -e '/SUBDIRS =/s/doc//' Makefile.in || die
+	fi
+}
+
+src_configure() {
+	local myconf="
+		$(use_enable crypt pgp) \
+		$(use_enable debug) \
+		$(use_enable gpg gpgme) \
+		$(use_enable imap) \
+		$(use_enable nls) \
+		$(use_enable nntp) \
+		$(use_enable pop) \
+		$(use_enable smime) \
+		$(use_enable smtp) \
+		$(use_with idn) \
+		$(use_with kerberos gss) \
+		$(use slang && echo --with-slang=${EPREFIX}/usr) \
+		$(use !slang && echo --with-curses=${EPREFIX}/usr) \
+		--enable-compressed \
+		--enable-external-dotlock \
+		--enable-nfs-fix \
+		--sysconfdir=${EPREFIX}/etc/${PN} \
+		--with-docdir=${EPREFIX}/usr/share/doc/${PN}-${PVR} \
+		--with-regex \
+		--with-exec-shell=${EPREFIX}/bin/sh"
+
+	case $CHOST in
+		*-solaris*)
+			# Solaris has no flock in the standard headers
+			myconf+=" --enable-fcntl --disable-flock"
+			# wchar_t depends on locale
+			myconf+=" --without-wc-funcs"
+		;;
+		*)
+			myconf+=" --disable-fcntl --enable-flock"
+		;;
+	esac
+
+	# mutt prioritizes gdbm over bdb, so we will too.
+	# hcache feature requires at least one database is in USE.
+	if use tokyocabinet; then
+		myconf="${myconf} --enable-hcache \
+			--with-tokyocabinet --without-qdbm --without-gdbm --without-bdb"
+	elif use qdbm; then
+		myconf="${myconf} --enable-hcache \
+			--without-tokyocabinet --with-qdbm --without-gdbm --without-bdb"
+	elif use gdbm ; then
+		myconf="${myconf} --enable-hcache \
+			--without-tokyocabinet --without-qdbm --with-gdbm --without-bdb"
+	elif use berkdb; then
+		myconf="${myconf} --enable-hcache \
+			--without-tokyocabinet --without-qdbm --without-gdbm --with-bdb"
+	else
+		myconf="${myconf} --disable-hcache \
+			--without-tokyocabinet --without-qdbm --without-gdbm --without-bdb"
+	fi
+
+	# there's no need for gnutls, ssl or sasl without socket support
+	if use pop || use imap || use smtp ; then
+		if use gnutls; then
+			myconf="${myconf} --with-gnutls"
+		elif use ssl; then
+			myconf="${myconf} --with-ssl"
+		fi
+		# not sure if this should be mutually exclusive with the other two
+		myconf="${myconf} $(use_with sasl)"
+	else
+		myconf="${myconf} --without-gnutls --without-ssl --without-sasl"
+	fi
+
+	if use mbox; then
+		myconf="${myconf} --with-mailpath=${EPREFIX}/var/spool/mail"
+	else
+		myconf="${myconf} --with-homespool=Maildir"
+	fi
+
+	econf ${myconf} || die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	if use mbox; then
+		insinto /etc/mutt
+		newins "${FILESDIR}"/Muttrc.mbox Muttrc
+	else
+		insinto /etc/mutt
+		doins "${FILESDIR}"/Muttrc
+	fi
+
+	# A newer file is provided by app-misc/mime-types. So we link it.
+	rm "${ED}"/etc/${PN}/mime.types
+	dosym /etc/mime.types /etc/${PN}/mime.types
+
+	# A man-page is always handy, so fake one
+	if use !doc; then
+		emake -C doc DESTDIR="${D}" muttrc.man || die
+		# make the fake slightly better, bug #413405
+		sed -e 's#@docdir@/manual.txt#http://www.mutt.org/doc/devel/manual.html#' \
+			-e 's#in @docdir@,#at http://www.mutt.org/,#' \
+			-e "s#@sysconfdir@#${EPREFIX}/etc/${PN}#" \
+			-e "s#@bindir@#${EPREFIX}/usr/bin#" \
+			doc/mutt.man > mutt.1
+		cp doc/muttbug.man flea.1
+		cp doc/muttrc.man muttrc.5
+		doman mutt.1 flea.1 muttrc.5
+	else
+		# nuke manpages that should be provided by an MTA, bug #177605
+		rm "${ED}"/usr/share/man/man5/{mbox,mmdf}.5 \
+			|| ewarn "failed to remove files, please file a bug"
+	fi
+
+	if use !prefix ; then
+		fowners root:mail /usr/bin/mutt_dotlock
+		fperms g+s /usr/bin/mutt_dotlock
+	fi
+
+	dodoc BEWARE COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		echo
+		elog "If you are new to mutt you may want to take a look at"
+		elog "the Gentoo QuickStart Guide to Mutt E-Mail:"
+		elog "   https://wiki.gentoo.org/wiki/Mutt"
+		echo
+	fi
+}