kde-apps: Add KDE Applications 19.08.3

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 126 insertions, 0 deletions

diff --git a/kde-apps/k3b/Manifest b/kde-apps/k3b/Manifest
index 11a7c4c7ed33..efc8d4bc6453 100644
--- a/kde-apps/k3b/Manifest
+++ b/kde-apps/k3b/Manifest
@@ -1,2 +1,3 @@
 DIST k3b-19.04.3.tar.xz 10496576 BLAKE2B 15d9b42b52b43f687f917ea077315404cae9225fe2d9759331336afd9135c2fadf35e0be9580933fd68661e054d981a19c74110b01e022be96d5afcbfac6a451 SHA512 1098ba685d683ad3687c5a0bf0fe27db69358d6142a76830227e497577ab0cfb2fcbccb59912fab2265f54568b8f6236486d2cd407dce709f6d2d725b40afe96
 DIST k3b-19.08.2.tar.xz 10505676 BLAKE2B 601b60eea2ea2cbe7eb30e947f922c17c9debfc1d2b14dd2604f5783b268d4b60dbfaf0b32f3e5bc0c6d7bb05d3c6cf0ff275eec90ae255eed52c17eafc8bce8 SHA512 e1ff3b9678e6f90764b60560e132f4c969d3f11d38b5233d48c628901509807682de06fb91c9bf653672df62b57afb8e2dcedf6a754b71af31c83e53a385caee
+DIST k3b-19.08.3.tar.xz 10500940 BLAKE2B 8184e6790a312e66f76d3112084e7ec8cf16b67ee3deb2d1fe88df76680d573b26310544c9c747168708494fca0e0c88db9b3ee8f05d66470622a0c42a491e87 SHA512 6a98100a43ba7b18e7333e4782fc070b6faae480c03a788d80d0051b2a72e8e89eb501ef7ffc1f1fa46b18141a6f53407079778b6c51709282cc43530863cf84
diff --git a/kde-apps/k3b/k3b-19.08.3.ebuild b/kde-apps/k3b/k3b-19.08.3.ebuild
new file mode 100644
index 000000000000..3f2f8b8ba15c
--- /dev/null
+++ b/kde-apps/k3b/k3b-19.08.3.ebuild
@@ -0,0 +1,125 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Full-featured burning and ripping application based on KDE Frameworks"
+HOMEPAGE="https://userbase.kde.org/K3b"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="dvd emovix encode ffmpeg flac libav mad mp3 musepack sndfile sox taglib vcd vorbis webkit"
+
+REQUIRED_USE="
+	flac? ( taglib )
+	mp3? ( encode taglib )
+	sox? ( encode taglib )
+"
+
+DEPEND="
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kfilemetadata-${KFMIN}:5[taglib?]
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-apps/libkcddb-${PVCUT}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	media-libs/libsamplerate
+	dvd? ( media-libs/libdvdread:= )
+	ffmpeg? (
+		libav? ( media-video/libav:= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( >=media-libs/flac-1.2[cxx] )
+	mp3? ( media-sound/lame )
+	mad? ( media-libs/libmad )
+	musepack? ( >=media-sound/musepack-tools-444 )
+	sndfile? ( media-libs/libsndfile )
+	taglib? ( >=media-libs/taglib-1.5 )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+	webkit? ( >=dev-qt/qtwebkit-5.212.0_pre20180120:5 )
+"
+RDEPEND="${DEPEND}
+	app-cdr/cdrdao
+	dev-libs/libburn
+	media-sound/cdparanoia
+	virtual/cdrtools
+	dvd? (
+		>=app-cdr/dvd+rw-tools-7
+		encode? ( media-video/transcode[dvd] )
+	)
+	emovix? ( media-video/emovix )
+	sox? ( media-sound/sox )
+	vcd? ( media-video/vcdimager )
+"
+
+DOCS+=( ChangeLog {FAQ,PERMISSIONS,README}.txt )
+
+src_configure() {
+	local mycmakeargs=(
+		-DK3B_BUILD_API_DOCS=OFF
+		-DK3B_BUILD_WAVE_DECODER_PLUGIN=ON
+		-DK3B_ENABLE_HAL_SUPPORT=OFF
+		-DK3B_ENABLE_MUSICBRAINZ=OFF
+		-DK3B_DEBUG=$(usex debug)
+		-DK3B_ENABLE_DVD_RIPPING=$(usex dvd)
+		-DK3B_BUILD_EXTERNAL_ENCODER_PLUGIN=$(usex encode)
+		-DK3B_BUILD_FFMPEG_DECODER_PLUGIN=$(usex ffmpeg)
+		-DK3B_BUILD_FLAC_DECODER_PLUGIN=$(usex flac)
+		-DK3B_BUILD_LAME_ENCODER_PLUGIN=$(usex mp3)
+		-DK3B_BUILD_MAD_DECODER_PLUGIN=$(usex mad)
+		-DK3B_BUILD_MUSE_DECODER_PLUGIN=$(usex musepack)
+		-DK3B_BUILD_SNDFILE_DECODER_PLUGIN=$(usex sndfile)
+		-DK3B_BUILD_SOX_ENCODER_PLUGIN=$(usex sox)
+		-DK3B_ENABLE_TAGLIB=$(usex taglib)
+		-DK3B_BUILD_OGGVORBIS_DECODER_PLUGIN=$(usex vorbis)
+		-DK3B_BUILD_OGGVORBIS_ENCODER_PLUGIN=$(usex vorbis)
+		$(cmake-utils_use_find_package webkit Qt5WebKitWidgets)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	echo
+	elog "If you get warnings on start-up, uncheck the \"Check system"
+	elog "configuration\" option in the \"Misc\" settings window."
+	echo
+
+	local group=cdrom
+	use kernel_linux || group=operator
+	elog "Make sure you have proper read/write permissions on optical device(s)."
+	elog "Usually, it is sufficient to be in the ${group} group."
+	echo
+}