kde-apps/ktp-accounts-kcm: 21.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-apps/ktp-accounts-kcm/Manifest b/kde-apps/ktp-accounts-kcm/Manifest
index 09cdf331f1c4..5fedc01d014c 100644
--- a/kde-apps/ktp-accounts-kcm/Manifest
+++ b/kde-apps/ktp-accounts-kcm/Manifest
@@ -1 +1,2 @@
 DIST ktp-accounts-kcm-21.04.3.tar.xz 266056 BLAKE2B f52493a6f2787d031d27ebe1f30bafa714d2fc086ec456e0566724b0ff012a481c295efa4d2fb906fe975a501f1a151247d66cc4f225c5e01351044f8e788ad0 SHA512 a69a19054e8f709d2728cc89ccb7e4dbb0ff1dd3dab76470945479aa405f3cc22991dd1d5ea95cee0eed6ad7e1fcda097b9f9225155c32fcba9ed9bad00058f3
+DIST ktp-accounts-kcm-21.08.0.tar.xz 266336 BLAKE2B da76957ffc65e20063dc2a508bdfdf0747d4efe6f3069173548b2fe5e93dfb22e15a4ab02233242bbd9dd56ff85121594119cbbe8822ac35058cd105c051050e SHA512 6ac643b8f661459324cc2bf5e5076144a0db42b54da395aa93bc9ee0c1277290c9514183bf6660fe6a938e5df1e71b9848970db2dbe27b95a647f1ec6ad4b8d1
diff --git a/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-21.08.0.ebuild b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-21.08.0.ebuild
new file mode 100644
index 000000000000..b197d7bac01f
--- /dev/null
+++ b/kde-apps/ktp-accounts-kcm/ktp-accounts-kcm-21.08.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.84.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="KDE Telepathy account management kcm"
+HOMEPAGE="https://community.kde.org/KTp"
+
+LICENSE="LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="experimental"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/kaccounts-integration-${PVCUT}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	net-libs/accounts-qt
+	net-libs/signond
+	>=net-libs/telepathy-qt-0.9.8
+"
+DEPEND="${COMMON_DEPEND}
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	net-libs/libaccounts-glib
+"
+RDEPEND="${COMMON_DEPEND}
+	>=kde-apps/kaccounts-providers-${PVCUT}:5
+	net-im/telepathy-connection-managers
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_DISABLED_PROVIDERS=$(usex experimental)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if use experimental; then
+		ewarn "Experimental providers are enabled."
+		ewarn "Most of them aren't integrated nicely and may require additional steps for account creation."
+		ewarn "Use at your own risk!"
+	fi
+	ecm_pkg_postinst
+}