kde-apps/dolphin-plugins-dropbox: 21.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 64 insertions, 0 deletions

diff --git a/kde-apps/dolphin-plugins-dropbox/Manifest b/kde-apps/dolphin-plugins-dropbox/Manifest
index 3c644ff083b6..59e3698db07f 100644
--- a/kde-apps/dolphin-plugins-dropbox/Manifest
+++ b/kde-apps/dolphin-plugins-dropbox/Manifest
@@ -1 +1,2 @@
 DIST dolphin-plugins-21.08.3.tar.xz 254604 BLAKE2B 9a7a9c7a1cf82d458c1fd0bbce6b47c233b8a7a20bd1d1696bc75d6b04c8e4a9d6464025d8ad39b3bb96b8dd428fb880a5d318f7c0d13ef3bc8bf24a42c24169 SHA512 2fb7fbd6490d768f3eb7d756429d858337b8088a7c87836ed4a54fc3f863f50c4973bbe2ae149d53d2769d7ce3c31fbd737bc4afc74fd14260a158da83992076
+DIST dolphin-plugins-21.12.0.tar.xz 254764 BLAKE2B 7c73390bd2c26643dfbc5593ef896ca674e5a0b17ede78e68504727125ac07370fb4b4139e0058e2050fbf065a7945f441ed7198fcd43fa9ea5fd679ba1998cb SHA512 c80f795dbb9a68a3d0f543a95386425289e9e2f8bd2c3bdf8644d05dd9ab651b8237528eee0535167448de165d7aac6f5f4bcc020d17d31d500a1958d7d0bcc2
diff --git a/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.12.0.ebuild b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.12.0.ebuild
new file mode 100644
index 000000000000..0d9df94bf891
--- /dev/null
+++ b/kde-apps/dolphin-plugins-dropbox/dolphin-plugins-dropbox-21.12.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="false"
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="dropbox"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Dolphin plugin for Dropbox service integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/dolphin-${PVCUT}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+"
+RDEPEND="${DEPEND}
+	net-misc/dropbox-cli
+"
+
+src_prepare() {
+	ecm_src_prepare
+	# solid, qtdbus only required by mountiso
+	ecm_punt_bogus_dep Qt5 DBus
+	ecm_punt_bogus_dep KF5 Solid
+	# delete non-${PN} translations
+	if [[ ${KDE_BUILD_TYPE} = release ]]; then
+		find po -type f -name "*po" -and -not -name "*${MY_PLUGIN_NAME}plugin" -delete || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}
+
+src_install() {
+	ecm_src_install
+	rm "${D}"/usr/share/metainfo/org.kde.dolphin-plugins.metainfo.xml || die
+}