kde-apps: Add KDE Applications 17.04.3

Package-Manager: Portage-2.3.6, Repoman-2.3.1

1 files changed, 74 insertions, 0 deletions

diff --git a/kde-apps/kate/kate-17.04.3.ebuild b/kde-apps/kate/kate-17.04.3.ebuild
new file mode 100644
index 000000000000..58d43628d007
--- /dev/null
+++ b/kde-apps/kate/kate-17.04.3.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+KDE_HANDBOOK="optional"
+KDE_TEST="true"
+VIRTUALX_REQUIRED="test"
+inherit kde5
+
+DESCRIPTION="Kate is an advanced text editor"
+HOMEPAGE="https://www.kde.org/applications/utilities/kate http://kate-editor.org"
+KEYWORDS="~amd64 ~x86"
+IUSE="+addons"
+
+DEPEND="
+	$(add_frameworks_dep kactivities)
+	$(add_frameworks_dep kcodecs)
+	$(add_frameworks_dep kcompletion)
+	$(add_frameworks_dep kconfig)
+	$(add_frameworks_dep kconfigwidgets)
+	$(add_frameworks_dep kcoreaddons)
+	$(add_frameworks_dep kcrash)
+	$(add_frameworks_dep kdbusaddons)
+	$(add_frameworks_dep kguiaddons)
+	$(add_frameworks_dep ki18n)
+	$(add_frameworks_dep kiconthemes)
+	$(add_frameworks_dep kio)
+	$(add_frameworks_dep kitemmodels)
+	$(add_frameworks_dep kitemviews)
+	$(add_frameworks_dep kjobwidgets)
+	$(add_frameworks_dep kparts)
+	$(add_frameworks_dep kservice)
+	$(add_frameworks_dep ktexteditor)
+	$(add_frameworks_dep ktextwidgets)
+	$(add_frameworks_dep kwidgetsaddons)
+	$(add_frameworks_dep kwindowsystem)
+	$(add_frameworks_dep kxmlgui)
+	$(add_qt_dep qtdbus)
+	$(add_qt_dep qtgui)
+	$(add_qt_dep qtscript)
+	$(add_qt_dep qtwidgets)
+	$(add_qt_dep qtxml)
+	addons? (
+		$(add_frameworks_dep kbookmarks)
+		$(add_frameworks_dep knewstuff)
+		$(add_frameworks_dep kwallet)
+		$(add_frameworks_dep plasma)
+		$(add_frameworks_dep threadweaver)
+		$(add_qt_dep qtsql)
+		>=dev-libs/libgit2-0.22.0:=[threads]
+	)
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	kde5_src_prepare
+	# test hangs
+	sed -e "/session_manager_test/d" -i kate/autotests/CMakeLists.txt || die
+	# delete colliding kwrite translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -name "kwrite*" -delete || die
+		rm -rf po/*/docs/kwrite || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_addons=$(usex addons)
+		-DBUILD_kwrite=FALSE
+	)
+
+	kde5_src_configure
+}